perl - 使用Log::Log4perl制作自记录模块

有没有一种方法可以使用Log::Log4perl创建一个智能的自记录模块，即使没有调用脚本也不初始化Log4perl，该模块也可以将其操作记录到文件中？据我所知，使用Log4perl的唯一方法是从配置中的运行脚本中对其进行初始化，然后实现Log4perl调用的模块将根据调用者的Log4perl配置进行日志记录。

相反，我希望这些模块为Log4perl提供默认的初始化配置。这将提供模块类别的默认文件追加器。然后，如果需要，我可以通过使用不同的配置在调用方中初始化Log4perl来覆盖此行为，希望一切都能正常进行。

这种防御性日志记录行为是否可能？或者我将需要在每个调用要记录的模块的.pl脚本中依赖于启动Log4perl吗？

最佳答案

我在Moose中的自定义Log角色中执行了此操作(删除了无关的复杂代码):

package MyApp::Role::Log;

use Moose::Role;
use Log::Log4perl;

my @methods = qw(
    log trace debug info warn error fatal
    is_trace is_debug is_info is_warn is_error is_fatal
    logexit logwarn error_warn logdie error_die
    logcarp logcluck logcroak logconfess
);

has _logger => (
    is => 'ro',
    isa => 'Log::Log4perl::Logger',
    lazy_build => 1,
    handles => \@methods,
);

around $_ => sub {
    my $orig = shift;
    my $this = shift;

    # one level for this method itself
    # two levels for Class:;MOP::Method::Wrapped (the "around" wrapper)
    # one level for Moose::Meta::Method::Delegation (the "handles" wrapper)
    local $Log::Log4perl::caller_depth;
    $Log::Log4perl::caller_depth += 4;

    my $return = $this->$orig(@_);

    $Log::Log4perl::caller_depth -= 4;
    return $return;

} foreach @methods;

method _build__logger => sub {
    my $this = shift;

    my $loggerName = ref($this);
    Log::Log4perl->easy_init() if not Log::Log4perl::initialized();
    return Log::Log4perl->get_logger($loggerName)
};

如您所见，日志对象是自初始化的-如果尚未调用Log::Log4perl->init，则将调用easy_init。您可以轻松地对此进行修改，以允许每个模块自定义其记录器-我可以使用可选的角色参数，并使用ref($this)作为默认后备。

PS。您可能还想看看MooseX::Log::Log4perl，这是我在使用上面的记录器角色之前开始的地方。有一天，当我解决它时，我将向该MX模块提交一些急需的补丁，以合并我添加的一些功能。

关于perl - 使用Log::Log4perl制作自记录模块，我们在Stack Overflow上找到一个类似的问题：https://stackoverflow.com/questions/3018528/