haskell - Netwire - 如何构建一条产生位置、墙壁弹跳的电线？

使用 netwire-4.0.7

正如问题标题所说，我正在尝试创建一条产生位置的线(在每一步中以一定的速度移动位置)，从其他对象“弹跳”。我能想到的最简单的例子是在一个盒子内移动，比如在一些屏幕保护程序中。

我写这个函数是为了尝试做到这一点(仅针对一个轴):

import Control.Wire
bouncyWire :: Double -> Double -> Double -> Double -> Wire () IO a Double
bouncyWire startPosition startVelocity lowerBound upperBound = proc _ -> do
  rec
     v <- delay startVelocity -< if p < lowerBound || p > upperBound
                                    then -v else v
     p <- integral_ startPosition -< v
  returnA -< p

(我实际上将它与一个不同的 monad 一起使用，但这段代码实际上并没有使用它，它会使这里的问题变得过于复杂)。

然而，用 counterSession $ 1/60 踩它时，我遇到了一个问题 - 它不是从墙上“弹跳”，而是卡在那里。我认为发生的事情是它一遍又一遍地翻转速度 v，但我不确定为什么。我想我可能使用了延迟错误之类的。

最佳答案

正如 Richard Huxton 所解释的，您的电线被卡在了边界后面。一种解决方案是检查您不仅要反转速度，还要始终将它们指向正确的方向。这样，电线总是从边界后面得到。另一个解决方案是，如果它出去，将位置改回边界内。这样，永远不会感觉到电线落后(这是您在游戏中通常想要做的事情)。结合在一起它可能看起来像

import Prelude hiding ((.), id)
import Control.Category
import Control.Wire
import Control.Wire.Wire
import Control.Wire.Prefab.Move

bouncyWire :: (Monad m)
           => Double -> Double -> Double -> Double -> Wire () m a Double
bouncyWire startPosition startVelocity lowerBound upperBound =
    objPosition <$> object_ update (ObjectState startPosition startVelocity)
        . constant (Accelerate 0, ())
  where
    update _ s@(ObjectState pos vel)
        | (pos > upperBound)    = ObjectState (2*upperBound - pos) (- abs vel)
        | (pos < lowerBound)    = ObjectState (2*lowerBound - pos) (abs vel)
        | otherwise             = s

我对箭头符号不是很熟悉，所以我使用了 Category 和 Applicative 符号(使用 . 的电线组合)。对于这个任务，object_ 特别方便。它在内部集成了速度和循环，我们需要做的就是给它一个修改函数并从输出中提取位置。

关于haskell - Netwire - 如何构建一条产生位置、墙壁弹跳的电线？，我们在Stack Overflow上找到一个类似的问题：https://stackoverflow.com/questions/18380081/