c - 计算器错误

我试着学习flex和bison，但是我的flex/bison计算器打印错误的结果。例子

$ ./fb1-5
1 + 2 + 3
= 32728

生成文件

fb1-5:  fb1-5.l fb1-5.y
    bison -d fb1-5.y
    flex fb1-5.l
    cc -o $@ fb1-5.tab.c lex.yy.c -lfl

雷克瑟

%{
# include "fb1-5.tab.h"
%}
%%
"+"    { return ADD; }
"-"    { return SUB; }
"*"    { return MUL; }
"/"    { return DIV; }
"|"    { return ABS; }
[0-9]+ { yylval = atoi(yytext); return NUMBER; }
\n     { return EOL; }
[ \t]  { /* ignore whitespace */ }
.      { printf("Mystery character %c\n", *yytext); }
%%

分析器

/* simplest version of calculator */
%{
#include <stdio.h>
%}
/* declare tokens */
%token NUMBER
%token ADD SUB MUL DIV ABS
%token EOL
%%
calclist: /* nothing */
 | calclist exp EOL { printf("= %d\n", $1); }
 ;
exp: factor

 | exp ADD factor { $$ = $1 + $3; }
 | exp SUB factor { $$ = $1 - $3; }
 ;
factor: term

 | factor MUL term { $$ = $1 * $3; }
 | factor DIV term { $$ = $1 / $3; }
 ;
term: NUMBER

 | ABS term   { $$ = $2 >= 0? $2 : - $2; }
;
%%
main(int argc, char **argv)
{
  yyparse();
}
yyerror(char *s)
{
  fprintf(stderr, "error: %s\n", s);
}

怎么了？

最佳答案

在与calclist相关联的操作中，您引用的是$1的值，它引用递归产生式规则的calclist部分。但是，您实际上从未将值赋给任何地方的非终结符。你是说2美元吗？

FB1

c - 计算器错误