同步TC路径到打开对话框，代替Listary功能之一

TC很好用。TC的目录跳转也很方便，还是双窗口。

Windows打开对话框很难有。目录跳转很不方便，还无法代替。

好在Listary统一了这两者，解决了这个问题，可以方便地把TC路径同步到打开对话框。

但用惯了Everything，感觉Listary有点复杂臃肿，搜索结果不像EV是列表可重用，进程也多，而且大部分功能用不到。

对我而言，装Listary就是为了目录跳转方便，感觉有点杀鸡用牛刀。

于是就有了代用的AHK脚本，实现起来很简单，一个定时器即可。

#Persistent
#SingleInstance Force
;; #NoTrayIcon

tPath:=oldPath:=id_OD:=""
SetTimer,CheckWin,500
return

CheckWin:
If WinExist("ahk_class TTOTAL_CMD") And WinExist("ahk_class #32770",,,"请先输入视频或音频文件")　　;;屏蔽MPC-BE窗口，个人用得到
{
    WinGetTitle,tempStr
    If tempStr Not Contains 打开,另存为,选择,浏览打印文件　　;;根据需要调整
    {
        oldPath=
        Return
    }
    WinGet,id_OD,Id
    If WinActive("ahk_class TTOTAL_CMD")
    {
        SetTimer,CheckWin,Off
        WinWaitNotActive
        tPath:=getTcFolder()
        WinWaitActive,Ahk_Id%id_OD%
        If (oldPath<>tPath){
            SendInput %tPath%{Enter}
            oldPath:=tPath
        }
        tPath=
        SetTimer,CheckWin,On
    }
}
If (id_OD="") Or !WinExist("ahk_id" . id_OD)
    oldPath=
return

getTcFolder()
{
    ClipSaved:=ClipboardAll
    clipboard =
    SendMessage 1075,2029,0,,ahk_class TTOTAL_CMD
    ClipWait,2
    OutDir=%clipboard%
    Clipboard:=ClipSaved
    ClipSaved=
    Return OutDir
}