c - 旋转编码器防溢

我正在为一个AVR ATMega328P微控制器编写代码。微控制器应该读取编码器，并根据编码器的旋转来增加或减少r23。不幸的是，在这个时候，不管我旋转编码器的方向如何，输出只会减少，直到它达到0，然后在255开始。
我的代码相当简单，基于一个表查找值，该值结合了编码器的前一个状态和当前状态。如果前一个状态和当前状态没有合并以创建有效的turn，则返回错误，代码不执行任何操作。如果发生有效的状态更改，则通过r24将1或-1添加到r23。
我没有问题让微控制器读取编码器，但我不知道如何防止r23溢出。我的问题是当我点击255并添加1时，寄存器溢出并转到0。我不希望寄存器归零；我希望它保持在255，直到我将编码器旋转到相反的方向。我对0也有同样的问题。如果寄存器是0，我加-1，我不希望寄存器变成255，我希望它保持在0，直到我把它旋转到相反的方向。
我对跳出框框思考没有问题。如果你有一个解决方案或想法，请随时张贴。

;**** A P P L I C A T I O N   N O T E  *************************************
;*
;* Title:
;* Version:
;* Last updated:
;* Target:  AVR Dragon
;*
;*
;* DESCRIPTION
;*
;*.device   ATmega328P @ 1M  clock speed
;*
;* This is a simple program to test an optical encoder
;***************************************************************************

.include "m328Pdef.inc"
.org 0x0000
    jmp RESET   ;Reset Handle

.org 0x0008
    jmp Interrupt1 ; PCINT1 Handler

enc_states:
.db 0,-1,1,0,1,0,0,-1,-1,0,0,1,0,1,-1,0

RESET:

;Setup stack pointer
    ldi temp, low(RAMEND)
    out SPL, temp
    ldi temp, high(RAMEND)
    out SPH, temp

//Set Port B pins to output
    ser     temp            ; Set Register Rd <-- 0xff (output)
    out     DDRB,temp       ; set all PORTB bits as output

//Clear analog input pins and enable pull ups on Pin 0 and 1 (Port C)
    clr     temp
    out     DDRC, temp      ;all pins input
    ldi     temp, (1<<PC1)|(1<<PC0)
    out     PORTC,temp      ;Enable pullups on Pin 0 and 1

//Set Port D pins to output
    ser     temp            ; Set Register Rd <-- 0xff
    out     DDRD,temp       ; set all PORTD bits as output

//Enable encoder pins interrupt sources (Encoder 1)
    ldi     temp, (1<<PCINT9)|(1<<PCINT8)
    sts     PCMSK1, temp

//Enable encoder pins interrupt sources (Encoder 2)
//  ldi     temp, (1<<PCINT11)|(1<<PCINT10)
//  sts     PCMSK1, temp

//Enable pin change interrupts
    ldi     temp, (1<<PCIE1)
    sts     PCICR, temp

//Enable global interrupts
    sei

//Lookup table initial value
    ldi     ZL, 0x00   ;lookup table index and initial state

.def temp   = r16
    clr     r25
    clr     r24
    clr     r23

loop:
    out PORTB, r23
    jmp loop

Interrupt1:
// Push SREG, etc
    in      r25, PORTC  ;encoder value from PORTC

    ldi   ZH, High(enc_states*2)   ; setup Z pointer hi
    ldi   ZL, Low (enc_states*2)   ; setup Z pointer lo
    rol     r22     ;remember previous state and shift left twice
    rol     r22
    cbr     r25, 0xFC  ;clear encoder bits 7:2
    mov     r21,r25
    or      r25, r22   ;combine encoder bits with old bits
    cbr     r25, 0xF0  ;clear bits 7:4 for table lookup
    mov     r22, r25   ;save table lookup value
    mov     ZL, r25    ;load index value into table
    lpm     r24, z      ;get result
    add     r23,r24

// Pop SREG, etc.
    reti

最佳答案

“饱和”可以很简单地通过利用进位标志来完成，例如：

  mov __tmp_reg__, r23
  add __tmp_reg__, r24   ; do the addition

  brcs saturated          ; if the carry flag is set we have an overflow and should discard the result

    mov r23, __tmp_reg__ ; there was no overflow so we store the result

  saturated:

用上面的代码替换ISR末尾的add r23,r24，应该没问题。（显然，您可能需要将__tmp_reg__更改为可以用作临时存储器的某些寄存器。）
考虑到r24可能是正的、负的或零的，通过稍微扩展上述原则，可以正确处理所有情况：

  mov __tmp_reg__, r23

  tst r24

  breq doreturn  ; if r24 == 0 we have nothing to do and may just return

  brmi subtract  ; if r24 is 'negative' we need to subtract

    add __tmp_reg__, r24  ; if r24 is not negative we just add
    rjmp store            ; and go to where the result may be stored

  subtract:

    neg r24  ; r24 := -r24
    sub __tmp_reg__, r24   ; do the subtraction

  store:

  brcs doreturn          ; if the carry flag is set we have an overflow and should discard the result

    mov r23, __tmp_reg__ ; there was no overflow so we store the result

  doreturn:

仔细看一下你的代码，在我看来，当z指针的计算完成时，代码中还有一个“小故障”：

ldi   ZH, High(enc_states*2)   ; setup Z pointer hi
ldi   ZL, Low (enc_states*2)   ; setup Z pointer lo

和

mov     ZL, r25    ;load index value into table

看起来有问题：z地址的下半部分被忽略，并被索引值覆盖。当Low (enc_states*2)不是0时，这将导致问题；您可能需要执行add ZL, r25和adc ZH, __zero_reg__（16位加法）而不是mov ZL, r25。
另一种想法可能会降低你日常工作的复杂性：
增量式旋转编码器的输出可以解释为类似于某种同步串行数据：一个输出（例如“A”）表示“时钟”信号，而另一个输出（“B”）表示“数据”信号。
您可以自由选择哪个输出用于哪个信号，以及您选择的“时钟”极性。算法相当简单：
（去噪和）在“时钟”信号上检测上升（或下降，您可以选择）转换
一旦检测到“时钟”边缘，只需读取“数据”信号的电平-这里不需要去噪
然后读取的单个“data”位直接指示编码器刚刚进入的方向：“0”或“1”，一个方向或另一个方向。
在伪代码中，这可能看起来像：

bit lastClockState;

void readEncoder() {

    bit currentClockState = readClockPin();

    if ( lastClockState == 1 && currentClockState == 0 ) {
        // A (falling) edge was detected...

        // Get the direction of the rotation:
        bit direction = readDataPin();

        if ( direction == 1 ) {
            value++;
        } else {
            value--;
        }
    }

    lastClockState = currentClockState; // Update the lastClockState for the next iteration

}

例如，让它每隔10毫秒执行一次，你就已经有了一些极简的“免费”去弹跳。
（顺便说一下，总结一下许多其他人之前学到的经验：不要试图使用一些外部/引脚变化中断来检测任何机械开关或机械编码器产生的（未消除噪声的）信号转换。机械元件的反弹特性将确保其永远不会按预期工作。）