qbasic - QBasic:如何从另一个程序中运行一个程序？

我在QBasic中制作了两个不同的程序，它们都保存在不同的.bas文件中，即一个是1.bas，另一个是2.bas。

当我在程序2.bas中时如何打开程序1.bas而不关闭它？

程序1应该在程序2内运行一段时间，到结束时，我应该再次进入程序2。有什么办法吗？

我想知道在QBasic和/或QB64中是否有适用的语法。

最佳答案

在Qbasic中，您可以使用CHAIN命令将控制权传递给另一个.BAS文件，完成后它将返回第一个.BAS文件。您可以将其与COMMON组合以在两个程序之间共享变量。

您也可以使用RUN，但是在QBasic中您不能传递变量（不确定，但是我认为控件将不会返回）。在QB64中，可以使用RUN传递变量

请参阅标准COM1_EX.BAS和COM2_EX.BAS作为示例，COM1_EX.BAS的内容：

' == COM1_EX.BAS - COMMON statement programming example ==
DIM Values(1 TO 50)
COMMON Values(), NumValues

PRINT "Enter values one per line. Type 'END' to quit."
NumValues = 0
DO
   INPUT "-> ", N$
   IF I >= 50 OR UCASE$(N$) = "END" THEN EXIT DO
   NumValues = NumValues + 1
   Values(NumValues) = VAL(N$)
LOOP
PRINT "Leaving COM1_EX.BAS to chain to COM2_EX.BAS"
PRINT "Press any key to chain... "
DO WHILE INKEY$ = ""
LOOP

CHAIN "com2_ex"

COM2_EX.BAS的内容：

' == COM2_EX.BAS - COMMON statement programming example ==
' Notice that the variables Values() and NumValues from COM1_EX
' will be called X() and N here in COM2_EX
DIM X(1 TO 50)
COMMON X(), N

PRINT
PRINT "Now executing file com2_ex.bas, reached through a CHAIN command"
IF N > 0 THEN
   Sum = 0
   FOR I = 1 TO N
      Sum = Sum + X(I)
   NEXT I
   PRINT "The average of the values is"; Sum / N
END IF