c - 带有C的汇编器-段错误

我有两个文件：f1.S，其中是用汇编语言编写的Fibonacci函数（计数Fibonacci序列的第n个成员）；f2.c，其中调用Fibonacci函数。
以下是这些文件：
一楼

.global fibonacci
fibonacci:

push %rbp
movq %rsp, %rbp
push %rax

movq 16(%rbp), %rax

cmp $0, %rax
je zeroValue
cmp $1, %rax
je oneValue
jmp more

zeroValue:
addq $0, %r8
jmp end

oneValue:
addq $1, %r8
jmp end

more:
movq 16(%rbp), %rax
dec %rax
pushq %rax
call fibonacci
movq 16(%rbp), %rax
dec %rax
dec %rax
pushq %rax
call fibonacci

end:
mov %rbp, %rsp
pop %rbp
ret

二层c

#include <stdio.h>
extern int fibonacci (int);
int main ()
{
    int n = 6;
    int res;
    res = fibonacci(n);
    printf ("N-th member of Fibonacci sequence is: %d", res);
    return 0;
}

要编译和链接，我要执行以下命令：

as f1.S -o f1.o

gcc f2.c -c -o f2.o

gcc f2.o f1.o -o program

一切正常，直到我试图运行我的exe文件（程序）。我无法运行它，因为我收到消息：分段错误。我做错什么了？
Fibonacci函数是肯定的，因为我在干净的汇编程序中使用它，然后它工作了。

最佳答案

在gdb中，你会得到这样的SIGSEGV：

Program received signal SIGSEGV, Segmentation fault.
fibonacci () at f1.S:6
6   push %rax

更有趣的是你的回溯（结尾）：

(gdb) backtrace -10
#1048280 0x00007fffffffe6e0 in ?? ()
#1048281 0x000000000040056d in more () at f1.S:28
#1048282 0x00007fffffffe7fe in ?? ()
#1048283 0x00007fffffffe7ff in ?? ()
#1048284 0x00007fffffffe700 in ?? ()
#1048285 0x000000000040056d in more () at f1.S:28
#1048286 0x00007fffffffe7ff in ?? ()
#1048287 0x0000000000000006 in ?? ()
#1048288 0x00007fffffffe720 in ?? ()
#1048289 0x000000000040051f in main () at f2.c:7
Backtrace stopped: previous frame inner to this frame (corrupt stack?)

所以你设法调用你的递归1048289次。。。
此外，在第8行（movq 16(%rbp), %rax）之后，您将得到：

(gdb) i r rax
rax            0x7fffffffe800   140737488349184

从你的函数来看，rax应该是一个计数器。
由于您使用的是64位寄存器，我假设您运行的是x86_64体系结构which doesn't store arguments on stack，但使用的是寄存器：
如果类是整数，则使用序列%rdi、%rsi、%rdx、%rcx、%r8和%r9的下一个可用寄存器

(gdb) i r edi
edi            0x6  6

您的解决方案可能在cdecl calling convention上运行良好，但在Microsoft x64调用约定或System V AMD64 ABI上运行不好。
例如，完成此操作的方法是（适用于System V AMD64 ABI）：

.global fibonacci
fibonacci:

push %rbp
push %rdi

cmp $0, %rdi
je zeroValue
cmp $1, %rdi
je oneValue
jmp more

zeroValue:
    movq $0, %rax
    jmp end

oneValue:
    movq $1, %rax
    jmp end

more:
    dec %rdi
    call fibonacci
    push %rax
    dec %rdi
    call fibonacci
    pop %r8
    add %r8, %rax

end:
    pop %rdi
    pop %rbp
    ret

就像：
存储rbp
存储rdi
如果rdi==0：返回0
如果rdi==1：返回1
降低rdi
叫斐波那契
将结果存储在堆栈上
降低rdi
叫斐波那契
将结果还原到r8
将r8添加到结果中
恢复rdi
恢复rbp
出于好奇，这里有一个没有递归的版本，只有一个循环（很少有处理低值的情况）：

.global fibonacci
fibonacci:

cmp $2, %rdi # 2 and higher should be computer normally
jg compute

cmp $0, %rdi
jz zero
mov $1, %rax # 1st and 2nd elements = 1
ret

zero:
    mov $0, %rax
    ret

compute:
    mov %rdi, %rcx  # Use cpu counter register
    sub $2, %rcx    # The first number that will come out of this loop
                    # is 2, so decrease number of iterations
    mov $1, %r8     # a = 1
    mov $1, %r9     # b = 1

begin_iter:
    mov %r9, %rax   # sum = b
    add %r8, %rax   # sum += a
    mov %r9, %r8    # a = b
    mov %rax, %r9   # b = a

    loop begin_iter

    ret