sed - sed给我“::意外的EOF(待定}错误)，我不知道为什么

我正在尝试将GNU sed命令移植到BSD sed(在OSX中)。该命令是:

cat -- "$1" | sed -n -e "\${/^#/H;x;/${tapPrintTapOutputSedPattern}/p;}" \
-e "/${tapPrintTapOutputSedPattern}/{x;/${tapPrintTapOutputSedPattern}/p;b;}" \
-e "/^#/{H;b;}" \
-e "x;/${tapPrintTapOutputSedPattern}/p" \
-e "/^Bail out!/q"

它适用于GNU sed，但BSD sed会出现此错误:

sed: 2: "/^Bail out!/q
": unexpected EOF (pending }'s)

如果相关，这是变量扩展后的命令:

cat -- "test021.tap" | sed -n \
-e "\${/^#/H;x;/^not ok\|^ok \([0-9]\+ \)\?# [tT][oO][dD][oO]\|^Bail out!/p;}" \
-e "/^not ok\|^ok \([0-9]\+ \)\?# [tT][oO][dD][oO]\|^Bail out!/{x;/^not ok\|^ok \([0-9]\+ \)\?# [tT][oO][dD][oO]\|^Bail out!/p;b;}" \
-e "/^#/{H;b;}" \
-e "x;/^not ok\|^ok \([0-9]\+ \)\?# [tT][oO][dD][oO]\|^Bail out!/p" \
-e "/^Bail out!/q"

关于为什么/如何解决它的任何想法？

干杯!

最佳答案

至少在语句中的分支命令(b)之前，尝试使用换行符代替分号。查看是否可行:

sed -n "
  \${
    /^#/H
    x
    /${tapPrintTapOutputSedPattern}/p
  }
  /${tapPrintTapOutputSedPattern}/{
    x
    /${tapPrintTapOutputSedPattern}/p
    b
  }
  /^#/{
    H
    b
  }
  x
  /${tapPrintTapOutputSedPattern}/p
  /^Bail out!/q
" "$1"