得益于有关Stackoverflow的明智问题和解答,例如Best way to implement observer pattern in Delphi和Are there any Videos/Screen casts or other resources on how to use Interfaces in Delphi?,在Delphi中有很好的Observer模式示例。从这些stackoverflow问题中,提取了以下指导性材料链接:
Joanna Carter's blog
SourceMaking site
TDelphiHobbyist's blog
itte.no site
dunit's DUnitWizard
在第二个stackoverflow问题中,mghie将dunit's DUnitWizard's XPObserver.pas
描述为非常有趣,而其他XP*.pas
则值得仔细研究。但是,仅在两个地方引用XPObserver
单元,在dunit\Contrib\DUnitWizard\Source\Common\dunit\XPObserverTests.pas
中,测试的唯一目的似乎是检查引用计数,而在dunit\Contrib\DUnitWizard\Source\DelphiExperts\DUnitProject\XPTestedUnitUtils.pas
中,仅使用XPObserver单元中声明的IXPFamily类型。
因此,我想知道使用此XPObserver
单元的最佳实践是什么。
例如:设计问题,例如:
(1)如何使用XPObserver
单元实现观察者模式以执行某些操作?
(2)如何使用XPObserver
实现MVC模式?
或编码类似的问题:
(3)声称XPObserver
的TXPSubjects
提供启用single observer<->multiple subject
关系的功能。但是,FSubjects
被声明为私有。也没有吸气剂。我不知道这是设计使然吗? (例如,作者用// ...***DON'T*** refactor this method!!
编写了TXPSubject.DeleteObserver
。因此,我不确定修改代码,因为我无法完全理解此代码,也许还无法完全理解其他部分。)如果是这样,使用TXPSubjects启用的假定方式是什么? single observer<->multiple subject
关系?
非常感谢您的宝贵时间和意见!
最佳答案
让我为您提供一个示例,说明如何使用XPObserver单元。首先是几个用于模拟数据模型的接口:
type
IColorChannel = interface(IXPSubject)
function GetValue: byte;
procedure RandomChange;
end;
IColorChannelObserver = interface(IXPObserver)
['{E1586F8F-32FB-4F77-ACCE-502AFDAF0EC0}']
procedure Changed(const AChannel: IColorChannel);
end;
IColor = interface(IXPSubject)
function GetValue: TColor;
end;
IColorObserver = interface(IXPObserver)
['{0E5D2FEC-5585-447B-B242-B9B57FC782F2}']
procedure Changed(const AColor: IColor);
end;
IColorChannel
只是包装一个byte
值,它具有返回值并随机更改它的方法。注册其自己的IColorChannelObserver
接口的实现者也可以观察到它。IColor
只是包装一个TColor
值,它只有一个返回值的方法。注册其自己的IColorObserver
接口的实现者也可以观察到它。一个实现
IColorChannel
的类,对此没有什么困难:type
TColorChannel = class(TXPSubject, IColorChannel)
function GetValue: byte;
procedure RandomChange;
private
fValue: byte;
end;
function TColorChannel.GetValue: byte;
begin
Result := fValue;
end;
procedure TColorChannel.RandomChange;
var
Value, Idx: integer;
Icco: IColorChannelObserver;
begin
Value := Random(256);
if fValue <> Value then begin
fValue := Value;
for Idx := 0 to ObserverCount - 1 do begin
// Or use the Supports() function instead of QueryInterface()
if GetObserver(Idx).QueryInterface(IColorChannelObserver, Icco) = S_OK then
Icco.Changed(Self);
end;
end;
end;
现在,一个为RGB实现
IColor
的类,它将包含并观察TColorChannel
的三个实例-即单个观察者与多个主题的关系:type
TRGBColor = class(TXPSubject, IColor, IColorChannelObserver)
function GetValue: TColor;
private
fRed: IColorChannel;
fGreen: IColorChannel;
fBlue: IColorChannel;
fValue: TColor;
function InternalUpdate: boolean;
public
constructor Create(ARed, AGreen, ABlue: IColorChannel);
procedure Changed(const AChannel: IColorChannel);
end;
constructor TRGBColor.Create(ARed, AGreen, ABlue: IColorChannel);
begin
Assert(ARed <> nil);
Assert(AGreen <> nil);
Assert(ABlue <> nil);
inherited Create;
fRed := ARed;
fRed.AddObserver(Self, fRed);
fGreen := AGreen;
fGreen.AddObserver(Self, fGreen);
fBlue := ABlue;
fBlue.AddObserver(Self, fBlue);
InternalUpdate;
end;
procedure TRGBColor.Changed(const AChannel: IColorChannel);
var
Idx: integer;
Ico: IColorObserver;
begin
if InternalUpdate then
for Idx := 0 to ObserverCount - 1 do begin
if GetObserver(Idx).QueryInterface(IColorObserver, Ico) = S_OK then
Ico.Changed(Self);
end;
end;
function TRGBColor.GetValue: TColor;
begin
Result := fValue;
end;
function TRGBColor.InternalUpdate: boolean;
var
Value: TColor;
begin
Result := False;
Value := RGB(fRed.GetValue, fGreen.GetValue, fBlue.GetValue);
if fValue <> Value then begin
fValue := Value;
Result := True;
end;
end;
如果三个通道值中的任何一个发生更改,颜色将应用更改,并依次通知所有其观察者。
现在使用这些类的数据模块:
type
TDataModule1 = class(TDataModule)
procedure DataModuleCreate(Sender: TObject);
private
fRed: IColorChannel;
fGreen: IColorChannel;
fBlue: IColorChannel;
fColor: IColor;
public
property BlueChannel: IColorChannel read fBlue;
property GreenChannel: IColorChannel read fGreen;
property RedChannel: IColorChannel read fRed;
property Color: IColor read fColor;
end;
procedure TDataModule1.DataModuleCreate(Sender: TObject);
begin
Randomize;
fRed := TColorChannel.Create;
fGreen := TColorChannel.Create;
fBlue := TColorChannel.Create;
fColor := TRGBColor.Create(fRed, fGreen, fBlue);
end;
最后是使用该数据模块并且仅了解接口而不了解实现类的表单:
type
TForm1 = class(TForm, IXPObserver, IColorChannelObserver, IColorObserver)
Button1: TButton;
Button2: TButton;
Button3: TButton;
StatusBar1: TStatusBar;
procedure FormCreate(Sender: TObject);
procedure FormDestroy(Sender: TObject);
procedure ButtonClick(Sender: TObject);
public
procedure Changed(const AChannel: IColorChannel); overload;
procedure Changed(const AColor: IColor); overload;
procedure ReleaseSubject(const Subject: IXPSubject;
const Context: pointer);
private
fChannels: array[0..2] of IColorChannel;
fColor: IColor;
end;
procedure TForm1.FormCreate(Sender: TObject);
var
Idx: integer;
begin
Button1.Caption := 'red';
Button1.Tag := 0;
fChannels[0] := DataModule1.RedChannel;
Button2.Caption := 'green';
Button2.Tag := 1;
fChannels[1] := DataModule1.GreenChannel;
Button3.Caption := 'blue';
Button3.Tag := 2;
fChannels[2] := DataModule1.BlueChannel;
for Idx := 0 to 2 do
fChannels[Idx].AddObserver(Self, fChannels[Idx]);
fColor := DataModule1.Color;
fColor.AddObserver(Self, fColor);
end;
procedure TForm1.FormDestroy(Sender: TObject);
var
Idx: integer;
begin
for Idx := Low(fChannels) to High(fChannels) do
fChannels[Idx].DeleteObserver(Self);
fColor.DeleteObserver(Self);
end;
procedure TForm1.ButtonClick(Sender: TObject);
var
Button: TButton;
begin
Button := Sender as TButton;
if (Button.Tag >= Low(fChannels)) and (Button.Tag <= High(fChannels)) then
fChannels[Button.Tag].RandomChange;
end;
procedure TForm1.Changed(const AChannel: IColorChannel);
var
Idx: integer;
begin
Assert(AChannel <> nil);
for Idx := Low(fChannels) to High(fChannels) do
if fChannels[Idx] = AChannel then begin
while StatusBar1.Panels.Count <= Idx do
StatusBar1.Panels.Add;
StatusBar1.Panels[Idx].Text := IntToStr(AChannel.GetValue);
break;
end;
end;
procedure TForm1.Changed(const AColor: IColor);
begin
Assert(AColor <> nil);
Color := AColor.GetValue;
end;
procedure TForm1.ReleaseSubject(const Subject: IXPSubject;
const Context: pointer);
var
Idx: integer;
begin
// necessary if the objects implementing IXPSubject are not reference-counted
for Idx := Low(fChannels) to High(fChannels) do begin
if Subject = fChannels[Idx] then
fChannels[Idx] := nil;
end;
if Subject = fColor then
fColor := nil;
end;
该表单实现了接口,但没有引用计数。它注册自己以观察数据模块的四个属性中的每一个,只要颜色通道发生更改,它就会在状态栏窗格中显示该值,当颜色更改时,它将更新其自己的背景色。有一些按钮可以随机更改颜色通道。
数据模块属性和更改数据的其他方法可能同时拥有更多的观察者。
使用FastMM4在Delphi 5和Delphi 2009中进行了测试,没有内存泄漏。当表单中的每个
DeleteObserver()
没有匹配的AddObserver()
调用时,将发生泄漏。