java - ANTLR4不能正确处理左递归

我正在尝试使用ANTLR4描述逻辑表达式的语法。
当然，这种语法具有直接的左递归功能，正如我读过的ANTLR4支持的那样。

grammar Logic;
@header {
package parser;
import expression.*;
}

expression returns [Expression value] : disjunction {$value = $disjunction.value;}
                                      | disjunction IMPLIES expression {$value = new Implication($disjunction.value, $expression.value);};

disjunction returns [Expression value] : conjunction {$value = $conjunction.value;}
                                       | disjunction OR conjunction {$value = new Disjunction($disjunction.value, $conjunction.value);};

conjunction returns [Expression value] : negation {$value = $negation.value;}
                                       | conjunction AND negation {$value = new Conjunction($conjunction.value, $negation.value);};

negation returns [Expression value] : variable {$value = $variable.value;}
                                    | NOT negation {$value = new Negation($negation.value);}
                                    | OB expression CB {$value = $expression.value;};

variable returns [Expression value] : VAR {$value = new Variable($VAR.text);};

IMPLIES : '->';
OR : '|';
AND : '&';
NOT : '!';
OB : '(';
CB : ')';
VAR : [A-Z]([0-9])*;

但是，当我运行antlr为我的语法生成解析器时，会出现一些奇怪的错误：

error(65): Logic.g4:5:125: unknown attribute value for rule disjunction in $disjunction.value
error(65): Logic.g4:5:125: unknown attribute value for rule conjunction in $conjunction.value

当我在析取规则中交换析取和合取，使析取右关联时，它是可行的，但这会在我的工作中引起一些错误。

可能很重要，我使用Intellij Idea的ANTLR4-插件生成了解析器。

我究竟做错了什么？
先感谢您。

最佳答案

在代码中引用disjunction时：

disjunction returns [Expression value]
 : conjunction {$value = $conjunction.value;}
 | disjunction OR conjunction {$value = new Disjunction($disjunction.value, $conjunction.value);}
 ;

如果您执行value而不是$disjunction中的disjunction，则ANTLR会尝试获取整个封闭规则的disjunction OR ...。

如果要在disjunction中引用disjunction OR ...，则需要在引用之前对其进行标记：

disjunction returns [Expression value]
 : c1=conjunction                  {$value = $c1.value;}
 | d=disjunction OR c2=conjunction {$value = new Disjunction($d.value, $c2.value);}
 ;

这是一个完整的（经过测试的）示例：

grammar Logic;

@header {
  import expression.*;
}

expression returns [Expression value]
 : d1=disjunction                      {$value = $d1.value;}
 | d2=disjunction IMPLIES e=expression {$value = new Implication($d2.value, $e.value);}
 ;

disjunction returns [Expression value]
 : c1=conjunction                  {$value = $c1.value;}
 | d=disjunction OR c2=conjunction {$value = new Disjunction($d.value, $c2.value);}
 ;

conjunction returns [Expression value]
 : n1=negation                   {$value = $n1.value;}
 | c=conjunction AND n2=negation {$value = new Conjunction($c.value, $n2.value);}
 ;

negation returns [Expression value]
 : variable         {$value = $variable.value;}
 | NOT n=negation   {$value = new Negation($n.value);}
 | OB expression CB {$value = $expression.value;}
 ;

variable returns [Expression value]
 : VAR {$value = new Variable($VAR.text);}
 ;

IMPLIES : '->';
OR      : '|';
AND     : '&';
NOT     : '!';
OB      : '(';
CB      : ')';
VAR     : [A-Z]([0-9])*;
SPACE   : [ \t\r\n] -> skip;