haskell - 一般 zipper zipper

对于任何容器类型，我们都可以形成(以元素为中心) zipper ，并且知道此结构是Comonad。最近在another Stack Overflow question中针对以下类型对此进行了详细的探讨:

data Bin a = Branch (Bin a) a (Bin a) | Leaf a deriving Functor

使用以下 zipper

data Dir = L | R
data Step a = Step a Dir (Bin a)   deriving Functor
data Zip  a = Zip [Step a] (Bin a) deriving Functor
instance Comonad Zip where ...

尽管Zip的实例的构造有点毛茸茸，但确实是Comonad。就是说，Zip可以完全从Tree完全机械地派生，并且(我相信)以这种方式派生的任何类型都会自动成为Comonad，因此我认为应该可以通用且自动地构造这些类型及其同名物。

实现 zipper 构造通用性的一种方法是使用以下类和类型族

data Zipper t a = Zipper { diff :: D t a, here :: a }

deriving instance Diff t => Functor (Zipper t)

class (Functor t, Functor (D t)) => Diff t where
  data D t :: * -> *
  inTo  :: t a -> t (Zipper t a)
  outOf :: Zipper t a -> t a

(或多或少)出现在Haskell Cafe主题和Conal Elliott的博客中。可以为各种核心代数类型实例化此类，从而提供了讨论ADT派生类的通用框架。

所以，最终，我的问题是我们是否可以写

instance Diff t => Comonad (Zipper t) where ...

可以用来包含上述特定的Comonad实例:

instance Diff Bin where
  data D Bin a = DBin { context :: [Step a], descend :: Maybe (Bin a, Bin a) }
  ...

不幸的是，我没有写过这样的实例的运气。 inTo / outOf签名是否足够？还需要其他约束类型吗？这个实例有可能吗？

最佳答案

就像Chitty-Chitty-Bang-Bang中吸引 child 的人一样，他们将糖果和玩具吸引到囚禁中，大学物理专业的招聘人员喜欢用肥皂泡和飞旋镖来愚弄，但是当门c关闭时，这是“对了， children ，有时间学习关于部分分化!”。我也是。不要说我没有警告过你。

这是另一个警告:以下代码需要{-# LANGUAGE KitchenSink #-}，或者更确切地说

{-# LANGUAGE TypeFamilies, FlexibleContexts, TupleSections, GADTs, DataKinds,
    TypeOperators, FlexibleInstances, RankNTypes, ScopedTypeVariables,
    StandaloneDeriving, UndecidableInstances #-}

没有特别的顺序。

可微分的函子提供普通 zipper

到底什么是可微函子？

class (Functor f, Functor (DF f)) => Diff1 f where
  type DF f :: * -> *
  upF      ::  ZF f x  ->  f x
  downF    ::  f x     ->  f (ZF f x)
  aroundF  ::  ZF f x  ->  ZF f (ZF f x)

data ZF f x = (:<-:) {cxF :: DF f x, elF :: x}

它是一个具有导数的函子，它也是一个函子。导数表示元素的单孔上下文。 zipper 类型ZF f x表示一对单孔上下文和该孔中的元素。
Diff1的操作描述了我们可以在 zipper 上进行的导航的类型(没有“向左”和“向右”的任何概念，有关这些信息，请参见Clowns and Jokers论文)。我们可以“向上”，通过将元素插入孔中来重新组装结构。我们可以“向下”，找到在给定结构中访问元素的各种方法:我们用元素的上下文装饰每个元素。我们可以“转转”，
使用现有的 zipper 并用其上下文装饰每个元素，因此我们找到了重新聚焦的所有方法(以及如何保持当前的聚焦)。

现在，aroundF的类型可能会让您想起某些

class Functor c => Comonad c where
  extract    :: c x -> x
  duplicate  :: c x -> c (c x)

提醒您，您是对的!我们有一跳又一跳

instance Diff1 f => Functor (ZF f) where
  fmap f (df :<-: x) = fmap f df :<-: f x

instance Diff1 f => Comonad (ZF f) where
  extract    = elF
  duplicate  = aroundF

我们坚持认为

extract . duplicate == id
fmap extract . duplicate == id
duplicate . duplicate == fmap duplicate . duplicate

我们还需要

fmap extract (downF xs) == xs              -- downF decorates the element in position
fmap upF (downF xs) = fmap (const xs) xs   -- downF gives the correct context

多项式函子是可微的

常数函子是可微的。

data KF a x = KF a
instance Functor (KF a) where
  fmap f (KF a) = KF a

instance Diff1 (KF a) where
  type DF (KF a) = KF Void
  upF (KF w :<-: _) = absurd w
  downF (KF a) = KF a
  aroundF (KF w :<-: _) = absurd w

无处可放元素，因此不可能形成上下文。无处可去upF或downF，我们很容易找到所有去downF的方法。

身份函子是可区分的。

data IF x = IF x
instance Functor IF where
  fmap f (IF x) = IF (f x)

instance Diff1 IF where
  type DF IF = KF ()
  upF (KF () :<-: x) = IF x
  downF (IF x) = IF (KF () :<-: x)
  aroundF z@(KF () :<-: x) = KF () :<-: z

琐碎的上下文中只有一个元素，downF找到它，upF重新打包它，aroundF只能保留。

和保留可区分性。

data (f :+: g) x = LF (f x) | RF (g x)
instance (Functor f, Functor g) => Functor (f :+: g) where
  fmap h (LF f) = LF (fmap h f)
  fmap h (RF g) = RF (fmap h g)

instance (Diff1 f, Diff1 g) => Diff1 (f :+: g) where
  type DF (f :+: g) = DF f :+: DF g
  upF (LF f' :<-: x) = LF (upF (f' :<-: x))
  upF (RF g' :<-: x) = RF (upF (g' :<-: x))

其他零碎的部分很少。要使用downF，我们必须在加标签的组件中使用downF，然后修复生成的 zipper 以在上下文中显示标签。

  downF (LF f) = LF (fmap (\ (f' :<-: x) -> LF f' :<-: x) (downF f))
  downF (RF g) = RF (fmap (\ (g' :<-: x) -> RF g' :<-: x) (downF g))

要使用aroundF，我们要剥离标签，弄清楚如何处理未加标签的东西，然后在所有生成的 zipper 中恢复标签。焦点中的元素x被其整个 zipper z取代。

  aroundF z@(LF f' :<-: (x :: x)) =
    LF (fmap (\ (f' :<-: x) -> LF f' :<-: x) . cxF $ aroundF (f' :<-: x :: ZF f x))
    :<-: z
  aroundF z@(RF g' :<-: (x :: x)) =
    RF (fmap (\ (g' :<-: x) -> RF g' :<-: x) . cxF $ aroundF (g' :<-: x :: ZF g x))
    :<-: z

请注意，我必须使用ScopedTypeVariables消除对aroundF的递归调用。作为类型函数，DF不具有内射性，因此f' :: D f x不足以强制f' :<-: x :: Z f x。

产品保留差异性。

data (f :*: g) x = f x :*: g x
instance (Functor f, Functor g) => Functor (f :*: g) where
  fmap h (f :*: g) = fmap h f :*: fmap h g

要专注于成对的元素，您可以专注于左侧，而不理会右侧，反之亦然。莱布尼兹著名的乘积法则与简单的空间直觉相对应!

instance (Diff1 f, Diff1 g) => Diff1 (f :*: g) where
  type DF (f :*: g) = (DF f :*: g) :+: (f :*: DF g)
  upF (LF (f' :*: g) :<-: x) = upF (f' :<-: x) :*: g
  upF (RF (f :*: g') :<-: x) = f :*: upF (g' :<-: x)

现在，downF的工作方式与求和方式类似，不同之处在于，我们不仅必须使用标签(以显示出前进的方式)而且还应使用未经改动的其他组件来修复 zipper 上下文。

  downF (f :*: g)
    =    fmap (\ (f' :<-: x) -> LF (f' :*: g) :<-: x) (downF f)
    :*:  fmap (\ (g' :<-: x) -> RF (f :*: g') :<-: x) (downF g)

但是aroundF是一大堆笑声。无论我们当前正在访问哪一侧，我们都有两种选择:

在那一侧移动aroundF。

将upF移出另一侧，并将downF移到另一侧。

每种情况都要求我们利用子结构的操作，然后修正上下文。

  aroundF z@(LF (f' :*: g) :<-: (x :: x)) =
    LF (fmap (\ (f' :<-: x) -> LF (f' :*: g) :<-: x)
          (cxF $ aroundF (f' :<-: x :: ZF f x))
        :*: fmap (\ (g' :<-: x) -> RF (f :*: g') :<-: x) (downF g))
    :<-: z
    where f = upF (f' :<-: x)
  aroundF z@(RF (f :*: g') :<-: (x :: x)) =
    RF (fmap (\ (f' :<-: x) -> LF (f' :*: g) :<-: x) (downF f) :*:
        fmap (\ (g' :<-: x) -> RF (f :*: g') :<-: x)
          (cxF $ aroundF (g' :<-: x :: ZF g x)))
    :<-: z
    where g = upF (g' :<-: x)

!多项式都是可微的，因此给我们带来了共鸣。

嗯有点抽象。所以我在所有可能的地方都添加了deriving Show，然后加入

deriving instance (Show (DF f x), Show x) => Show (ZF f x)

允许进行以下互动(手动整理)

> downF (IF 1 :*: IF 2)
IF (LF (KF () :*: IF 2) :<-: 1) :*: IF (RF (IF 1 :*: KF ()) :<-: 2)

> fmap aroundF it
IF  (LF (KF () :*: IF (RF (IF 1 :*: KF ()) :<-: 2)) :<-: (LF (KF () :*: IF 2) :<-: 1))
:*:
IF  (RF (IF (LF (KF () :*: IF 2) :<-: 1) :*: KF ()) :<-: (RF (IF 1 :*: KF ()) :<-: 2))

练习使用链规则显示可微函子的组成是可微的。

甜!我们现在可以回家吗？当然不是。我们尚未区分任何递归结构。

用bifunctors构造递归函子

正如关于数据类型泛型编程的现有文献(请参阅Patrik Jansson和Johan Jeuring的工作，或Jeremy Gibbons的出色的讲义)所言，Bifunctor详细解释了一种带有两个参数的类型构造函数，分别对应于两种子结构。我们应该能够“映射”两者。

class Bifunctor b where
  bimap :: (x -> x') -> (y -> y') -> b x y -> b x' y'

我们可以使用Bifunctor给出递归容器的节点结构。每个节点都有子节点和元素。这些可能只是两种子结构。

data Mu b y = In (b (Mu b y) y)

看到？我们在b的第一个参数中“打结递归结”，并在参数y的第二个参数中保留它。因此，我们一劳永逸

instance Bifunctor b => Functor (Mu b) where
  fmap f (In b) = In (bimap (fmap f) f b)

要使用此功能，我们需要一套Bifunctor实例。

Bifunctor套件

常量是双向的。

newtype K a x y = K a

instance Bifunctor (K a) where
  bimap f g (K a) = K a

您可以说我首先写了这一点，因为标识符较短，但这很好，因为代码较长。

变量是双向的。

我们需要对应于一个参数或另一个参数的双功能键，因此我创建了一种数据类型以区分它们，然后定义了合适的GADT。

data Var = X | Y

data V :: Var -> * -> * -> * where
  XX :: x -> V X x y
  YY :: y -> V Y x y

这使得V X x y成为x的副本，而V Y x y成为y的副本。相应地

instance Bifunctor (V v) where
  bimap f g (XX x) = XX (f x)
  bimap f g (YY y) = YY (g y)

求和和双向功能的产品是双向功能

data (:++:) f g x y = L (f x y) | R (g x y) deriving Show

instance (Bifunctor b, Bifunctor c) => Bifunctor (b :++: c) where
  bimap f g (L b) = L (bimap f g b)
  bimap f g (R b) = R (bimap f g b)

data (:**:) f g x y = f x y :**: g x y deriving Show

instance (Bifunctor b, Bifunctor c) => Bifunctor (b :**: c) where
  bimap f g (b :**: c) = bimap f g b :**: bimap f g c

到目前为止，样板好，但是现在我们可以定义类似

List = Mu (K () :++: (V Y :**: V X))

Bin = Mu (V Y :**: (K () :++: (V X :**: V X)))

如果您想将这些类型用于实际数据，而又不想在乔治·塞拉特(Georges Seurat)的笨拙传统中视而不见，请使用模式同义词。

但是 zipper 呢？我们如何证明Mu b是可区分的？我们将需要证明b在两个变量中是可微的。铛!现在是时候了解部分差异化了。

双功能的偏导数

因为我们有两个变量，所以我们将需要能够有时在其他时间集体讨论它们。我们将需要单例家庭:

data Vary :: Var -> * where
  VX :: Vary X
  VY :: Vary Y

现在我们可以说一个Bifunctor在每个变量中具有偏导数，并给出相应的zipper概念。

class (Bifunctor b, Bifunctor (D b X), Bifunctor (D b Y)) => Diff2 b where
  type D b (v :: Var) :: * -> * -> *
  up      :: Vary v -> Z b v x y -> b x y
  down    :: b x y -> b (Z b X x y) (Z b Y x y)
  around  :: Vary v -> Z b v x y -> Z b v (Z b X x y) (Z b Y x y)

data Z b v x y = (:<-) {cxZ :: D b v x y, elZ :: V v x y}

此D操作需要知道要定位的变量。相应的 zipper Z b v告诉我们哪个变量v必须是焦点。当我们“用上下文装饰”时，我们必须用x -contexts装饰X -elements和用y -contexts装饰Y -elements。但除此之外，这是同一回事。

我们还有两个任务:首先，证明我们的bifunctor套件是可区分的。其次，证明Diff2 b允许我们建立Diff1 (Mu b)。

区分Bifunctor套件

恐怕这不是摆弄，而是教化。随时跳过。

常数与以前一样。

instance Diff2 (K a) where
  type D (K a) v = K Void
  up _ (K q :<- _) = absurd q
  down (K a) = K a
  around _ (K q :<- _) = absurd q

在这种情况下，生命太短了，无法发展类型级别的Kronecker-delta的理论，因此我只对变量进行了单独处理。

instance Diff2 (V X) where
  type D (V X) X = K ()
  type D (V X) Y = K Void
  up VX (K () :<- XX x)  = XX x
  up VY (K q :<- _)      = absurd q
  down (XX x) = XX (K () :<- XX x)
  around VX z@(K () :<- XX x)  = K () :<- XX z
  around VY (K q :<- _)        = absurd q

instance Diff2 (V Y) where
  type D (V Y) X = K Void
  type D (V Y) Y = K ()
  up VX (K q :<- _)      = absurd q
  up VY (K () :<- YY y)  = YY y
  down (YY y) = YY (K () :<- YY y)
  around VX (K q :<- _)        = absurd q
  around VY z@(K () :<- YY y)  = K () :<- YY z

对于结构性案例，我发现引入帮助程序使我能够统一处理变量非常有用。

vV :: Vary v -> Z b v x y -> V v (Z b X x y) (Z b Y x y)
vV VX z = XX z
vV VY z = YY z

然后，我构建了小工具，以简化down和around所需的“重新标记”。 (当然，我在工作时看到了需要哪些小工具。)

zimap :: (Bifunctor c) => (forall v. Vary v -> D b v x y -> D b' v x y) ->
         c (Z b X x y) (Z b Y x y) -> c (Z b' X x y) (Z b' Y x y)
zimap f = bimap
  (\ (d :<- XX x) -> f VX d :<- XX x)
  (\ (d :<- YY y) -> f VY d :<- YY y)

dzimap :: (Bifunctor (D c X), Bifunctor (D c Y)) =>
         (forall v. Vary v -> D b v x y -> D b' v x y) ->
         Vary v -> Z c v (Z b X x y) (Z b Y x y) -> D c v (Z b' X x y) (Z b' Y x y)
dzimap f VX (d :<- _) = bimap
  (\ (d :<- XX x) -> f VX d :<- XX x)
  (\ (d :<- YY y) -> f VY d :<- YY y)
  d
dzimap f VY (d :<- _) = bimap
  (\ (d :<- XX x) -> f VX d :<- XX x)
  (\ (d :<- YY y) -> f VY d :<- YY y)
  d

准备好了很多之后，我们就可以详细研究一下。求和很容易。

instance (Diff2 b, Diff2 c) => Diff2 (b :++: c) where
  type D (b :++: c) v = D b v :++: D c v
  up v (L b' :<- vv) = L (up v (b' :<- vv))
  down (L b) = L (zimap (const L) (down b))
  down (R c) = R (zimap (const R) (down c))
  around v z@(L b' :<- vv :: Z (b :++: c) v x y)
    = L (dzimap (const L) v ba) :<- vV v z
    where ba = around v (b' :<- vv :: Z b v x y)
  around v z@(R c' :<- vv :: Z (b :++: c) v x y)
    = R (dzimap (const R) v ca) :<- vV v z
    where ca = around v (c' :<- vv :: Z c v x y)

产品是艰苦的工作，这就是为什么我是数学家而不是工程师。

instance (Diff2 b, Diff2 c) => Diff2 (b :**: c) where
  type D (b :**: c) v = (D b v :**: c) :++: (b :**: D c v)
  up v (L (b' :**: c) :<- vv) = up v (b' :<- vv) :**: c
  up v (R (b :**: c') :<- vv) = b :**: up v (c' :<- vv)
  down (b :**: c) =
    zimap (const (L . (:**: c))) (down b) :**: zimap (const (R . (b :**:))) (down c)
  around v z@(L (b' :**: c) :<- vv :: Z (b :**: c) v x y)
    = L (dzimap (const (L . (:**: c))) v ba :**:
        zimap (const (R . (b :**:))) (down c))
      :<- vV v z where
      b = up v (b' :<- vv :: Z b v x y)
      ba = around v (b' :<- vv :: Z b v x y)
  around v z@(R (b :**: c') :<- vv :: Z (b :**: c) v x y)
    = R (zimap (const (L . (:**: c))) (down b):**:
        dzimap (const (R . (b :**:))) v ca)
      :<- vV v z where
      c = up v (c' :<- vv :: Z c v x y)
      ca = around v (c' :<- vv :: Z c v x y)

从概念上讲，它和以前一样，但是官僚机构更多。我使用pre-type-hole技术构建了这些文件，使用undefined作为我尚不准备工作的地方的存根，并在一个地方(在任何给定的时间)引入了故意的类型错误，希望从那里获得有用的提示类型检查器。您也可以在电子游戏方面进行类型检查，即使在Haskell中也是如此。

递归容器的子节点 zipper
b相对于X的偏导数告诉我们如何在节点内部一步找到子节点，因此我们得到了传统的zipper概念。

data MuZpr b y = MuZpr
  {  aboveMu  :: [D b X (Mu b y) y]
  ,  hereMu   :: Mu b y
  }

通过重复插入X位置，我们可以一直放大到根。

muUp :: Diff2 b => MuZpr b y -> Mu b y
muUp (MuZpr {aboveMu = [], hereMu = t}) = t
muUp (MuZpr {aboveMu = (dX : dXs), hereMu = t}) =
  muUp (MuZpr {aboveMu = dXs, hereMu = In (up VX (dX :<- XX t))})

但是我们需要元素 zipper 。

元素 zipper 固定点的元素 zipper

每个元素都在节点内部。该节点位于一堆X -derivatives下。但是元素在该节点中的位置由Y -derivative给出。我们得到

data MuCx b y = MuCx
  {  aboveY  :: [D b X (Mu b y) y]
  ,  belowY  :: D b Y (Mu b y) y
  }

instance Diff2 b => Functor (MuCx b) where
  fmap f (MuCx { aboveY = dXs, belowY = dY }) = MuCx
    {  aboveY  = map (bimap (fmap f) f) dXs
    ,  belowY  = bimap (fmap f) f dY
    }

我大胆地说

instance Diff2 b => Diff1 (Mu b) where
  type DF (Mu b) = MuCx b

但是在进行操作之前，我需要点点滴滴。

我可以在functor-zippers和bifunctor-zippers之间交换数据，如下所示:

zAboveY :: ZF (Mu b) y -> [D b X (Mu b y) y]  -- the stack of `X`-derivatives above me
zAboveY (d :<-: y) = aboveY d

zZipY :: ZF (Mu b) y -> Z b Y (Mu b y) y      -- the `Y`-zipper where I am
zZipY (d :<-: y) = belowY d :<- YY y

这足以让我定义:

  upF z  = muUp (MuZpr {aboveMu = zAboveY z, hereMu = In (up VY (zZipY z))})

也就是说，我们首先重新组装元素所在的节点，然后将元素 zipper 变成子节点 zipper ，然后像上面一样一直缩小。

接下来，我说

  downF  = yOnDown []

从空堆栈开始向下，并定义辅助函数，该函数从任何堆栈下面重复进行down:

yOnDown :: Diff2 b => [D b X (Mu b y) y] -> Mu b y -> Mu b (ZF (Mu b) y)
yOnDown dXs (In b) = In (contextualize dXs (down b))

现在，down b仅将我们带入节点内。我们需要的 zipper 还必须带有节点的上下文。这就是contextualise的作用:

contextualize :: (Bifunctor c, Diff2 b) =>
  [D b X (Mu b y) y] ->
  c (Z b X (Mu b y) y) (Z b Y (Mu b y) y) ->
  c (Mu b (ZF (Mu b) y)) (ZF (Mu b) y)
contextualize dXs = bimap
  (\ (dX :<- XX t) -> yOnDown (dX : dXs) t)
  (\ (dY :<- YY y) -> MuCx {aboveY = dXs, belowY = dY} :<-: y)

对于每个Y位置，我们都必须提供一个元素 zipper ，这样很好，我们知道整个上下文dXs返回到根，以及描述元素如何位于其节点中的dY。对于每个X -position，都有另外一个子树可以探索，因此我们扩大堆栈并继续前进!

那只剩下转移重点的事了。我们可能会呆在原地，或者从我们所在的地方走下来，或者上升，或者上升然后再下降。开始。

  aroundF z@(MuCx {aboveY = dXs, belowY = dY} :<-: _) = MuCx
    {  aboveY = yOnUp dXs (In (up VY (zZipY z)))
    ,  belowY = contextualize dXs (cxZ $ around VY (zZipY z))
    }  :<-: z

与以往一样，现有元素被其整个 zipper 取代。对于belowY部分，我们看一下现有节点中还有哪些地方可以找到:我们将找到替代元素Y -positions或其他X -subnodes进行探索，因此我们对其进行contextualise。对于aboveY部分，我们必须在重新组装要访问的节点后，以自己的方式备份X -derivatives堆栈。

yOnUp :: Diff2 b => [D b X (Mu b y) y] -> Mu b y ->
         [D b X (Mu b (ZF (Mu b) y)) (ZF (Mu b) y)]
yOnUp [] t = []
yOnUp (dX : dXs) (t :: Mu b y)
  =  contextualize dXs (cxZ $ around VX (dX :<- XX t))
  :  yOnUp dXs (In (up VX (dX :<- XX t)))

在此过程的每一步，我们都可以转到around的其他地方，或者继续往上走。

就是这样!我没有给出法律的正式证明，但是在我看来，这些操作似乎在爬网结构时仔细地正确维护了上下文。

我们学到了什么？

可区分性引入了上下文中事物的概念，引入了共鸣结构，其中extract为您提供事物，而duplicate探索上下文以寻找其他事物以实现上下文。如果我们对节点具有适当的差分结构，则可以为整棵树开发差分结构。

哦，分别对待类型构造函数的每个Arity显然是可怕的。更好的方法是在索引集之间使用函子

f :: (i -> *) -> (o -> *)

在这里，我们使o具有不同种类的结构，并存储i具有不同种类的元素。这些在雅可比构造下是封闭的

J f :: (i -> *) -> ((o, i) -> *)

其中每个生成的(o, i) -structures都是偏导数，告诉您如何在i -structure中制作o -element-hole。但这又是一次有趣的打字。