delphi - Delphi TDBGrid所选行获取值

我想从TDBGrid的所选行中检索一个值，怎么办？

procedure TForm7.Button2Click(Sender: TObject);
    var
      i, j: Integer;
      s: string;
    begin
      if DBGrid1.SelectedRows.Count>0 then
        with DBGrid1.DataSource.DataSet do
          for i:=0 to DBGrid1.SelectedRows.Count-1 do
          begin
            GotoBookmark(DBGrid1.SelectedRows.Items[i]);
            for j := 0 to FieldCount-1 do
            begin
              if (j>0) then s:=s+', ';
              s := s + FindField(Fields.Fields[j].FieldName).AsString;
            end;
            Listbox1.Items.Add(s);
            s:= '';
          end;
    end;

最佳答案

下面的代码解决了您的一些问题。

主要问题是您没有正确初始化s以及获取所选行的字段的方式存在缺陷。

调用DataSet.Disable/EnableControls和ListBox1.Items.BeginUpdate/EndUpdate可以加快处理速度。

另外，避免像瘟疫一样使用with构造。如您所见，我对局部DataSet变量的使用涉及了最少的额外键入，并避免了使用with时可能出现的各种意外问题。

procedure TForm1.GetSelected;
var
  i,
  J : Integer;
  s : String;
  DataSet : TDataSet;
begin
  if DBGrid1.SelectedRows.Count>0 then begin
    DataSet := DBGrid1.DataSource.DataSet;
   //  with DBGrid1.DataSource.DataSet do
   try
     ListBox1.Items.BeginUpdate;
     DataSet.DisableControls;
     for i:=0 to DBGrid1.SelectedRows.Count-1 do
      begin
        DataSet.GotoBookmark(Pointer(DBGrid1.SelectedRows.Items[i]));
        s := '';
        for j := 0 to DataSet.FieldCount - 1 do
        begin
          if (j>0) then s:=s+', ';
          s := s + DataSet.Fields[j].AsString;
          //s := s + FindField(Fields.Fields[j].FieldName).AsString;
        end;
        Listbox1.Items.Add(s);
        //s:= '';
      end;
    finally
      DataSet.EnableControls;
      ListBox1.Items.EndUpdate;
    end;
  end;
end;

**更新：**

您可以像这样将当前网格行设置为选中状态

DBGrid1.SelectedRows.CurrentRowSelected := True;

更新＃2

网格的选定行存储在名为TBookmarkList的SelectedRow中。要清除当前选择，您需要做的就是调用其Clear方法，如下所示：

procedure TForm1.btnClearSelectedClick(Sender: TObject);
begin
  DBGrid1.SelectedRows.Clear;
end;

同样，如果要清除ListBox，只需调用其Clear方法，如下所示：

procedure TForm1.btnClearListBoxClick(Sender: TObject);
begin
  ListBox1.Clear;
end;

如果您无法让我的代码正常工作，请尝试以下操作：


在对象检查器中，将“ DBGrid选项”属性dgMultiSelect设置为True。
将一个按钮放在窗体上，并在其OnClick处理程序调用GetSelected中。


编译并运行。单击网格中的一行，然后单击按钮。没发生什么事。原因是单击按钮会将焦点移到DBGrid之外，因此就其而言，没有选择任何行。然后尝试步骤3。


再次运行该应用程序。这一次按住Ctrl键，同时单击网格和按钮。这次，选定的行出现在列表框中。按住Ctrl键的同时，单击网格中的另一行，然后单击该按钮。这次，两行都添加到ListBox中。

关于delphi - Delphi TDBGrid所选行获取值，我们在Stack Overflow上找到一个类似的问题：https://stackoverflow.com/questions/41778927/