delphi - Delphi:泛型和TObjectList

我创建了一个像

TMyClass = class(TObject)
private
  FList1: TObjectList<List1>;
  FList2: TObjectList<List2>;
public
end;

现在，我想要一个方法FillArray(Content);，最好应执行一次，即不重载。我相信使用泛型是可行的，但是我对这些野兽实在经验不足，无法真正实现它。有人知道吗？提前致谢！

最佳答案

我相信以下内容仅适用于Delphi2010。由于它取决于系统单元中TArray 的声明，因此如下所示：

  TArray<T> = array of T;

这是我为协助TArray到列表转换而开发的单元

unit ListTools;

interface
uses Generics.Collections;
type
 TListTools = class(TObject)
 public
    // Convert TList<T> to TArray<T>
    class function ToArray<T>(AList: TList<T>): TArray<T>;
    // Append Array elements in AValues to AList
    class procedure AppendList<T>(AList : TList<T>;AValues : TArray<T>);
    // Clear List and Append Values to aList
    class procedure ToList<T>(AList : TList<T>;AValues : TArray<T>);
 end;

implementation

{ TListTools }

class procedure TListTools.AppendList<T>(AList: TList<T>; AValues: TArray<T>);
var
  Element : T;
begin
  for Element in AValues do
  begin
     AList.Add(Element);
  end;
end;

class function TListTools.ToArray<T>(AList: TList<T>): TArray<T>;
// taken from rtti.pas
var
  i : Integer;
begin
  SetLength(Result, AList.Count);
  for i := 0 to AList.Count - 1 do
    Result[i] := AList[i];
end;

class procedure TListTools.ToList<T>(AList: TList<T>; AValues: TArray<T>);
begin
   AList.Clear;
   AppendList<T>(AList,AValues);
end;

end.

由于TList 是TObjectList 的父类，因此它应该与TObjectList 一起使用，尽管我没有尝试过。

关于delphi - Delphi:泛型和TObjectList，我们在Stack Overflow上找到一个类似的问题：https://stackoverflow.com/questions/1642436/