vim - vim中最喜欢的地方

vim中是否有一个命令可以标记一个位置(文件的路径，该文件中的行号)，以便以后可以轻松地转到该位置？

这将类似于NERDTree :Bookmark命令。您可以使用NERDTreeFromBookmark打开文件。我正在寻找相同的功能，不同之处在于书签不仅是文件，而且是文件+行号。

谢谢

最佳答案

viminfo设置可以包含选项!，这使它可以在viminfo文件中存储所有带有大写字母的全局变量。使用此功能，您可以定义一个名为g:BOOKMARKS的变量，并将书签存储在其中。

这是一些vimscript，您可以用来执行此操作:

set viminfo+=!

if !exists('g:BOOKMARKS')
  let g:BOOKMARKS = {}
endif

" Add the current [filename, cursor position] in g:BOOKMARKS under the given
" name
command! -nargs=1 Bookmark call s:Bookmark(<f-args>)
function! s:Bookmark(name)
  let file   = expand('%:p')
  let cursor = getpos('.')

  if file != ''
    let g:BOOKMARKS[a:name] = [file, cursor]
  else
    echom "No file"
  endif

  wviminfo
endfunction

" Delete the user-chosen bookmark
command! -nargs=1 -complete=custom,s:BookmarkNames DelBookmark call s:DelBookmark(<f-args>)
function! s:DelBookmark(name)
  if !has_key(g:BOOKMARKS, a:name)
    return
  endif

  call remove(g:BOOKMARKS, a:name)
  wviminfo
endfunction

" Go to the user-chosen bookmark
command! -nargs=1 -complete=custom,s:BookmarkNames GotoBookmark call s:GotoBookmark(<f-args>)
function! s:GotoBookmark(name)
  if !has_key(g:BOOKMARKS, a:name)
    return
  endif

  let [filename, cursor] = g:BOOKMARKS[a:name]

  exe 'edit '.filename
  call setpos('.', cursor)
endfunction

" Completion function for choosing bookmarks
function! s:BookmarkNames(A, L, P)
  return join(sort(keys(g:BOOKMARKS)), "\n")
endfunction

我不确定代码的可读性，但是基本上，Bookmark命令接受一个参数作为名称。它将当前文件名和光标位置存储到g:BOOKMARKS字典中。您可以将带有标记名称的GotoBookmark命令使用到它。 DelBookmark以相同的方式工作，但是删除给定的标记。这两个功能都已完成制表符。

跳过它们的另一种方法是使用以下命令:

" Open all bookmarks in the quickfix window
command! CopenBookmarks call s:CopenBookmarks()
function! s:CopenBookmarks()
  let choices = []

  for [name, place] in items(g:BOOKMARKS)
    let [filename, cursor] = place

    call add(choices, {
          \ 'text':     name,
          \ 'filename': filename,
          \ 'lnum':     cursor[1],
          \ 'col':      cursor[2]
          \ })
  endfor

  call setqflist(choices)
  copen
endfunction

CopenBookmarks将在quickfix窗口中加载书签，这对我来说似乎是一个不错的界面。

此解决方案类似于Eric的解决方案-它使用.viminfo文件，因此，如果出现问题，您可能会丢掉分数。而且，如果您将标记保存在一个vim实例中，则它们将不会立即在另一个vim实例中使用。

我不知道您对vimscript有多满意，以防万一-为了使用它，您可以将代码放在plugin vimfiles目录下的文件中，例如plugin/bookmarks.vim。应该完全足够了。这也是全部要点:https://gist.github.com/1371174

编辑:稍微更改了解决方案的界面。原始版本可以在要点历史中找到。