excel - 使用高级过滤器获取唯一值不起作用？

我有两张纸：

工作表2：

Column C
Supplier Name
A
A
B
B
C

第1页（所需结果）

Column G
A
B
C

我正在尝试在工作表1的G列中创建唯一的供应商名称列表，如上所示。

我正在使用此代码：

Sub LIST()
    Dim r1 As Range, r2 As Range

    Dim lastrow As Long
    lastrow = Sheets("Data").Cells(Rows.Count, "C").End(xlUp).row

    Set r1 = Sheets("Data").Range("C2:C" & lastrow)
    Set r2 = Sheets("Sheet1").Range("G16")

    r1.AdvancedFilter Action:=xlFilterCopy, CopyToRange:=r2, unique:=True



End Sub

此代码无法正常工作。它显示第一个供应商名称A，如下所示：

工作表1

Column G
A
A
B
C

最佳答案

高级筛选器需要在复制到操作中携带的标题行。由于您尚未添加或包含一个，因此r1.AdvancedFilter命令假定C2是标题行。

将Range("C2:C" & lastrow)更改为Range("C1:C" & lastrow)，以便“高级筛选器”具有标题行。

Sub LIST()
    Dim r1 As Range, r2 As Range

    Dim lastrow As Long
    lastrow = Sheets("Data").Cells(Rows.Count, "C").End(xlUp).Row

    Set r1 = Sheets("Data").Range("C1:C" & lastrow)
    Set r2 = Sheets("Sheet1").Range("G16")

    r1.AdvancedFilter Action:=xlFilterCopy, CopyToRange:=r2, Unique:=True

End Sub

请注意，您将把C1传送到Sheet1！G16。如果不需要，将其删除。

通过直接值传递和RemoveDuplicates代替AdvancedFilter进行替换。

Sub nodupeLIST()
    Dim r1 As Range, lastrow As Long

    With Worksheets("Data")
        lastrow = .Cells(Rows.Count, "C").End(xlUp).Row
        Set r1 = .Range("C2:C" & lastrow)
    End With

    With Worksheets("Sheet1")
        With .Range("G16").Resize(r1.Rows.Count, 1)
            .Cells = r1.Value
            .RemoveDuplicates Columns:=1, Header:=xlNo
        End With
    End With

End Sub

关于excel - 使用高级过滤器获取唯一值不起作用？，我们在Stack Overflow上找到一个类似的问题：https://stackoverflow.com/questions/42940366/