javascript - 带有PEG.js的访问控制字符串(ACS)解析器/解释器

前言

我正在使用PEG.js创建，，coji，，C，，ontrol，，S 、、、、、、、、、、、、， ACS字符串通常用于公告板系统(BBS)，以检查对特定区域的访问权限。例如，参见Renegade's ACS documentation。

示例ACS字符串

以下是一些简化的字符串及其英语翻译，以供说明:

// Has GM123 OR NOT GM456
GM123|!GM456

// Has GM123 OR NOT (GM456 AND GM789) (note: AND is implied in this grammar if not specified)
GM123|!(GM456GM789)

// Has GM123 AND NOT GM456 OR has GM789
GM123!GM456|GM789

// Has GM1 OR (NOT GM2 OR GM3)
GM1|(!GM2|GM3)

我要实现的目标

我在这里想做的是解析和解释(或“运行”)ACS字符串，并最终得到一个最终的 bool(boolean) 值。

到目前为止的语法

以下是到目前为止我掌握的PEG.js语法。请注意，ACS字符串本身比上面的示例要复杂一些(例如，我允许GM ['abc'，'def'])，但我认为到目前为止，这还可以自我解释。

{
  function checkAccessSingle(acsName, arg) {
    return true;
  }

  function checkAccessMulti(acsName, args, anyMatch) {
    return true;
  }

  function makeNot(not, x) {
    return not ? !x : x;
  }
}

start
  = acsString


whitespaceChar
  = ' '

ws
  = whitespaceChar*

lineTerminatorChar
  = [\r\n\u2028\u2029]

decimalDigit
  = [0-9]

integer
  = decimalDigit+ { return parseInt(text(), 10); }

asciiPrintableChar
  = [ -~]

singleAsciiStringChar
  = !("'") asciiPrintableChar { return text(); }

doubleAsciiStringChar
  = !('"') asciiPrintableChar { return text(); }

nonEmptyStringLiteral
  = "'" chars:singleAsciiStringChar+ "'" { return chars.join(''); }
  / '"' chars:doubleAsciiStringChar+ '"' { return chars.join(''); }

AND
  = '&'

OR
  = '|'

NOT
  = '!'

acsName
  = n:([A-Z][A-Z]) { return n.join(''); }

acsArg
  = nonEmptyStringLiteral
  / integer

acsArgs
  = first:acsArg rest:(ws ',' ws a:acsArg { return a; })* {
      var args = [ first ];
      for(var i = 0; i < rest.length; ++i) {
        args.push(rest[i]);
      }
      return args;
    }

singleAcsCheck
  = not:NOT? n:acsName a:acsArg* {
    return function() {
      makeNot(not, checkAccessSingle(n, a));
      }
    }
  / not:NOT? n:acsName '[' a:acsArgs ']' {
    return function() {
      return makeNot(not, checkAccessMulti(n, a, false));
      }
    }
  / not:NOT? n:acsName '{' a:acsArgs '}' {
    return function() {
      return makeNot(not, checkAccessMulti(n, a, true));
      }
    }

multiAcsCheck
  = singleAcsCheck+

acsString = multiAcsCheck

我需要帮助的地方

我遇到的主要问题(如果还没有遇到其他问题!)是使用()和OR子句处理优先级。这可能很简单，但是我已经为此工作了好几天，并且还有一些不足。再次，我最终要在此处实现的目标是输入ACS字符串并输出最终的 bool(boolean) 结果。各种ACS“命令”(例如上例中的“GM”)都应进行方法调用，以完成肮脏的工作。

最佳答案

这是一个快速演示，可以正确解析示例输入并显示如何动态评估表达式(这将返回 bool(boolean) 值):

{
  function check(name, value) {
    // Dummy implementation: returns true when the name starts with 'A'
    return name.charAt(0) == 'A';
  }
}

start
 = expr

expr
 = or_expr

or_expr
 = left:and_expr '|' right:expr { return left || right; }
 / and_expr

and_expr
 = left:not_expr '&'? right:expr { return left && right; }
 / not_expr

not_expr
 = '!' value:atom { return !value; }
 / atom

atom
 = acs_check
 / '(' value:expr ')' { return value; }

acs_check
 = n:name a:arg { return check(n, a); }

name
 = c:([A-Z][A-Z]) { return c.join(''); }

arg
 = c:[A-Z]+ { return c.join(''); }
 / d:[0-9]+ { return d.join(''); }

关于javascript - 带有PEG.js的访问控制字符串(ACS)解析器/解释器，我们在Stack Overflow上找到一个类似的问题：https://stackoverflow.com/questions/26196390/