delphi - TStringList 的 addObject 方法

我想知道这个方法调用是做什么的:

stringList.addObject(String,Object);

我也想知道这个属性有什么作用:

stringList.Objects[i]

添加时看起来像键，值对。但是在循环中检索时会检索到什么？

我也看到 items[i] 调用。

我对 TStringList 操作和 TList 操作感到困惑。

最佳答案

它添加了一对项目:TStringList.Strings 列表中的一个条目，以及 TObject 列表中的一个匹配项 TStringList.Objects。

例如，这允许您存储为项目提供名称的字符串列表，以及作为包含匹配项目的类的对象。

type
  TPerson=class
    FFirstName, FLastName: string;
    FDOB: TDateTime;
    FID: Integer;
  private
    function GetDOBAsString: string;
    function GetFullName: string;
  published
    property FirstName: string read FFirstName write FFirstName;
    property LastName: string read FLastName write FLastName;
    property DOB: TDateTime read FDOB write FDOB;
    property DOBString: string read GetDOBAsString;
    property FullName: string read GetFullName;
    property ID: Integer read FID write FID;
  end;

implementation

{TPerson}
function TPerson.GetDOBAsString: string;
begin
  Result := 'Unknown';
  if FDOB <> 0 then
    Result := DateToStr(FDOB);
end;

function TPerson.GetFullName: string;
begin
  Result := FFirstName + ' ' + FLastName; // Or FLastName + ', ' + FFirstName
end;

var
  PersonList: TStringList;
  Person: TPerson;
  i: Integer;
begin
  PersonList := TStringList.Create;
  try
    for i := 0 to 9 do
    begin
      Person := TPerson.Create;
      Person.FirstName := 'John';
      Person.LastName := Format('Smith-%d', [i]); // Obviously, 'Smith-1' isn't a common last name.
      Person.DOB := Date() - RandRange(1500, 3000);  // Make up a date of birth
      Person.ID := i;
      PersonList.AddObject(Person.LastName, Person);
    end;

    // Find 'Smith-06'
    i := PersonList.IndexOf('Smith-06');
    if i > -1 then
    begin
      Person := TPerson(PersonList[i]);
      ShowMessage(Format('Full Name: %s, ID: %d, DOB: %s',
                         [Person.FullName, Person.ID, Person.DOBString]));
    end;
  finally
    for i := 0 to PersonList.Count - 1 do
      PersonList.Objects[i].Free;
    PersonList.Free;
  end;

这显然是一个人为的例子，因为它不是你真正觉得有用的东西。不过，它展示了这个概念。

另一个方便的用途是将整数值与字符串一起存储(例如，显示 TComboBox 或 TListBox 中的项目列表以及用于数据库查询的相应 ID)。在这种情况下，您只需对 Objects 数组中的整数(或其他任何大小)进行类型转换。

// Assuming LBox is a TListBox on a form:
while not QryItems.Eof do
begin
  LBox.Items.AddObject(QryItem.Fields[0].AsString, TObject(QryItem.Fields[1[.AsInteger));
  QryItems.Next;
end;

// User makes selection from LBox
i := LBox.ItemIndex;
if i > -1 then
begin
  ID := Integer(LBox.Items.Objects[i]);
  QryDetails.ParamByName('ItemID').AsInteger := ID;
  // Open query and get info.
end;

在存储实际 TObject 以外的内容的情况下，您不需要释放内容。由于它们不是真实的对象，因此除了 TStringList 本身之外没有任何东西可以释放。

关于delphi - TStringList 的 addObject 方法，我们在Stack Overflow上找到一个类似的问题：https://stackoverflow.com/questions/8947400/