binary - ANTLR:区分一元和二进制运算符的问题(例如减号)

我正在使用ANTLR(3.2)解析一些相当简单的语法。不幸的是，我遇到了一个小问题。遵循以下规则:

exp
 : NUM
 | '(' expression OPERATOR expression ')' -> expression+
 | '(' (MINUS | '!') expression ')' -> expression
 ;

运算符包含与MINUS定义的负号('-')相同的负号。现在，ANTLR似乎无法处理这两个规则。如果我删除其中任何一个，一切正常。

有任何想法吗？

最佳答案

使一元表达式成为优先级最高的表达式。我还将对一元-使用其他 token ，以使负号之间的区别更好。演示:

grammar Exp;

options {
  output=AST;
}

tokens {
  UNARY;
}

parse
  :  exp EOF
  ;

exp
  :  additionExp
  ;

additionExp
  :  multiplyExp ('+'^ multiplyExp | '-'^ multiplyExp)*
  ;

multiplyExp
  :  unaryExp ('*'^ unaryExp | '/'^ unaryExp)*
  ;

unaryExp
  :  '-' atom -> ^(UNARY atom)
  |  '!' atom -> ^('!' atom)
  |  atom
  ;

atom
  :  '(' exp ')' -> exp
  |  Number      -> Number
  ;

Number : ('0'..'9')+ ('.' ('0'..'9')+)? ;

Spaces : (' ' | '\t' | '\r'| '\n') {$channel=HIDDEN;} ;

源快速测试:

3 * -4 + 7 / 6 * -(3 + -7 * (4 + !2))

产生了以下AST:


使用http://graph.gafol.net/ 创建的

图像

关于binary - ANTLR:区分一元和二进制运算符的问题(例如减号)，我们在Stack Overflow上找到一个类似的问题：https://stackoverflow.com/questions/4019687/