我们有一堆文件是html页面，但其中包含额外的xml元素（都以公司名称“TLA”作为前缀），为我现在正在重写的旧程序提供数据和结构。
示例表单：
<html >
<head>
<title>Highly Simplified Example Form</title>
</head>
<body>
<TLA:document xmlns:TLA="http://www.tla.com">
<TLA:contexts>
<TLA:context id="id_1" value=""></TLA:context>
</TLA:contexts>
<TLA:page>
<TLA:question id="q_id_1">
<table>
<tr>
<td>
<input id="input_id_1" type="text" />
</td>
</tr>
</table>
</TLA:question>
</TLA:page>
<!-- Repeat many times -->
</TLA:document>
</body>
</html>
我的任务是编写一个预处理器，它只将html元素及其属性和内容复制到一个新文件中。
这样地：
<html >
<head>
<title>Highly Simplified Example Form</title>
</head>
<body>
<table>
<tr>
<td>
<input id="input_id_1" type="text" />
</td>
</tr>
</table>
<!-- Repeat many times -->
</body>
</html>
我已经采用了使用XSLT的方法，因为对于不同的文件，这是我需要extract the TLA elements的。到目前为止，这是XSLT：
<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:msxsl="urn:schemas-microsoft-com:xslt" exclude-result-prefixes="msxsl"
xmlns:mbl="http://www.mbl.com">
<xsl:output method="xml" indent="yes"/>
<xsl:strip-space elements="*" />
<xsl:template match="mbl:* | mbl:*/@* | mbl:*/text()"/>
<xsl:template match="@*|node()">
<xsl:copy>
<xsl:apply-templates select="@*|node()"/>
</xsl:copy>
</xsl:template>
</xsl:stylesheet>
但是，这只会产生以下结果：
<html >
<head>
<title>Highly Simplified Example Form</title>
</head>
<body>
</body>
</html>
如您所见，TLA:document元素中的所有内容都被排除在外。除了过滤掉TLA元素之外，还需要在XSLT中更改什么来获取所有html？
或者，有没有更简单的方法来解决这个问题？我知道几乎每个浏览器都会忽略TLA元素，所以有没有办法使用HTML工具或应用程序来获得我所需要的东西？
最佳答案
专门针对HTML元素是很困难的，但是如果您只想从TLA名称空间中排除内容（但仍然包括TLA元素包含的任何非TLA元素），那么这应该是可行的：
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:mbl="http://www.tla.com" exclude-result-prefixes="mbl">
<xsl:output method="xml" indent="yes"/>
<xsl:strip-space elements="*" />
<xsl:template match="@*|node()" priority="-2">
<xsl:copy>
<xsl:apply-templates select="@*|node()"/>
</xsl:copy>
</xsl:template>
<!-- This element-only identity template prevents the
TLA namespace declaration from being copied to the output -->
<xsl:template match="*">
<xsl:element name="{name()}">
<xsl:apply-templates select="@* | node()" />
</xsl:element>
</xsl:template>
<!-- Pass processing on to child elements of TLA elements -->
<xsl:template match="mbl:*">
<xsl:apply-templates select="*" />
</xsl:template>
</xsl:stylesheet>
如果要排除任何具有非空命名空间的内容，也可以使用此选项：
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:mbl="http://www.tla.com" exclude-result-prefixes="mbl">
<xsl:output method="xml" indent="yes"/>
<xsl:strip-space elements="*" />
<xsl:template match="@*|node()" priority="-2">
<xsl:copy>
<xsl:apply-templates select="@*|node()"/>
</xsl:copy>
</xsl:template>
<xsl:template match="*">
<xsl:element name="{name()}">
<xsl:apply-templates select="@* | node()" />
</xsl:element>
</xsl:template>
<xsl:template match="*[namespace-uri()]">
<xsl:apply-templates select="*" />
</xsl:template>
</xsl:stylesheet>
对示例输入运行这两种操作时，结果是：
<html>
<head>
<title>Highly Simplified Example Form</title>
</head>
<body>
<table>
<tr>
<td>
<input id="input_id_1" type="text" />
</td>
</tr>
</table>
</body>
</html>