我正在组装中的“ simon”游戏，每当打开一个按钮时，我都需要发出蜂鸣声，蜂鸣声也应该彼此不同。
谢谢
最佳答案
您可以使用speaker来简化设计。
扬声器使您可以播放不同频率的方波，it can actually be used to reproduce digital audio，但是涉及更多。
扬声器只是一个电磁体，当电流流过时，会向后拉，否则它将保持在默认位置。
通过前后移动扬声器，可以产生声波。
扬声器可以手动移动，也可以使用PIT的通道2移动。
端口61h的位0控制扬声器源（0 =手动，1 = PIT），同一端口的位1是使用PIT时的“扬声器启用”位（未使用扬声器时的“位置”）。
这是缺少手动驱动部分的原理图（来自此page）：
PIT通过端口40h-43h进行控制，每次分频器的两个字节都将使用模式3（方波发生器）进行设置。
PIT具有运行在大约1.193180 MHz的振荡器，该分频器用于控制方波的周期。
无需处理内部问题：在PIT振荡器的每个刻度上，加载的分频器都会递减。方波的周期等于PIT将分频器递减至零所需的时间。
产生声音只是用所需的分频器对PIT进行编程并启用扬声器的问题。
稍后，我们需要禁用它。
一种简单的方法是使用int 1ch，每秒调用18.2次。
通过在首次播放声音时在变量中保存持续时间，在int 1ch的每个滴答处将其减小以及在计数达到零时禁用扬声器，可以控制蜂鸣的持续时间。
使用int 1ch需要设置功能（beep_setup）和拆卸功能（beep_teardown）。
BITS 16
ORG 100h
__start__:
;Setup
call beep_setup
;Sample beep of ~2sec
mov ax, 2000
mov bx, 36
call beep_play
;Wait for input
xor ax, ax
int 16h
;Tear down
call beep_teardown
mov ax, 4c00h
int 21h
;-------------------------------------------------
;
;Setup the beep ISR
;
beep_setup:
push es
push ax
xor ax, ax
mov es, ax
;Save the original ISR
mov ax, WORD [es: TIMER_INT * 4]
mov WORD [cs:original_timer_isr], ax
mov ax, WORD [es: TIMER_INT * 4 + 2]
mov WORD [cs:original_timer_isr + 2], ax
;Setup the new ISR
cli
mov ax, beep_isr
mov WORD [es: TIMER_INT * 4], ax
mov ax, cs
mov WORD [es: TIMER_INT * 4 + 2], ax
sti
pop ax
pop es
ret
;
;Tear down the beep ISR
;
beep_teardown:
push es
push ax
call beep_stop
xor ax, ax
mov es, ax
;Restore the old ISR
cli
mov ax, WORD [cs:original_timer_isr]
mov WORD [es: TIMER_INT * 4], ax
mov ax, WORD [cs:original_timer_isr + 2]
mov WORD [es: TIMER_INT * 4 + 2], ax
sti
pop ax
pop es
ret
;
;Beep ISR
;
beep_isr:
cmp BYTE [cs:sound_playing], 0
je _bi_end
cmp WORD [cs:sound_counter], 0
je _bi_stop
dec WORD [cs:sound_counter]
jmp _bi_end
_bi_stop:
call beep_stop
_bi_end:
;Chain
jmp FAR [cs:original_timer_isr]
;
;Stop beep
;
beep_stop:
push ax
;Stop the sound
in al, 61h
and al, 0fch ;Clear bit 0 (PIT to speaker) and bit 1 (Speaker enable)
out 61h, al
;Disable countdown
mov BYTE [cs:sound_playing], 0
pop ax
ret
;
;Beep
;
;AX = 1193180 / frequency
;BX = duration in 18.2th of sec
beep_play:
push ax
push dx
mov dx, ax
mov al, 0b6h
out 43h, al
mov ax, dx
out 42h, al
mov al, ah
out 42h, al
;Set the countdown
mov WORD [cs:sound_counter], bx
;Start the sound
in al, 61h
or al, 3h ;Set bit 0 (PIT to speaker) and bit 1 (Speaker enable)
out 61h, al
;Start the countdown
mov BYTE [cs:sound_playing], 1
pop dx
pop ax
ret
;Keep these in the code segment
sound_playing db 0
sound_counter dw 0
original_timer_isr dd 0
TIMER_INT EQU 1ch
特别感谢Sep Roland修复了原始代码中的缺陷！
您可以使用
beep_play发出哔声，所使用的单位是上述硬件配置的“自然”单位。如果您的频率和持续时间是固定的，那么这些单元将免费简化代码。
在指定的持续时间后，蜂鸣声将停止，您可以使用
beep_stop强制停止。一次播放多种声音是不可能的（即使不借助PWM技术也无法混合）。
在播放另一声哔哔声时调用
beep_play将具有停止当前哔声并开始新哔声的效果。