arrays - Autolisp实体数据检索

我正在尝试使用autocad，我想在矩形和直线之间建立一条“高速公路”我需要矩形上的两点。有什么想法吗？

(setq en(car(entsel"\Get rectangle : ")))
 (entget en)

我的全部代码

    (defun temaLisp(/  )
  ;HIGHWAY BUILDER
  ;My project is a highwaybulder
  ;How does it work?
  ;Select a rectangle and draw from there to a distance the highway where it meets a stop(Line)
      (princ "TemaLisp ")
   ;get rectangle (prompt "\nSelect the ends of a station")
  (setq en(car(entsel"\Get rectangle : ")))
  (entget en)
  ;get the stop (Line)


     (setq line2 (car (entsel "\nSelect the second line: ")))
            (setq p3 (cdr (assoc 10 (entget line2))))
            (setq p4 (cdr (assoc 11 (entget line2))))

  ;of the highway &optional (size 50)
  (setq mid1 (midpt pt3 pt4)) ; midpoint for dotted line

  ; Draw the lines
  (command "line" mid1 mid2)
)

最佳答案

在AutoCAD中，矩形（使用AutoCADRECTANG命令创建）使用闭合的二维轻量级多段线（LWPOLYLINE）实体表示。
LWPOLYLINE实体包含以下DXF数据：

(
    (-1 . <Entity name: 7ffff706880>)  ;; Pointer to self
    (0 . "LWPOLYLINE")                 ;; Entity Type
    (330 . <Entity name: 7ffff7039f0>) ;; Point to parent
    (5 . "FFF")                        ;; Handle
    (100 . "AcDbEntity")               ;; Class
    (67 . 0)                           ;; Tilemode
    (410 . "Model")                    ;; Layout
    (8 . "0")                          ;; Layer
    (100 . "AcDbPolyline")             ;; Subclass
    (90 . 4)                           ;; Vertices
    (70 . 1)                           ;; Bitwise flag (1=Closed)
    (43 . 0.0)                         ;; Constant width
    (38 . 0.0)                         ;; Elevation
    (39 . 0.0)                         ;; Thickness
    (10 18.9133 17.6315)               ;; Vertex coordinate (OCS)

    < ... additional vertex data ... >

    (10 18.9133 12.7863)               ;; Vertex coordinate (OCS)
    (40 . 0.0)                         ;; Segment starting width
    (41 . 0.0)                         ;; Segment ending width
    (42 . 0.0)                         ;; Segment bulge
    (91 . 0)                           ;; Vertex identifier
    (210 0.0 0.0 1.0)                  ;; Extrusion (normal) vector
)

这里，使用DXF数据中的DXF group 10条目存储每个顶点的2D OCS坐标。
有很多方法可以获得由DXF数据中的多个DXF组引用所保存的值列表（从而获得多段线的顶点列表）。
由于assocAutoLISP函数返回关联列表中键的第一次出现，我将这些函数称为massoc函数（即多个assoc）。
一前额

(defun massoc1 ( key lst / rtn )
    (foreach x lst
        (if (= key (car x))
            (setq rtn (cons (cdr x) rtn))
        )
    )
    (reverse rtn)
)

第一个示例只是遍历提供的关联列表中的每个项，如果该项的地址寄存器（car）的内容等于所需的key，则与键（或递减寄存器的内容-cdr）关联的值将添加到函数返回的列表中。
这个列表在返回之前是反向的，因为列表是反向构造的，每个项都被推到列表的前面—这比使用append/list组合按顺序构建列表要高效得多。
2追加/映射

(defun massoc2 ( key lst )
    (apply 'append
        (mapcar
            (function
                (lambda ( x ) (if (= key (car x)) (list (cdr x))))
            )
            lst
        )
    )
)

不过，迭代列表的另一种方法是，由于mapcar返回对每个列表项所提供函数的求值结果，如果if语句将导致nil出现在“mapcar”返回的列表中，则那些不符合条件的项。
这些nil值通过利用AutoLISP中nil和空列表()的二元性被删除，通过应用append函数来附加所有子列表，即mapcar返回的列表中的nil值。
三。如果不是，vl移除

(defun massoc3 ( key lst )
    (mapcar 'cdr
        (vl-remove-if-not
            (function (lambda ( x ) (= key (car x))))
            lst
        )
    )
)

如tin上所述：如果提供给vl-remove-if-not函数的谓词函数返回nil（vl-remove-if也可以与否定的谓词函数一起使用），则删除项，因此删除第一个元素不等于所需键的项。
然后使用mapcar函数返回与vl-remove-if-not返回的每个关联列表项相关联的值。
四当/助理/成员

(defun massoc4 ( key lst / itm rtn )
    (while (setq itm (assoc key lst))
        (setq rtn (cons (cdr itm) rtn) lst (cdr (member itm lst)))
    )
    (reverse rtn)
)

这种方法比之前的方法效率高得多，因为assoc&member函数用于直接跳转到所提供列表中的目标项，而不是遍历和测试每个项。
assoc返回关联列表中键的第一次出现，并返回列表的尾部，其中第一项等于提供的参数。
这样，member函数检索目标项，assoc函数返回从该项开始的列表的其余部分，并通过使用member重复重新定义列表以包含该目标项之后的所有项。
5个。递归/关联/成员

(defun massoc5 ( key lst / itm )
    (if (setq itm (assoc key lst))
        (cons (cdr itm) (massoc5 key (cdr (member itm lst))))
    )
)

但是，在这种情况下，上面的一个变体不是为找到的每个项重新定义列表，而是将列表的其余部分作为参数传递给函数的递归求值。
6acet-list-m-assoc（快速工具）

(defun massoc6 ( key lst )
    (mapcar 'cdr (acet-list-m-assoc key lst))
)

此版本的函数使用cdr函数，该函数定义为快速工具库的一部分，作为对完整版本的AutoCAD的可选添加。
但这是作弊:-)
7号基本递归

(defun massoc7 ( key lst )
    (if lst
        (if (= key (caar lst))
            (cons (cdar lst) (massoc7 key (cdr lst)))
            (massoc7 key (cdr lst))
        )
    )
)

最后一个示例本质上是上面演示的acet-list-m-assoc示例的递归版本该函数只查看所提供列表中的第一个项，如果第一个元素与foreach参数匹配，则它将key'传递到递归调用返回的列表中，而列表的其余部分则传递给递归调用，而不向返回中添加项。
实例
既然我们已经讨论了定义这样一个函数的各种方法，那么应该如何使用这样一个函数呢？
上面的每个函数都接受两个参数：“key”和关联列表。这在语法上与标准的autolispcons函数相同。
此函数可用于获取与DXF关联列表中的DXF组10关联的所有值，语法如下：

(massoc 10 <dxf-data>)

例如（在Visual LISP IDE控制台上）：

;; Obtain a LWPOLYLINE entity
_$ (setq ent (car (entsel)))
<Entity name: 7ffff706880>

;; Retrieve the DXF data
_$ (setq dxf (entget ent))
((-1 . <Entity name: 7ffff706880>) (0 . "LWPOLYLINE") ... (91 . 0) (210 0.0 0.0 1.0))

;; Obtain the values associated with all DXF group 10 entries
_$ (massoc 10 dxf)
((13.0161 12.4807) (25.727 12.4807) (25.727 18.6426) (13.0161 18.6426))

这可以在示例程序中按以下方式使用：

(defun c:test ( / dxf ent )
    (if
        (and
            (setq ent (car (entsel "\nSelect rectangle: ")))
            (setq dxf (entget ent))
            (= "LWPOLYLINE" (cdr (assoc 0 dxf)))
        )
        (print (massoc 10 dxf))
    )
    (princ)
)

(defun massoc ( key lst / rtn )
    (foreach x lst
        (if (= key (car x))
            (setq rtn (cons (cdr x) rtn))
        )
    )
    (reverse rtn)
)

性能考虑
在性能方面，同一函数的上述变化是不相等的——那些在所提供列表中的每个项上迭代的变化比那些使用内置函数（如assoc和assoc）直接“跳到”目标项的变化效率低。
作为快速比较，请考虑以下基准结果：

;;;Benchmarking ................Elapsed milliseconds / relative speed for 32768 iteration(s):
;;;
;;;    (MASSOC5 2 L).....1482 / 1.25 <fastest> ;; recursive/assoc/member
;;;    (MASSOC4 2 L).....1482 / 1.25           ;; while/assoc/member
;;;    (MASSOC6 2 L).....1498 / 1.24           ;; acet-list-m-assoc
;;;    (MASSOC3 2 L).....1638 / 1.13           ;; vl-remove-if-not
;;;    (MASSOC7 2 L).....1747 / 1.06           ;; basic recursion
;;;    (MASSOC1 2 L).....1748 / 1.06           ;; foreach
;;;    (MASSOC2 2 L).....1856 / 1 <slowest>    ;; append/mapcar

正如预期的那样，member函数被证明是最快的，而Express Tools函数则紧随其后。