delphi - 如何将带有附件的MAPI电子邮件发送给传真收件人？

我正在使用this method从Delphi应用程序内部发送带有PDF附件的MAPI电子邮件。

它将打开一个MS Outlook“新消息”窗口，其中已附带pdf文档，收件人为空。

如果您输入普通的电子邮件联系人，则可以正常进行。

但是，如果您选择传真收件人，它将显示在我的“已发送邮件”文件夹中，但是传递会以静默方式失败（没有错误，没有MS Outlook“传递失败”消息，也没有传递消息）。

在MS Outlook中仅使用传真号码设置“传真收件人”。没有电子邮件或其他任何内容。我们使用faxcore server将这些“传真”路由到Outlook收件箱。

如果您look at this image，则我为此联系人填写的唯一字段是标有“商务传真”的字段。

如果我手动（即在我的应用程序外部）创建标准的MS Outlook电子邮件，并选择完全相同的传真收件人，然后手动附加完全相同的PDF，那么一切正常。

因此，似乎有关使用MAPI发送至传真号码的操作导致其失败。
This post sounds similar, except they get a "message undeliverable" error and I don't.

谁能给我一些指导吗？

谢谢

更新：如果我使用MAPI创建电子邮件，但是随后我手动删除了附件，则附件确实可以工作。因此，从Outlook内部，我可以将附件通过电子邮件发送给传真收件人，但是使用MAPI失败。

完整的源代码如下：

unit Main;

interface

uses
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
  StdCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    procedure Button1Click(Sender: TObject);
  private
    function SendEMailUsingMAPI(const Subject, Body, FileName, SenderName,
      SenderEMail, RecipientName, RecipientEMail: string): integer;
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

{$R *.DFM}

uses
  Mapi;

procedure TForm1.Button1Click(Sender: TObject);
begin
  //this will bring up an MS Outlook dialog.
  //inside that dialog, if i choose a normal email recipient, it works.
  //                    if i choose a fax recipient, it fails silently.
  //if i create the email from w/in outlook, it can go to *either* with success.

  SendEmailUsingMAPI(
    'Subject',  //subject of email
    'Body',  //body of email text
    'c:\my_doc.pdf',  //attachment file name
    'My name',  //sender email name
    '[email protected]',  //sender email address
    '',  //recipient email name
    '');  //recipient email address
end;


function TForm1.SendEMailUsingMAPI(const Subject, Body, FileName, SenderName,
  SenderEMail, RecipientName, RecipientEMail: string): Integer;
var
  Message: TMapiMessage;
  lpSender, lpRecipient: TMapiRecipDesc;
  FileAttach: TMapiFileDesc;
  SM: TFNMapiSendMail;
  MAPIModule: HModule;
  FileType: TMapiFileTagExt;
begin
  FillChar(Message,SizeOf(Message),0);

  if (Subject <> '') then begin
    Message.lpszSubject := PChar(Subject);
  end;

  if (Body <> '') then begin
    Message.lpszNoteText := PChar(Body);
  end;

  if (SenderEmail <> '') then
  begin
    lpSender.ulRecipClass := MAPI_ORIG;
    if (SenderName = '') then begin
      lpSender.lpszName := PChar(SenderEMail);
    end
    else begin
      lpSender.lpszName := PChar(SenderName);
    end;
    lpSender.lpszAddress := PChar(SenderEmail);
    lpSender.ulReserved := 0;
    lpSender.ulEIDSize := 0;
    lpSender.lpEntryID := nil;
    Message.lpOriginator := @lpSender;
  end;

  if (RecipientEmail <> '') then begin
    lpRecipient.ulRecipClass := MAPI_TO;
    if (RecipientName = '') then begin
      lpRecipient.lpszName := PChar(RecipientEMail);
    end
    else begin
      lpRecipient.lpszName := PChar(RecipientName);
    end;
    lpRecipient.lpszAddress := PChar(RecipientEmail);
    lpRecipient.ulReserved := 0;
    lpRecipient.ulEIDSize := 0;
    lpRecipient.lpEntryID := nil;
    Message.nRecipCount := 1;
    Message.lpRecips := @lpRecipient;
  end
  else begin
    Message.lpRecips := nil;
  end;

  if (FileName = '') then begin
    Message.nFileCount := 0;
    Message.lpFiles := nil;
  end
  else begin
    FillChar(FileAttach,SizeOf(FileAttach),0);
    FileAttach.nPosition := Cardinal($FFFFFFFF);
    FileAttach.lpszPathName := PChar(FileName);

    FileType.ulReserved := 0;
    FileType.cbEncoding := 0;
    FileType.cbTag := 0;
    FileType.lpTag := nil;
    FileType.lpEncoding := nil;

    FileAttach.lpFileType := @FileType;
    Message.nFileCount := 1;
    Message.lpFiles := @FileAttach;
  end;

  MAPIModule := LoadLibrary(PChar(MAPIDLL));

  if MAPIModule = 0 then begin
    Result := -1;
  end
  else begin
    try
      @SM := GetProcAddress(MAPIModule,'MAPISendMail');
      if @SM <> nil then begin
        Result := SM(0,Application.Handle,Message,
          MAPI_DIALOG or MAPI_LOGON_UI,0);
      end
      else begin
        Result := 1;
      end;
    finally
      FreeLibrary(MAPIModule);
    end;
  end;

  if Result <> 0 then begin
    MessageDlg('Error sending mail ('+IntToStr(Result)+').',mtError,[mbOK],0);
  end;
end;

end.

最佳答案

好的，您的更新指向附件，因此，我要作另一个猜测：尝试将附件的文件类型显式设置为“ application / pdf”（您当前的代码未设置lpFileType字段）。传真处理可能取决于此。您只需将MapiFileTagExt（类型lpFileType指向）的编码部分保留为空白，只需填充记录并设置cbTag和lpTag字段即可。

如果您需要代码（mapi结构有时可能有点令人眼花）乱），就大喊大叫，但是要花点时间找点时间键入它。.无论如何，我还是在猜测。我的家庭环境中没有传真设置，否则我会做一些适当的测试。

编辑

下面说明一些代码。但是，此后我一直使用Outlook Spy（既没有方法也没有检查）或手动附加文件时进行检查，似乎只在收到的传入消息上对发送的项目设置了PR_ATTACH_MIME_TAG属性。

  FillChar(FileAttach,SizeOf(FileAttach),0);
  FileAttach.nPosition := Cardinal($FFFFFFFF);
  FileAttach.lpszPathName := PChar(FileName);
  //
  MimeType := 'application/pdf';
  //
  FileType.ulReserved := 0;
  FileType.cbTag := Length( MimeType );
  FileType.lpTag := PByte(MimeType);
  FileType.cbEncoding := 0;
  FileType.lpEncoding := nil;
  //
  FileAttach.lpFileType := @FileType;
  Message.nFileCount := 1;
  Message.lpFiles := @FileAttach;

（代码格式化程序并不是特别有用）。

关于delphi - 如何将带有附件的MAPI电子邮件发送给传真收件人？，我们在Stack Overflow上找到一个类似的问题：https://stackoverflow.com/questions/1234623/