delphi - 在pascal中动态分配匿名函数

我希望能够在pascal中动态生成弹出菜单。

我还希望能够为每个菜单项动态分配OnClick处理程序。

这是我习惯于在C#中可以做的事情，这是我在pascal中的尝试。

菜单项onClick事件处理程序需要属于一个对象(of Object)，因此我为此创建了一个容器对象。

这是我的代码:

unit Unit1;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.StdCtrls, Vcl.Menus;

type
  TForm1 = class(TForm)
    PopupMenu1: TPopupMenu;
    procedure FormCreate(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

  TFoo = class
    public
      Bar : String;
      Val : Integer;
  end;

  TNotifyEventWrapper = class
    private
      FProc: TProc<TObject>;
      I : Integer;
    public
      constructor Create(Proc: TProc<TObject>);
    published
      procedure Event(Sender: TObject);
  end;

var
  Form1: TForm1;
  NE : TNotifyEventWrapper;

implementation

{$R *.dfm}

constructor TNotifyEventWrapper.Create(Proc: TProc<TObject>);
begin
    inherited Create;
    FProc := Proc;
end;

procedure TNotifyEventWrapper.Event(Sender: TObject);
begin
    ShowMessage(IntToStr(I));
    FProc(Sender);
end;

procedure TForm1.FormCreate(Sender: TObject);
var
    F : TFoo;
    I: Integer;
    mi : TMenuItem;
begin
    if Assigned(NE) then FreeAndNil(NE);

    for I := 1 to 10 do
    begin
        F := TFoo.Create;
        F.Bar := 'Hello World!';
        F.Val := I;
        NE := TNotifyEventWrapper.Create
        (
            procedure (Sender :TObject)
            begin
               ShowMessage(F.Bar + ' ' + inttostr(F.Val) + Format('  Addr = %p', [Pointer(F)]) + Format('Sender = %p, MI.OnClick = %p', [Pointer(Sender), Pointer(@TMenuItem(Sender).OnClick)]));
            end
        );
        NE.I := I;

        mi := TMenuItem.Create(PopupMenu1);

        mi.OnClick := NE.Event;

        mi.Caption := inttostr(F.Val);

        PopupMenu1.Items.Add(mi);
    end;
end;

end.

单击菜单项编号6

程序显示预期的消息

但是，下一条消息未显示预期结果。

而不是6，它显示项目10

无论我单击列表中的哪个项目，它们似乎都将触发列表中最后一个项目的事件处理程序(10)。

我向我建议，NE对象的成员过程Event是该对象所有实例的相同内存地址。

无论我单击哪个菜单项，内存地址MI.OnClick都是相同的。

最佳答案

理解这一点的关键是要了解变量捕获捕获的是变量而不是值。

您的anon方法都捕获相同的变量F。该变量只有一个实例，因为FormCreate仅执行一次。这就解释了行为。当您的anon方法执行时，变量F在最终循环迭代中具有为其分配的值。

您需要的是使每个不同的anon方法都捕获不同的变量。您可以通过在生成每种不同的anon方法时制作一个新的堆栈框架来实现。

function GetWrapper(F: Foo): TNotifyEventWrapper;
begin
  Result := TNotifyEventWrapper.Create(
    procedure(Sender: TObject)
    begin
      ShowMessage(F.Bar + ...);
    end
  );
end;

因为函数GetWrapper的参数是该函数的堆栈框架中的局部变量，所以每次GetWrapper的调用都会创建该局部变量的新实例。

您可以将GetWrapper放在您需要的位置。作为FormCreate中的嵌套函数，或作为私有(private)方法，或在单元范围内。

然后按以下方式构建菜单:

F := TFoo.Create;
F.Bar := 'Hello World!';
F.Val := I;
NE := GetWrapper(F);
NE.I := I;