multithreading - 如何使用Delphi从线程更新GUI

我正在使用Delphi匿名线程执行代码。
在线程中间，必须进行几次GUI更新，更改一些标签，等等。

如果我从线程内部执行此操作，则将在线程停止后立即进行更改。它们消失了，然后应用程序给了我旧的窗口处理程序错误...(这是可以预料的)
System Error. Code:1400. Invalid window handle
我尝试使用Syncronize(updateui);方法执行更改(将它们移至单独的函数)，但是在同步E2066 Missing operator or semicolon上收到错误，这对我根本没有意义...

我已经一页接一页地搜索了，它们似乎都以这种方式调用，但是当我这样做时，我得到了上面的错误...

我说错了吗？

代码:

TThread.CreateAnonymousThread(
procedure
 begin
 main.Enabled:=false;
 Loading.show;
 label52.caption:=getfieldvalue(datalive.users,'users','credit_amount','user_id',user_id );
 CoInitialize(nil);
   if (length(maskedit1.Text)=maskedit1.MaxLength) and (pingip(serverip)=true) then
    begin
       if (strtofloat(label52.caption)>0) then
        begin
           ....do some work....

           Synchronize(updateui);
        end
       else Showmessage('Insufficient Funds. Please add funds to continue.');
    end
   else if (length(maskedit1.Text)<>maskedit1.MaxLength) then
    begin
     Showmessage('ID Number not long enough.');
    end
   else
    begin
     Showmessage('Could not connect to the server. Please check your internet connection and try again.');
    end;
 CoUnInitialize;
 loading.close;
 main.Enabled:=true;
end).start;

UpdateUI:

procedure TMain.updateui;
var
birthdate,deathdate:TDate;
begin
Panel3.Show;

Label57.Caption := 'Change 1';
Label59.Caption := 'Change 2';
Label58.Caption := 'Change 3';
Label60.Caption := 'Change 4';
Label62.Caption := 'Change 5';
Label70.Caption := 'Change 6';


ScrollBox1.Color := clwhite;
end;

最佳答案

使用TThread.Synchronize并将另一个匿名函数传递给它。然后，您可以在匿名函数中调用updateui:

TThread.CreateAnonymousThread(
  procedure
  begin
    // do whatever you want

    TThread.Synchronize(nil,
      procedure
      begin
        updateui();
      end);

   // do something more if you want
  end
).Start();

同步通常很昂贵(就性能而言)。仅在确实需要它们时才使用它们。如果扩展updateui-method以减少绘制操作，则可以提高性能。

可以使用SendMessage调用WM_SETREDRAW:

procedure StopDrawing(const Handle: HWND);
const
  cnStopDrawing = 0;
begin
  SendMessage(Handle, WM_SETREDRAW, cnStopDrawing, 0);
end;

procedure ContinueDrawing(const Handle: HWND);
const
  cnStartDrawing = 1;
begin
  SendMessage(Handle, WM_SETREDRAW, cnStartDrawing, 0);

  // manually trigger the first draw of the window
  RedrawWindow(Handle, nil, 0,
    RDW_ERASE or RDW_FRAME or RDW_INVALIDATE or RDW_ALLCHILDREN);
end;

在updateui()顶部添加对StopDrawing()的调用，并在updateui()末尾添加对ContinueDrawing()的调用。对ContinueDrawing()的调用应在finally-block中。这将确保即使在执行updateui期间发生异常之后，窗口也将被绘制。

例子:

procedure TMain.updateui;
begin
  try
    StopDrawing(Handle);

    Panel3.Show;

    Label57.Caption := 'Change 1';
    Label59.Caption := 'Change 2';

    // ...
  finally
    // Code under finally gets executed even if there was an error
    ContinueDrawing(Handle);
  end;
end;

关于multithreading - 如何使用Delphi从线程更新GUI，我们在Stack Overflow上找到一个类似的问题：https://stackoverflow.com/questions/31433680/