nsis - 为什么VIProductVersion自变量会覆盖ProductVersion键的值？

来自nsi脚本的代码片段:

VIProductVersion 1.2.0.0
VIAddVersionKey /LANG=${LANG_ENGLISH} FileVersion 1.1.0.0

我想将FileVersion设置为1.1.0.0，但在文件属性中将其设置为1.2.0.0。我还注意到，独自执行的VIProductVersion会添加FileVersion key 并设置其值。

文档说VIProductVersion添加了产品版本，但我看到的是实际上已添加FileVersion。这是NSIS中的错误吗？如果VIAddVersionKey FileVersion设置的值被VIProductVersion设置的一个值覆盖，则VIAddVersionKey的目的是什么？
VIProductVersion需要ojit_code调用，否则脚本不会编译。

我正在使用的版本:EclipseNSIS 0.9.8； MakeNSIS 2.46。操作系统:Windows 7。

最佳答案

版本信息资源存储在两个部分中:

VS_FIXEDFILEINFO是带有产品和文件版本的固定块，VIProductVersion设置了此

零个，一个或多个(多种语言)字符串块和一个或多个name = value字符串，VIAddVersionKey对其进行设置。

一些应用程序使用FileVersion字符串，如果该字符串不存在，则退回到VS_FIXEDFILEINFO::dwFileVersion，其他应用程序仅使用VS_FIXEDFILEINFO::dwFileVersion等。
VIProductVersion "1.2.3.4"将生成一个类似以下内容的版本 header

1 VERSIONINFO
FILEVERSION 1,2,3,4
PRODUCTVERSION 1,2,3,4
FILEOS 0x4
FILETYPE 0x1

通常这是足够的，但它不会让您设置PRODUCTVERSION!= FILEVERSION。

我认为这是NSIS中的错误，他们应该添加VIFileVersion命令或将VIProductVersion扩展到VIProductVersion <productver> [filever]。

您可以在tracker上添加功能请求。

同时，您可以通过在使用!packhdr的构建过程中调用resource hacker来解决此问题。

编辑:

它可以在编译时使用2.46来完成，使用!packhdr，外部第3方工具(我无法让reshacker导入.rc版本资源，因此我必须先转换为.res)和骇人的骇客:

!macro HackyVIFileVersion reshack gorcjorg fixedfilever
;http://www.angusj.com/resourcehacker/
;http://web.archive.org/web/20090918063311/http://www.jorgon.freeserve.co.uk/Gorcjorg.zip
!searchreplace HackyVIFileVersion_id "${__TIME__}" ":" ""
!define HackyVIFileVersion_cmd "$%TEMP%\nsisVIFV${HackyVIFileVersion_id}.cmd"
!appendfile "${HackyVIFileVersion_cmd}" `@echo off&setlocal ENABLEEXTENSIONS DISABLEDELAYEDEXPANSION$\n`
!appendfile "${HackyVIFileVersion_cmd}" `set eh=%TEMP%\exehead%~1.tmp$\n`
!appendfile "${HackyVIFileVersion_cmd}" `set rh=%~2$\n`
!appendfile "${HackyVIFileVersion_cmd}" `call "%rh%" -extract "%eh%", "%eh%1.rc", VersionInfo,1,$\n`
!appendfile "${HackyVIFileVersion_cmd}" `> "%eh%2.rc" echo.LANGUAGE LANG_ENGLISH, SUBLANG_ENGLISH_US $\n` ;must force lang for Gorcjorg
!appendfile "${HackyVIFileVersion_cmd}" `FOR /F "usebackq tokens=* delims=" %%A IN ("%eh%1.rc") DO ($\n`
!appendfile "${HackyVIFileVersion_cmd}" `   FOR /F "usebackq" %%B IN ('%%A') DO ($\n`
!appendfile "${HackyVIFileVersion_cmd}" `       if "%%~B"=="FILEVERSION" (>> "%eh%2.rc" echo.FILEVERSION %~4) else (>> "%eh%2.rc" echo.%%A)$\n`
!appendfile "${HackyVIFileVersion_cmd}" `   )$\n`
!appendfile "${HackyVIFileVersion_cmd}" `)$\n`
!appendfile "${HackyVIFileVersion_cmd}" `call "%~3" /fo "%eh%.res" /r "%eh%2.rc"$\n`
!appendfile "${HackyVIFileVersion_cmd}" `call "%rh%" -addoverwrite "%eh%", "%eh%", "%eh%.res", versioninfo,1,$\n`
!appendfile "${HackyVIFileVersion_cmd}" `del "%eh%2.rc"&del "%eh%1.rc"&del "%eh%.res"&del "%~0"`
!packhdr "$%TEMP%\exehead${HackyVIFileVersion_id}.tmp" '"${HackyVIFileVersion_cmd}" "${HackyVIFileVersion_id}" "${reshack}" "${gorcjorg}" "${fixedfilever}"'
!undef HackyVIFileVersion_cmd
!undef HackyVIFileVersion_id
!macroend


VIProductVersion "1.2.3.4"
VIAddVersionKey /LANG=1033 FileVersion 5.6.7.8
VIAddVersionKey /LANG=1033 ProductVersion "1.2.3.4"
VIAddVersionKey /LANG=1033 Comments "A test comment"
!insertmacro HackyVIFileVersion "C:\tools\ResHacker.exe" "C:\tools\GoRC.exe" "5,6,7,8"

...您最终得到以下版本资源:

1 VERSIONINFO
FILEVERSION 5,6,7,8
PRODUCTVERSION 1,2,3,4
FILEOS 0x4
FILETYPE 0x1
{
BLOCK "StringFileInfo"
{
    BLOCK "040904e4"
    {
        VALUE "Comments", "A test comment"
        VALUE "FileVersion", "5.6.7.8"
        VALUE "ProductVersion", "1.2.3.4"
    }
}

BLOCK "VarFileInfo"
{
    VALUE "Translation", 0x0409 0x04E4
}
}

fileVersion

nsis - 为什么VIProductVersion自变量会覆盖ProductVersion键的值？