macros - 使用 `once-only`宏

在Practical Common Lisp的第8章末尾，Peter Seibel提供了once-only宏。其目的是减轻用户定义宏中变量评估的许多细微问题。请注意，我目前还没有像其他一些文章那样理解此宏的工作原理，而是如何正确使用它:

(defmacro once-only ((&rest names) &body body)
  (let ((gensyms (loop for n in names collect (gensym))))
    `(let (,@(loop for g in gensyms collect `(,g (gensym))))
      `(let (,,@(loop for g in gensyms for n in names collect ``(,,g ,,n)))
        ,(let (,@(loop for n in names for g in gensyms collect `(,n ,g)))
           ,@body)))))

下面是一个示例(不正确)人为的宏，它尝试表现出几个变量评估问题。它声称对某个整数范围进行一定的增量迭代，返回该范围:

(defmacro do-range ((var start stop delta) &body body)
  "Sample macro with faulty variable evaluations."
  `(do ((,var ,start (+ ,var ,delta))
        (limit ,stop))
       ((> ,var limit) (- ,stop ,start))
     ,@body))

例如，(do-range (i 1 15 3) (format t "~A " i))应该打印1 4 7 10 13，然后返回14。

问题包括:1)潜在捕获limit的第二次出现，因为它以自由变量的形式出现； 2)潜在捕获到绑定(bind)变量limit的初次出现，因为它与其他出现在宏中的变量一起出现在表达式中参数，3)乱序评估，因为delta将在stop之前评估，即使stop在参数列表中的delta之前出现，以及4)多变量评估，因为stop和start被评估多次。据我了解，once-only应该解决以下问题:

(defmacro do-range ((var start stop delta) &body body)
  (once-only (start stop delta limit)
    `(do ((,var ,start (+ ,var ,delta))
          (limit ,stop))
         ((> ,var limit) (- ,stop ,start))
       ,@body)))

但是，(macroexpand '(do-range (i 1 15 3) (format t "~A " i)))抱怨limit是一个未绑定(bind)的变量。如果我改用with-gensyms，它只应解决上述问题1和2，则扩展将继续进行而不会发生任何情况。

这是once-only宏的问题吗？ once-only是否真的解决了上面概述的所有问题(也许还有其他问题)？

最佳答案

唯一的宏

为了消除N未使用的警告，我将宏更改为:

(defmacro once-only ((&rest names) &body body)
  (let ((gensyms (loop for nil in names collect (gensym))))
                           ; changed N to NIL, NIL is ignored
    `(let (,@(loop for g in gensyms collect `(,g (gensym))))
      `(let (,,@(loop for g in gensyms for n in names collect ``(,,g ,,n)))
        ,(let (,@(loop for n in names for g in gensyms collect `(,n ,g)))
           ,@body)))))

该宏的目的是确保表达式仅按定义的顺序求值一次。为此，它将引入新的未变量，并将评估结果绑定(bind)到那些变量。在宏内可以使用新变量。提供宏本身是为了使编写宏更加容易。

在DO-RANGE中仅使用一次

您的示例使用ONCE-ONLY:

(defmacro do-range ((var start stop delta) &body body)
  (once-only (start stop delta limit)
    `(do ((,var ,start (+ ,var ,delta))
          (limit ,stop))
         ((> ,var limit) (- ,stop ,start))
         ,@body)))

为什么LIMIT列表中有once-only？ limit在此处 undefined 。 LIMIT在ONCE-ONLY表单内部用作符号，但在外部没有绑定(bind)。
ONCE-ONLY期望名称列表是符号列表，并且这些名称绑定(bind)到表单。在您的情况下，limit是一个符号，但 undefined 。

我们需要从名称列表中删除limit:

(defmacro do-range ((var start stop delta) &body body)
  (once-only (start stop delta)
    `(do ((,var ,start (+ ,var ,delta))
          (limit ,stop))
         ((> ,var limit) (- ,stop ,start))
         ,@body)))

现在，如何处理LIMIT？鉴于once-only提供了名称的绑定(bind)，包括STOP，我们可以消除符号LIMIT并将其使用替换为,stop:

(defmacro do-range ((var start stop delta) &body body)
  (once-only (start stop delta)
    `(do ((,var ,start (+ ,var ,delta)))
         ((> ,var ,stop) (- ,stop ,start))
       ,@body)))

例:

CL-USER 137 > (pprint
               (macroexpand
                '(do-range (i 4 10 2)
                   (print i))))

(LET ((#1=#:G2170 4)
      (#3=#:G2171 10)
      (#2=#:G2172 2))
  (DO ((I #1# (+ I #2#)))
      ((> I #3#) (- #3# #1#))
   (PRINT I)))

关于macros - 使用 `once-only`宏，我们在Stack Overflow上找到一个类似的问题：https://stackoverflow.com/questions/43191760/