java - 如何使用ArrayList.get()？

我正在“处理”中编写一个程序，以制作一个3-D散点图，使人可以使用PeasyCam在空间中旋转。数据从文本文件读入PVectors的ArrayList。整个代码如下所示。我不明白的是，importTextfile（）需要在draw（）中调用（反复），这会大大减慢速度。为什么不能在setup（）中调用一次呢？通过draw（）中的“ println（pointsList）”，我可以看到，如果未在importTextFile（）之前添加pointList，则它会发生变化。谁能解释为什么？

（更新：通过尝试构建一个最小的工作示例，我现在看到的问题是，当我制作一个PVector V，然后将其重写以将其映射到显示窗口时。只是在setup（）期间使用importTextFile（）。我用什么代替.get（），以便获得Arraylist中内容的副本，而不是ArrayList中实际值的指针？）

这是代码：

import peasy.*;
PeasyCam cam;
ArrayList <PVector>pointList;

int maxX = 0;
int maxY = 0;
int maxZ = 0;

int minX = 10000;
int minY = 10000;
int minZ = 10000;

int range = 0;

void setup() {
   size(500, 500, P3D);
   cam = new PeasyCam(this, width/2, width/2, width/2, 800);
   cam.setMinimumDistance(100);
   cam.setMaximumDistance(2000);
   pointList = new ArrayList();
   importTextFile();
   println(pointList);

 //Determine min and max along each axis
   for (int i=0; i < pointList.size(); i++) {
      PVector R = pointList.get(i);
      if (R.x > maxX) {
        maxX = (int)R.x;
      }
      if (R.x < minX) {
        minX = (int)R.x;
      }
      if (R.y > maxY) {
        maxY = (int)R.y;
      }
      if (R.y < minY) {
        minY = (int)R.y;
      }
      if (R.z > maxZ) {
        maxZ = (int)R.z;
      }
      if (R.z < minZ) {
        minZ = (int)R.z;
      }
   }

   if (maxX - minX > range) {
      range = maxX - minX;
   }
   if (maxY - minY > range) {
      range = maxY - minY;
   }
   if (maxZ - minZ > range) {
      range = maxZ - minZ;
   }
   println(pointList);
}

void draw() {
    //importTextFile();  Uncomment to make run properly
    println(pointList);
    background(255);
    stroke(0);
    strokeWeight(2);
    line(0, 0, 0, width, 0, 0);
    line(0, 0, 0, 0, width, 0);
    line(0, 0, 0, 0, 0, width);
    stroke(150);
    strokeWeight(1);
    for (int i=1; i<6; i++) {
      line(i*width/5, 0, 0, i*width/5, width, 0);
      line(0, i*width/5, 0, width, i*width/5, 0);
    }
    lights();
    noStroke();
    fill(255, 0, 0);
    sphereDetail(10);

    //**The problem is here**
    for (int i=0; i < pointList.size(); i++) {
      PVector V = pointList.get(i);
      V.x = map(V.x, minX-50, minX+range+50, 0, width);
      V.y = map(V.y, minY-50, minY+range+50, 0, width);
      V.z = map(V.z, minZ-50, minZ+range+50, 0, width);
      pushMatrix();
      translate(V.x, V.y, V.z);
      sphere(4);
      popMatrix();
    }
}

void importTextFile() {
       String[] strLines = loadStrings("positions.txt");
       for (int i = 0; i < strLines.length; ++i) {
         String[] arrTokens = split(strLines[i], ',');
         float xx = float(arrTokens[2]);
         float yy = float(arrTokens[1]);
         float zz = float(arrTokens[0]);
         pointList.add( new PVector(xx,zz,yy) );
       }
    }

最佳答案

由于PVector是一个对象，当您执行PVector V = pointList.get(i)时，会将pointList中该特定元素的引用传递给V。它是内存中的地址。因此，现在V和pointList.get（number）共享相同的内存地址。任一个的任何更改都会改变两者，因为它们是指向同一位置的两个不同的指针。
但是，如果您这样做：

PVector V = new PVector(pointList.get(i).x, pointList.get(i).y, pointList.get(i).z);

V将是一个新对象，一切都会按您的要求运行，因为现在V具有它自己的内存地址。和poinList将保持不变。其他对象（例如数组）也是如此，请尝试看一下：

int[] one = new int[3];
int[] two = new int[3];

void setup(){
  one[0] = 0;
  one[1] = 1;
  one[2] = 2;

  print("one firstPrint -> \n");
  println(one);

  two = one;

  print("two firstPrint -> \n");
  println(two);

  two[2] = 4;

  // we didn't mean to change one, but...
  print("one secondPrint -> \n");
  println(one);
}