ocaml - 如何在ocaml中可视化/绘制自动机？

我正在做自动机的合成。所以最后，我也想绘制合成的自动机。那么，在ocaml中是否有用于该库的库？还是为任何图形可视化工具编写了ocaml包装器？我已经用谷歌搜索了，但是对于ocaml并没有得到多少。对ocamlgraph有何评论？我将在合成自动机中获得100多个状态。

最佳答案

使用ocamlgraph-这是一个图形库，可以为您生成点/ graphviz文件，但还可以做很多其他有趣的事情来处理自动机。
该库可以执行固定点，生成树，图形搜索，查找强连接的组件等，等等。

这是一些带标签的有向图的有向图的完整示例+用于进行深度优先搜索的模块+用于为其创建点表示的模块：

(* representation of a node -- must be hashable *)
module Node = struct
   type t = int
   let compare = Pervasives.compare
   let hash = Hashtbl.hash
   let equal = (=)
end

(* representation of an edge -- must be comparable *)
module Edge = struct
   type t = string
   let compare = Pervasives.compare
   let equal = (=)
   let default = ""
end

(* a functional/persistent graph *)
module G = Graph.Persistent.Digraph.ConcreteBidirectionalLabeled(Node)(Edge)

(* more modules available, e.g. graph traversal with depth-first-search *)
module D = Graph.Traverse.Dfs(G)

(* module for creating dot-files *)
module Dot = Graph.Graphviz.Dot(struct
   include G (* use the graph module from above *)
   let edge_attributes (a, e, b) = [`Label e; `Color 4711]
   let default_edge_attributes _ = []
   let get_subgraph _ = None
   let vertex_attributes _ = [`Shape `Box]
   let vertex_name v = string_of_int v
   let default_vertex_attributes _ = []
  let graph_attributes _ = []
end)

这样就可以编写程序了；例如像这样的东西：

(* work with the graph ... *)
let _ =
   let g = G.empty in
   let g = G.add_edge_e ...
   ...
   let file = open_out_bin "mygraph.dot" in
   let () = Dot.output_graph file g in
   ...
   if D.has_cycle g then ... else ...

关于ocaml - 如何在ocaml中可视化/绘制自动机？，我们在Stack Overflow上找到一个类似的问题：https://stackoverflow.com/questions/8999557/