python - 用Cython包装包含wxString的C++类

我正在研究一个Python扩展，以配合使用GUI的WxWIDGET编写的C++应用程序。我正在使用Cython，并且让基本系统（构建工具，加上带有适当版本细节的starter扩展等）工作得很愉快。
我只想让后端（非GUI）功能可用，比如文件解析和处理。但是，所有类（不仅仅是GUI类）都对字符串数据使用wxString，例如在下面的最小示例中：

#include <wx/string.h>

class MyClass{
    wxString name;
    wxString get_name(){
        return this->name;
    }
};

我的问题是，包装这样一门课最好的方法是什么？Python字符串和wxString实例之间是否有一种简单的接口方式？或者我也需要包装wxString类吗？我能不能以某种方式与wxPython端口连接以避免重新发明轮子？

最佳答案

我使用staticwxString::FromUTF8()函数将Python转换为wxString，然后使用wxString.ToUTF8()函数将其转换为另一个方向。下面是我想出的代码：

# Import the parts of wxString we want to use.
cdef extern from "wx/string.h":
    cdef cppclass wxString:
        char* ToUTF8()


# Import useful static functions from the class.
cdef extern from "wx/string.h" namespace "wxString":
   wxString FromUTF8(char*)


# Function to convert from Python string to wxString. This can be given either
# a unicode string, or a UTF-8 encoded byte string. Results with other encodings
# are undefined and will probably lead to errors.
cdef inline wxString from_python(python_string):
    # If it is a Python unicode string, encode it to a UTF-8 byte string as this
    # is how we will pass it to wxString.
    if isinstance(python_string, unicode):
        byte_string = python_string.encode('UTF-8')

    # It is already a byte string, and we have no choice but to assume its valid
    # UTF-8 as theres no (sane/efficient) way to detect the encoding.
    else:
        byte_string = python_string

    # Turn the byte string (which is still a Python object) into a C-level char*
    # string.
    cdef char* c_string = byte_string

    # Use the static wxString::FromUTF8() function to get us a wxString.
    return FromUTF8(c_string)


# Function to convert a wxString to a UTF-8 encoded Python byte string.
cdef inline object to_python_utf8(wxString wx_string):
    return wx_string.ToUTF8()


# Function to convert a wxString to a Python unicode string.
cdef inline object to_python_unicode(wxString wx_string):
    # Since the wxString.ToUTF8() method returns a const char*, we'd have to try
    # and cast it if we wanted to do it all in here. I've tried this and can't
    # seem to get it to work. But calling the to_python_utf8() function
    # means Cython handles the conversions and it all just works. Plus, since
    # they are defined as inline functions this may well be simplified down when
    # compiled.
    byte_string = to_python_utf8(wx_string)

    # Decode it to a unicode string and we're done.
    return byte_string.decode('UTF-8')

只需将它放在一个.pxd文件中（就我个人而言，我将它作为wx/string.pxd放在一个子目录中—如果您选择这样做，请确保您也创建了一个wx/__init__.pdx）。然后根据需要调用函数：

cimport wx.string

wx_string = wx.string.from_python(python_string)
python_string = wx.string.to_python_unicode(wx_string)