我正在为数独的数独变体(多数独)的概念化求解器，其中多个板重叠，如下所示:
如果我对游戏的理解正确，则必须以使任何两个或多个网格之间的重叠成为每个网格解决方案的一部分的方式来解决每个网格。
我不确定应该如何考虑。有人有任何提示/概念线索吗？此外，如果您想到了人工智能方面的任何话题，我也想听听。
最佳答案
约束编程(CP)
数独是一个典型的约束编程问题。您有一组变量(网格中的字段)，每个变量都有一个域(此处是0到9的数字)和对这些变量的一组约束(事实是，数字在行，列，块， ...)。
解决约束编程问题的一种通用方法是弧一致性(AC):传播约束。通过(部分)填充的变量，可以减少其余变量的域，等等。最后，如果传播不再会使域变小，则必须做出选择。
通过选择，您可以为某个变量选择一个值。一个好的策略是选择一个剩余少量可能值的变量。接下来，您将再次传播，并可能做出其他选择，依此类推。
您的程序有可能发现选择错误:它使一个或多个变量的域为空。在这种情况下，您会回溯:撤销先前做出的选择(以及选择之后的传播)，然后选择另一个值。
显然，此答案并非旨在提供对该主题的深入概述，但是Wikipedia page可以提供更好的概述和指向更多信息的指针。
有约束编程器，例如ECLiPSe(不是IDE)，MiniZinc等，可以简单地定义变量，域和约束。
用ECLiPSe解决问题
在ECLiPSe网站上，您可以找到a model for sudoku。阅读了有关ECLiPSe的一些文档后，您可以将此文件转换为多数独的模型。我做了一些小的修改，得到了以下快速解决方案:
% credits to Joachim Schimpf for his model of sudoku
% http://eclipseclp.org/examples/sudoku.ecl.txt
:- lib(ic).
:- import alldifferent/1 from ic_global.
solve(ProblemName) :-
problem(ProblemName,BA,BB),
multi_sudoku(3,BA,BB),
print_board(BA),
print_board(BB).
multi_sudoku(N,BA,BB) :-
sudoku(N,BA,VA),
sudoku(N,BB,VB),
N2 is N*N,
Inc is N2-N,
(multifor([I,J],1,N,1),param(BA,BB,Inc) do
BA[I+Inc,J+Inc] #= BB[I,J]
),
append(VA,VB,Vars),
labeling(Vars).
sudoku(N,Board,Vars) :-
N2 is N*N,
dim(Board,[N2,N2]),
Board[1..N2,1..N2] :: 1..N2,
( for(I,1,N2), param(Board,N2) do
Row is Board[I,1..N2],
alldifferent(Row),
Col is Board[1..N2,I],
alldifferent(Col)
),
( multifor([I,J],1,N2,N), param(Board,N) do
( multifor([K,L],0,N-1), param(Board,I,J), foreach(X,SubSquare) do
X is Board[I+K,J+L]
),
alldifferent(SubSquare)
),
term_variables(Board, Vars).
print_board(Board) :-
dim(Board, [N,N]),
( for(I,1,N), param(Board,N) do
( for(J,1,N), param(Board,I) do
X is Board[I,J],
( var(X) -> write(" _") ; printf(" %2d", [X]) )
), nl
), nl.
%----------------------------------------------------------------------
% Sample data
%----------------------------------------------------------------------
problem(1, [](
[](_, _, _, _, 6, _, _, _, _),
[](_, _, _, 4, _, 9, _, _, _),
[](_, _, 9, 7, _, 5, 1, _, _),
[](_, 5, 2, _, 7, _, 8, 9, _),
[](9, _, _, 5, _, 2, _, _, 4),
[](_, 8, 3, _, 4, _, 7, 2, _),
[](_, _, _, 2, _, 8, _, _, _),
[](_, _, _, 6, _, 4, _, _, _),
[](_, _, _, _, 5, _, _, _, _)
),
[](
[](_, _, _, _, 3, _, _, _, _),
[](_, _, _, 8, _, 7, _, _, _),
[](_, _, _, 1, _, 6, 3, _, _),
[](_, 9, 8, _, _, _, 1, 2, _),
[](2, _, _, _, _, _, _, _, 3),
[](_, 4, 3, _, _, _, 6, 5, _),
[](_, _, 7, 3, _, 5, 9, _, _),
[](_, _, _, 4, _, 2, _, _, _),
[](_, _, _, _, 6, _, _, _, _)
)
).
我从乔阿希姆·辛普(Joachim Schimpf)“借用”了数独的模型，因此归功于他。此外，请注意，此答案不建议在其他工具上使用ECLiPSe。在约束编程方面，我只是更熟悉Prolog工具链。但是，如果您更喜欢C++，Gecode将以大约相同(甚至更好)的性能来达到目的。
生成输出:
ECLiPSe Constraint Logic Programming System [kernel]
Kernel and basic libraries copyright Cisco Systems, Inc.
and subject to the Cisco-style Mozilla Public Licence 1.1
(see legal/cmpl.txt or http://eclipseclp.org/licence)
Source available at www.sourceforge.org/projects/eclipse-clp
GMP library copyright Free Software Foundation, see legal/lgpl.txt
For other libraries see their individual copyright notices
Version 6.1 #199 (x86_64_linux), Sun Mar 22 09:34 2015
[eclipse 1]: solve(1).
lists.eco loaded in 0.00 seconds
WARNING: module 'ic_global' does not exist, loading library...
queues.eco loaded in 0.00 seconds
ordset.eco loaded in 0.01 seconds
heap_array.eco loaded in 0.00 seconds
graph_algorithms.eco loaded in 0.03 seconds
max_flow.eco loaded in 0.00 seconds
flow_constraints_support.eco loaded in 0.00 seconds
ic_sequence.eco loaded in 0.01 seconds
ic_global.eco loaded in 0.07 seconds
2 1 4 8 6 3 9 5 7
8 7 5 4 1 9 2 6 3
6 3 9 7 2 5 1 4 8
4 5 2 3 7 1 8 9 6
9 6 7 5 8 2 3 1 4
1 8 3 9 4 6 7 2 5
5 4 1 2 3 8 6 7 9
7 2 8 6 9 4 5 3 1
3 9 6 1 5 7 4 8 2
6 7 9 5 3 4 2 8 1
5 3 1 8 2 7 4 6 9
4 8 2 1 9 6 3 7 5
7 9 8 6 5 3 1 2 4
2 6 5 7 4 1 8 9 3
1 4 3 2 8 9 6 5 7
8 2 7 3 1 5 9 4 6
9 1 6 4 7 2 5 3 8
3 5 4 9 6 8 7 1 2
我的机器花了大约0.11秒。此外，总共有60个有效解决方案。
最后两个“矩阵”显示了两个数独的解决方案。如您所见(我还没有完全检查过)，它们共享一个块(相同的输出)，并且所有数独约束都有效。解决方案的更方便的表示如下所示:
+-----+-----+-----+
|2 1 4|8 6 3|9 5 7|
|8 7 5|4 1 9|2 6 3|
|6 3 9|7 2 5|1 4 8|
+-----+-----+-----+
|4 5 2|3 7 1|8 9 6|
|9 6 7|5 8 2|3 1 4|
|1 8 3|9 4 6|7 2 5|
+-----+-----+-----+-----+-----+
|5 4 1|2 3 8|6 7 9|5 3 4|2 8 1|
|7 2 8|6 9 4|5 3 1|8 2 7|4 6 9|
|3 9 6|1 5 7|4 8 2|1 9 6|3 7 5|
+-----+-----+-----+-----+-----+
|7 9 8|6 5 3|1 2 4|
|2 6 5|7 4 1|8 9 3|
|1 4 3|2 8 9|6 5 7|
+-----+-----+-----+
|8 2 7|3 1 5|9 4 6|
|9 1 6|4 7 2|5 3 8|
|3 5 4|9 6 8|7 1 2|
+-----+-----+-----+
我不了解Python中的约束编程库，也不了解ECLiPSe到Python的端口。但是我的经验是，所有现代编程语言都具有这种工具。
使用约束编程工具(例如ECLiPSe，Gecode等)的优势首先，您只需要指定问题，如何解决就不必担心。此外，此类库在约束编程方面进行了30年的研究:它们经过了极大的优化，以大多数人无法想象的方式利用约束和结构，并且包含错误的可能性也比定制算法要小。此外，如果找到新的策略，算法等，则ECLiPSe的更新将导致更快地处理模型。
的缺点是，使用约束编程仍无法解决一些难题:搜索空间太大，约束过于复杂，无法将域缩减为小集合，并且处理能力不足以解决问题足够的选择以便找到有效的解决方案。另一个缺点是，指定问题并不总是那么容易:尽管程序员旨在设计好的约束，但是总会遇到复杂的问题，没有为之定义易于使用的约束。
其他技巧
显然，还有其他AI技术可以解决问题。 进化计算是解决硬搜索和优化问题的常用技术:首先填充数独以允许某些值有误，然后在每个步骤修复一个或多个字段。有时他们引入新的错误，以便最终找到有效的解决方案。
关于artificial-intelligence - 多数独AI方法，我们在Stack Overflow上找到一个类似的问题：https://stackoverflow.com/questions/34246972/