sparql - 找到两个最近的点的邻居

我想找到每个点的两个最近的邻居

数据集：

:p1 :has_position 1 .
:p2 :has_position 2 .
:p3 :has_position 3 .
:p4 :has_position 4 .

预期成绩 ：

?POINT  ?NEIGHBORS
"p1"    "p2; p3"
"p2"    "p1; p3"
"p3"    "p2; p4"
"p4"    "p2; p3"

我尝试这样的事情：

SELECT ?POINT ?POS (group_concat(?idPointN;separator='; ' )as ?NEIGHBORS)
WHERE{
    ?idPoint :has_position ?POS .
    ?idPointN :has_position ?POSN . FILTER (?idPoint != ?idPointN)
}
GROUP BY ?POINT ?POS

返回点的所有邻居。我想在ORDER BY(?POS-?POSN)中执行limit 2和group_concat之类的操作，但我不知道该怎么做。

编辑：

我写这个查询

SELECT ?POINT ?NEIGHBOR
WHERE{
    ?idPoint rdfs:label ?POINT . FILTER(?idN != ?idPoint)
    ?idPoint :has_position ?POS .


    ?idN rdfs:label ?NEIGHBOR .
    ?idN :has_position ?POSN .
}
ORDER BY ?POINT abs(?POS-?POSN)

对于每个点，它给我所有邻居的最接近的顺序。

我怎么能只有2个最接近的？并在同一行上？

最佳答案

在SPARQL中，获取每项最高n的查询确实很棘手，而且实际上还没有很好的方法。它几乎总是归结为一些怪异的破解。首先，用前缀声明的数据：

@prefix : <urn:ex:>

:p1 :has_position 1 .
:p2 :has_position 2 .
:p3 :has_position 3 .
:p4 :has_position 4 .

然后查询。选择行中有一个很长的字符串连接，但这仅仅是为了删除前缀，就像您在问题中描述的那样。在这种情况下，“ hack”正在认识到两个最接近的点q和r将使数量| p − q |最小化。 + | p − r |，因此我们可以计算该数量并采用赋予它的q和r值。您还需要确保对q和r进行一些排序，否则将得到重复的结果（因为您可以只交换q和r）。

prefix : <urn:ex:>

select ?p (concat(strafter(str(?q),str(:)),", ",strafter(str(?r),str(:))) as ?neighbors) {
  ?p :has_position ?pos1 .
  ?q :has_position ?pos2 .
  ?r :has_position ?pos3 .
  filter(?p != ?q && ?p != ?r)
  filter(str(?q) < str(?r))

  filter not exists {
    ?qq :has_position ?pos22 .
    ?rr :has_position ?pos33 .
    filter(?p != ?qq && ?p != ?rr)
    filter(str(?qq) < str(?rr))
    filter((abs(?pos1 - ?pos22) + abs(?pos1 - ?pos33)) <
           (abs(?pos1 - ?pos2)  + abs(?pos1 - ?pos3)))
  }
}

-------------------
| p   | neighbors |
===================
| :p1 | "p2, p3"  |
| :p2 | "p1, p3"  |
| :p3 | "p2, p4"  |
| :p4 | "p2, p3"  |
-------------------

现在，您还可以使用子查询来执行此操作，该子查询查找每个p的最小数量，然后在外部查询中查找产生它的q和r值：

prefix : <urn:ex:>

select ?p (concat(strafter(str(?q), str(:)), ", ", strafter(str(?r), str(:))) as ?neighbors) {
  { select ?p (min(abs(?pos1 - ?pos2) + abs(?pos1 - ?pos3)) as ?d) {
      ?p :has_position ?pos1 .
      ?q :has_position ?pos2 .
      ?r :has_position ?pos3 .
      filter(?p != ?q && ?p != ?r)
      filter(str(?q) < str(?r))
    }
    group by ?p
  }

  ?p :has_position ?pos1 .
  ?q :has_position ?pos2 .
  ?r :has_position ?pos3 .
  filter(?p != ?q && ?p != ?r)
  filter(str(?q) < str(?r))
  filter(abs(?pos1 - ?pos2) + abs(?pos1 - ?pos3) = ?d)
}

-------------------
| p   | neighbors |
===================
| :p1 | "p2, p3"  |
| :p2 | "p1, p3"  |
| :p3 | "p2, p4"  |
| :p4 | "p2, p3"  |
-------------------

关于sparql - 找到两个最近的点的邻居，我们在Stack Overflow上找到一个类似的问题：https://stackoverflow.com/questions/36398438/