emacs - 着色当前行号

我正在使用global-linum-mode作为行号。如果当前行的行号以不同的颜色(和/或不同的背景)突出显示，那就太好了。任何人都有一个想法如何实现这一目标？

谢谢!

最佳答案

我从以前对Relative Line Numbers In Emacs的答案中得出了这个答案，因为它涉及到在linum格式化过程中记住当前行号的问题。

我从linum面继承而来，但是使用了hl-line的背景色。如果前景和背景无法很好地匹配，则可以使用
M-x customize-face RET my-linum-hl RET

(require 'hl-line)

(defface my-linum-hl
  `((t :inherit linum :background ,(face-background 'hl-line nil t)))
  "Face for the current line number."
  :group 'linum)

(defvar my-linum-format-string "%3d")

(add-hook 'linum-before-numbering-hook 'my-linum-get-format-string)

(defun my-linum-get-format-string ()
  (let* ((width (1+ (length (number-to-string
                             (count-lines (point-min) (point-max))))))
         (format (concat "%" (number-to-string width) "d")))
    (setq my-linum-format-string format)))

(defvar my-linum-current-line-number 0)

(setq linum-format 'my-linum-format)

(defun my-linum-format (line-number)
  (propertize (format my-linum-format-string line-number) 'face
              (if (eq line-number my-linum-current-line-number)
                  'my-linum-hl
                'linum)))

(defadvice linum-update (around my-linum-update)
  (let ((my-linum-current-line-number (line-number-at-pos)))
    ad-do-it))
(ad-activate 'linum-update)

与其他答案一样，此方法在生成动态宽度方面比默认的dynamic格式更有效，但是您可以通过注释掉(add-hook linum-before-numbering-hook 'my-linum-get-format-string)行来使用静态宽度以实现最大速度(并可以选择修改my-linum-format-string的初始值以设置首选参数)宽度)。

Linum

emacs - 着色当前行号