postgresql - 通过ecto存储jsonb数据

我正试图通过exto把jsonb数据传给postgres。我希望能够获取一个有效的JSON字符串，将其作为graphql参数添加，并在表中看到该JSON。
迁移

defmodule MyApp.CreateJsonTable do
  use Ecto.Migration

  def change do
    create table(:geodata) do
      add(:json, :map)

      timestamps(type: :utc_datetime)
    end
  end
end

我的理解是，您需要为JSONB定义一个Poison结构，然后在插入时将其解码。

defmodule Geodatajson do
  use MyApp, :model

  embedded_schema do
    field(:latitude, :float)
    field(:longitude, :float)
  end
end

现在模型：

defmodule MyApp.Geodata do
  use MyApp, :model

  alias MyApp.Repo
  alias MyApp.Geodata

  schema "geodata" do
    embeds_one(:json, Geodatajson)

    timestamps()
  end

  def changeset(struct, params \\ %{}) do
    struct
    |> cast(params, [:json])
  end

  def add_geodata(str) do
    json = str |> Poison.decode!(as: Geodatajson)
    data = %Geodata{json: json}
    Repo.insert(data)
  end
end

我试着像这样传递数据：

iex> MyApp.Geodata.add_geodata("{\"latitude\": 1.23, \"longitude\": 4.56}")

但是JSONB没有被解码：

{:ok,
 %MyApp.Geodata{
   __meta__: #Ecto.Schema.Metadata<:loaded, "geodata">,
   id: 26,
   inserted_at: ~N[2018-04-28 13:28:42.346382],
   json: %Geodatajson{
     id: "3b22ef94-92eb-4c64-8174-9ce1cb88e8c5",
     latitude: nil,
     longitude: nil
   },
   updated_at: ~N[2018-04-28 13:28:42.346392]
 }}

我该怎么做才能把这些数据输入postgres？

最佳答案

Poison的as:要求传递一个struct实例，而不仅仅是模块的名称。

json = str |> Poison.decode!(as: Geodatajson)

应该是：

json = str |> Poison.decode!(as: %Geodatajson{})

关于postgresql - 通过ecto存储jsonb数据，我们在Stack Overflow上找到一个类似的问题：https://stackoverflow.com/questions/50077124/