fortran - 使用MPI IO编写多个分布式阵列

我正在重写一个使用MPI在一个方向上并行化的数值模拟代码。
到目前为止，包含数据的数组已由主MPI进程保存，这意味着将数据从所有MPI进程传输到一个，并分配巨大的数组来存储整个对象。它不是很有效，也不是一流的，并且对于大分辨率来说是个问题。

因此，我试图使用MPI-IO直接从分布式阵列写入文件。我的约束之一是写入的文件需要遵守fortran的“未格式化”格式(即，每个字段前后的4个字节整数，指示其大小)。

我编写了一个简单的测试程序，该程序仅在将一个分布式数组写入文件时才起作用。但是，当我编写多个数组时，文件的总大小是错误的，并且与等效的fortran“未格式化”文件进行比较时，文件是不同的。

这是示例代码:

module arrays_dim
   implicit none
   INTEGER,        PARAMETER :: dp   = kind(0.d0)
   integer,        parameter :: imax = 500
   integer,        parameter :: jmax = 50
   integer,        parameter :: kmax = 10
end module arrays_dim
module mpi_vars
   use mpi
   implicit none
   integer, save          :: ierr, myID, numprocs
   integer, save          :: i_start, i_end, i_mean, i_loc
   integer, save          :: subArray, fileH
   integer(MPI_OFFSET_KIND), save   :: offset, currPos
end module mpi_vars

program test
   use mpi
   use arrays_dim
   use mpi_vars
   real(dp), dimension(0:imax,0:jmax+1,0:kmax+1) :: v, w
   real(dp), dimension(:,:,:), allocatable       :: v_loc, w_loc
   integer                                       :: i, j, k

   call MPI_INIT(ierr)
   call MPI_COMM_RANK(MPI_COMM_WORLD, myID, ierr)
   call MPI_COMM_SIZE(MPI_COMM_WORLD, numprocs, ierr)

   i_mean = (imax+1)/numprocs
   i_start = myID*i_mean
   i_end   = i_start+i_mean-1
   if(i_mean*numprocs<imax+1) then
    if(myID == numprocs-1) i_end = imax
   endif
   i_loc = i_end - i_start + 1
   allocate(v_loc(i_start:i_end,0:jmax+1,0:kmax+1))
   allocate(w_loc(i_start:i_end,0:jmax+1,0:kmax+1))

   print*, 'I am:', myID, i_start, i_end, i_loc
   do k=0,kmax+1
      do j=0,jmax+1
         do i=0,imax
            v(i,j,k) = i+j+k
            w(i,j,k) = i*j*k
         enddo
      enddo
   enddo

   if(myID==0) then
       open(10,form='unformatted')
       write(10) v
       !write(10) w
       close(10)
   endif

   do k=0,kmax+1
      do j=0,jmax+1
         do i=i_start,i_end
            v_loc(i,j,k) = i+j+k
            w_loc(i,j,k) = i*j*k
         enddo
      enddo
   enddo

   call MPI_Type_create_subarray (3, [imax+1, jmax+2, kmax+2], [i_loc, jmax+2, kmax+2], &
                                     [i_start, 0, 0], &
                                    MPI_ORDER_FORTRAN, MPI_DOUBLE_PRECISION, subArray,  ierr)
   call MPI_Type_commit(subArray, ierr)
   call MPI_File_open(MPI_COMM_WORLD, 'mpi.dat',         &
                     MPI_MODE_WRONLY + MPI_MODE_CREATE + MPI_MODE_APPEND, &
                     MPI_INFO_NULL, fileH, ierr )


   call saveMPI(v_loc, (i_loc)*(jmax+2)*(kmax+2))
   !call saveMPI(w_loc, (i_loc)*(jmax+2)*(kmax+2))

   call MPI_File_close(fileH, ierr)

   deallocate(v_loc,w_loc)
   call MPI_FINALIZE(ierr)
end program test
!
subroutine saveMPI(array, n)
   use mpi
   use arrays_dim
   use mpi_vars

   implicit none
   real(dp), dimension(n) :: array
   integer                   :: n

   offset = (imax+1)*(jmax+2)*(kmax+2)*8
   if(myID==0) then
     call MPI_File_seek(fileH, int(0,MPI_OFFSET_KIND), MPI_SEEK_CUR, ierr)
     call MPI_File_write(fileH, [(imax+1)*(jmax+2)*(kmax+2)*8], 1, MPI_INTEGER, MPI_STATUS_IGNORE, ierr)
     call MPI_File_seek(fileH, offset, MPI_SEEK_CUR, ierr)
     call MPI_File_write(fileH, [(imax+1)*(jmax+2)*(kmax+2)*8], 1, MPI_INTEGER, MPI_STATUS_IGNORE, ierr)
   endif
   call MPI_File_set_view(fileH, int(4,MPI_OFFSET_KIND), MPI_DOUBLE_PRECISION, subArray, 'native', MPI_INFO_NULL, ierr)
   call MPI_File_write_all(fileH, array, (i_loc)*(jmax+2)*(kmax+2), MPI_DOUBLE_PRECISION, MPI_STATUS_IGNORE, ierr)
end subroutine saveMPI

当对!write(10) w和!call saveMPI(w_loc, (i_loc)*(jmax+2)*(kmax+2))行进行注释时(即我只写了v数组)，该代码可以正常工作:

mpif90.openmpi -O3 -o prog main.f90
mpirun.openmpi -np 4 ./prog
cmp mpi.dat fort.10

cmp不会生成输出，因此文件是相同的。
但是，如果我取消注释这些行，则生成的文件(mpi.dat和fort.10)是不同的。我确定问题出在定义偏移量的方式上，该偏移量用于在文件的正确位置写入数据，但是我不知道如何向第二次调用saveMPI指示初始位置应为结尾文件。我想念什么？

最佳答案

正如您所期望的那样，只有第一个对saveMPI的调用才能正常工作。从第二次调用开始，一切都变得困惑了。以下是发生情况的一些迹象:

MPI_File_set_view将独立文件指针和共享文件指针重置为零。有关更多详细信息，请参见MPI_File_set_view。因此，当您在v中调用w时，实际上是在使用MPI_File_set_view数据覆盖saveMPI数据。

和 MPI_File_write ，数据被写入当前 View 指定的文件的那些部分。这意味着您将尺寸信息添加到文件中的方式与先前为v设置的 View 并不完全兼容。

用MPI_File_seek调用MPI_SEEK_CUR设置相对于各个指针当前位置的位置。因此，对于第二个调用，它相对于进程0

的单个指针

我没有使用太多并行IO，因此除非我没有时间去研究文档，否则我将无能为力。我可以给出的提示是:

向saveMPI添加一个附加参数，该参数将包含要写入的数据的绝对位移；这可以是[in out] arg。对于第一个调用，它将为零，而对于随后的调用，它将是已写入文件的所有数据的大小，包括大小信息。可以用saveMPI更新。

在写入大小信息之前(由进程0调用)调用MPI_File_set_view以将 View 重置为MPI_File_open最初给定的线性字节流。这可以通过在调用etype时将filetype和MPI_BYTE都设置为MPI_File_set_view来完成。查看doc of MPI_File_open 以获取更多信息。然后，您将不得不在MPI_File_set_view中调用saveMPI。

您的saveMPI子例程可能看起来像

subroutine saveMPI(array, n, disp)
    use mpi
    use arrays_dim
    use mpi_vars

    implicit none
    real(dp), dimension(n) :: array
    integer                   :: n, disp

    offset = (imax+1)*(jmax+2)*(kmax+2)*8
    call MPI_File_set_view(fileH, int(disp,MPI_OFFSET_KIND), MPI_BYTE, MPI_BYTE, 'native', MPI_INFO_NULL, ierr)
    if(myID==0) then
        call MPI_File_seek(fileH, int(0,MPI_OFFSET_KIND), MPI_SEEK_END, ierr)
        call MPI_File_write(fileH, [(imax+1)*(jmax+2)*(kmax+2)*8], 1, MPI_INTEGER, MPI_STATUS_IGNORE, ierr)
        call MPI_File_seek(fileH, int(offset,MPI_OFFSET_KIND), MPI_SEEK_CUR, ierr)
        call MPI_File_write(fileH, [(imax+1)*(jmax+2)*(kmax+2)*8], 1, MPI_INTEGER, MPI_STATUS_IGNORE, ierr)
    endif
    call MPI_File_set_view(fileH, int(disp+4,MPI_OFFSET_KIND), MPI_DOUBLE_PRECISION, subArray, 'native', MPI_INFO_NULL, ierr)
    call MPI_File_write_all(fileH, array, (i_loc)*(jmax+2)*(kmax+2), MPI_DOUBLE_PRECISION, MPI_STATUS_IGNORE, ierr)
    disp = disp+offset+8
end subroutine saveMPI

并称为:

disp = 0
call saveMPI(v_loc, (i_loc)*(jmax+2)*(kmax+2), disp)
call saveMPI(w_loc, (i_loc)*(jmax+2)*(kmax+2), disp)

最后，请确保在两个调用之间删除该文件，因为您使用的是MPI_MODE_APPEND。

关于fortran - 使用MPI IO编写多个分布式阵列，我们在Stack Overflow上找到一个类似的问题：https://stackoverflow.com/questions/32280100/