c++ - 使用 CLion 和 CMake 的 CImg X11 链接错误

我在 CLion (Ubuntu) 中有一个使用 CImg 库的 C++ 项目。目前，我无法正确构建项目。我在 main.cpp 文件中包含了 CImg.h 文件。我得到的输出类似于 here 。我通过在终端中运行以下命令确保安装了 X11 工具:

sudo apt-get install libx11-dev

在上面链接的问题中，有一个答案指出要添加以下编译器选项:

-L/usr/X11R6/lib -lm -lpthread -lX11

但是，我遇到了两个问题。首先，我在 CLion 中使用 CMake，而不是命令窗口，所以我不确定如何使用此命令(假设它有效)。其次，上面指定的路径在我的电脑上似乎不存在——/usr 中没有 X11R6 文件夹。因此，如何正确链接所需的 X11 库，以便我可以开始使用 CImg？

(另外，我不知道这是否相关，但我没有安装 Magick++。)

最佳答案

遗憾的是， CImg 程序需要构建的方式在文档中并不十分清楚。这是我的看法:

第 1 步 - 您需要在屏幕上显示图像吗？

不，别笑，您可能正在 headless Web 服务器上操作图像。

如果你做 而不是 需要显示图像，你必须在 之前做 #define cimg_display 0 你包括 "CImg.h"

如果您确实需要显示图像，并且您使用的是 Windows，则需要使用 gdi32

链接

如果您确实需要显示图像并且您使用的是 macOS、OSX 或 Unix/Linux，则需要设置 X11 的 header 包含路径并与之链接

第 2 步 - 您是否需要读取/写入 PNG 格式的图像？

如果你做 而不是 需要这个功能，或者你很乐意让 CImg 使用你已经安装的 ImageMagick 来读/写 PNG 图像，什么都不做。

如果你想使用 CImg 的内置功能来读/写 PNG 图像，你需要在 之前对 #define cimg_use_png 1 你包含 "CImg.h" ，并且你需要设置 的头部包含路径和链接 libpng ojit_ libpng 和 libz 。

第 3 步 - 您需要读/写 JPEG 格式的图像吗？

如果你做 而不是 需要这个功能，或者你很高兴让 CImg 使用你已经安装的 ImageMagick 来读/写 JPEG 图像，什么都不做。

如果你想使用 CImg 的内置功能来读/写 JPEG 图像，你需要在 之前 #define cimg_use_jpeg 1 你包含 "CImg.h" ，你需要设置 的头包含路径 libjpeg_ojit 与链接.

第 4 步 - 其他内容

另一件事是您可能需要链接数学和 POSIX 线程库(使用 libjpeg 作为链接器开关)，但我不确定如何在所有平台上进行检查，所以我将把它留给您 - 它可以添加它可能没有坏处。

所以，记住所有这些，并使用这个小测试程序:

#include "CImg.h"

using namespace cimg_library;

int main() {
    CImg<unsigned char> img(640,400,1,3);         // Define a 640x400 color image with 8 bits per color component.
    img.fill(0);                                  // Set pixel values to 0 (color : black)
    unsigned char purple[] = { 255,0,255 };       // Define a purple color
    img.draw_text(100,100,"Hello World",purple);  // Draw a purple "Hello world" at coordinates (100,100).
    img.display("Window Title");                  // Display the image in a display window.
    img.save_png("test.png");                     // Save as PNG to prove we linked correctly
    img.save_jpeg("test.jpg");                    // Save as JPG to prove we linked correctly
    return 0;
}

-lm -lpthread 中的 CMake CmakeLists.txt 将是这样的:

cmake_minimum_required(VERSION 3.6)
project(CImgProject)

set(CMAKE_CXX_STANDARD 11)

set(SOURCE_FILES main.cpp)
add_executable(CImgProject ${SOURCE_FILES})

# You can alter these according to your needs, e.g if you don't need to display images - set(YOU_NEED_X11 0)
set(YOU_NEED_X11 1)
set(YOU_NEED_PNG 1)
set(YOU_NEED_JPG 1)

if(${YOU_NEED_X11} EQUAL 1)
    message(STATUS "Looking for X11...")
    find_package(X11 REQUIRED)
    include_directories(${X11_INCLUDE_DIR})
    target_link_libraries(CImgProject ${X11_LIBRARIES})
else()
    target_compile_definitions(CImgProject PRIVATE cimg_display=0)
endif()

if(${YOU_NEED_JPG} EQUAL 1)
    message(STATUS "Looking for libjpg...")
    find_package(JPEG REQUIRED)
    include_directories(${JPEG_INCLUDE_DIR})
    target_link_libraries (CImgProject ${JPEG_LIBRARY})
    target_compile_definitions(CImgProject PRIVATE cimg_use_jpeg=1)
endif()

if(${YOU_NEED_PNG} EQUAL 1)
    message(STATUS "Looking for libpng...")
    find_package(PNG REQUIRED)
    include_directories(${PNG_INCLUDE_DIR})
    target_link_libraries (CImgProject ${PNG_LIBRARY})
    target_compile_definitions(CImgProject PRIVATE cimg_use_png=1)
endif()

毕竟这是我的，相当令人失望的形象!

关于c++ - 使用 CLion 和 CMake 的 CImg X11 链接错误，我们在Stack Overflow上找到一个类似的问题：https://stackoverflow.com/questions/38903996/