Haskell primPutChar 定义

我试图弄清楚基本的 IO Haskell 函数是如何定义的，所以我使用了 this reference 并且我得到了 putChar 函数定义:

putChar    :: Char -> IO ()
putChar    =  primPutChar

但是，现在我无法在任何地方找到有关此 primPutChar 函数的更多信息。也许它可能指的是一个预编译的函数，可以从共享对象中作为二进制文件使用？如果是这样，是否可以查看其源代码？

最佳答案

prim* 是什么意思

既然你是从报告的角度问这个问题，那我们也从报告的角度来回答这个问题:



这在 Haskell2010 by the way 中仍然相同。

它是如何在 GHC 中实现的

但是，您可以 have a look at base 's source 来查看它是如何在 GHC 中实现的:

putChar         :: Char -> IO ()
putChar c       =  hPutChar stdout c

从那里你将深入兔子洞。 hPutChar 如何知道如何打印东西？好吧，它没有。它只“缓冲”并检查您是否可以编写:

hPutChar :: Handle -> Char -> IO ()
hPutChar handle c = do
    c `seq` return ()
    wantWritableHandle "hPutChar" handle $ \ handle_  -> do
     hPutcBuffered handle_ c

写入是在 writeCharBuffer 中完成的，它会填充一个内部缓冲区，直到它填满(或已到达一行——这实际上取决于缓冲区模式):

writeCharBuffer h_@Handle__{..} !cbuf = do
  -- much code omitted, like buffering
      bbuf'' <- Buffered.flushWriteBuffer haDevice bbuf'
  -- more code omitted, like buffering

那么 flushWriteBuffer 在哪里定义的呢？它实际上是 stdout 的一部分:

stdout :: Handle
stdout = unsafePerformIO $ do
   setBinaryMode FD.stdout
   enc <- getLocaleEncoding
   mkHandle FD.stdout "<stdout>" WriteHandle True (Just enc)
                nativeNewlineMode{-translate newlines-}
                (Just stdHandleFinalizer) Nothing

stdout :: FD
stdout = stdFD 1

文件描述符( FD )是 BufferedIO 的一个实例:

instance BufferedIO FD where
  -- some code omitted
  flushWriteBuffer  fd buf = writeBuf' fd buf

和 writeBuf 使用 instance GHC.IO.Device.RawIO FD 's write ，最终 leads to :

writeRawBufferPtr loc !fd buf off len
  | isNonBlocking fd = unsafe_write -- unsafe is ok, it can't block
  | otherwise   = do r <- unsafe_fdReady (fdFD fd) 1 0 0
                     if r /= 0
                        then write
                        else do threadWaitWrite (fromIntegral (fdFD fd)); write
  where
    do_write call = fromIntegral `fmap`
                      throwErrnoIfMinus1RetryMayBlock loc call
                        (threadWaitWrite (fromIntegral (fdFD fd)))
    write         = if threaded then safe_write else unsafe_write
    unsafe_write  = do_write (c_write (fdFD fd) (buf `plusPtr` off) len)
    safe_write    = do_write (c_safe_write (fdFD fd) (buf `plusPtr` off) len)

where we can see c_safe_write and c_write, which are usually bindings to C library functions:

foreign import capi unsafe "HsBase.h write"
   c_write :: CInt -> Ptr Word8 -> CSize -> IO CSsize

因此， putChar 使用 write 。至少在 GHC 的实现中。然而，该报告不需要该实现，因此允许另一个编译器/运行时使用其他函数。

TL; 博士

GHC 的实现使用 write 和内部缓冲区来写入内容，包括单个字符。

关于Haskell primPutChar 定义，我们在Stack Overflow上找到一个类似的问题：https://stackoverflow.com/questions/45133494/