我编写了一个 Perl 脚本来使用 Win32::OLE 读取 Microsoft Word 文档内容。
我的问题是包含编号列表的文档(以 1、2、3……开头)。我的 Perl 脚本无法获得该数字。我只能得到文本内容,而不是数字。
请建议如何以保留文本编号的方式将该编号列表转换为纯文本。
最佳答案
我的博客文章 Extract bullet lists from PowerPoint slides using Perl and Win32::OLE 展示了如何使用 PowerPoint 执行此操作。事实证明,使用 Word 的任务要简单一些。
#!/usr/bin/env perl
use strict;
use warnings;
use feature 'say';
use Carp qw( croak );
use Const::Fast;
use Path::Class;
use Try::Tiny;
use Win32::OLE;
use Win32::OLE::Const ('Microsoft.Word');
use Win32::OLE::Enum;
$Win32::OLE::Warn = 3;
run(@ARGV);
sub run {
my $docfile = shift;
# Croaks if it cannot resolve
$docfile = file($docfile)->absolute->resolve;
my $word = get_word();
my $doc = $word->Documents->Open(
{
FileName => "$docfile",
ConfirmConversions => 0,
AddToRecentFiles => 0,
Revert => 0,
ReadOnly => 1,
}
);
my $pars = Win32::OLE::Enum->new($doc->Paragraphs);
while (my $par = $pars->Next) {
print_paragraph($par);
}
}
sub print_paragraph {
my $par = shift;
my $range = $par->Range;
my $fmt = $range->ListFormat;
my $bullet = $fmt->ListString;
my $text = $range->Text;
unless ($bullet) {
say $text;
return;
}
my $level = $fmt->ListLevelNumber;
say ">" x $level, join(' ', $bullet, $text);
return;
}
sub get_word {
my $word;
try { $word = Win32::OLE->GetActiveObject('Word.Application') }
catch { croak $_ };
return $word if $word;
$word = Win32::OLE->new('Word.Application', sub { $_[0]->Quit });
return $word if $word;
croak sprintf('Cannot start Word: %s', Win32::OLE->LastError);
}
给定以下 Word 文档:
它生成输出:
这是一个文件
>1.这是一个编号列表
>2.编号列表中的第二项
>3.第三个
回到正常段落。
>>a.另一个 list
>>b.是的,第二个项目来了
>>c.不太确定在这里放什么
>>>我。分项
Object Browser 是必不可少的。
关于perl - 使用 Perl 和 Win32::OLE,如何将 Word 文档中的编号列表转换为纯文本?,我们在Stack Overflow上找到一个类似的问题:https://stackoverflow.com/questions/23757926/