assembly - MZ(DOS，16位).EXE header 中页数和最后一页大小的重要性

我正在尝试学习如何使用程序集(NASM)创建Dos .EXE文件，手动构造 header 并将该文件组装为二进制文件。页面选项(页面总数和最后一页的字节数)都有问题。不管我设置的初始值有多小，该程序都可以工作。

在极端情况下，即使设置1个字节的1页，以下程序也会起作用:

;
; the smallest possible "Hello, World!" .EXE (DOS MZ) file
; assemble with:
; nasm -f bin -w+all -O0 smallest_hello_exe.asm -o ASM.EXE
;

bits 16
cpu 8086

;
; by setting cs:ip=-10h:100h instead of 0h:0h inside the .EXE header
; (identical assignments), we achieve the following two advantages:
; 1) ds==cs, so no "push cs pop ds" is needed in order for ds:dx
; to point to the message string
; 2) we can exit by int 20h instead of int 21h, thus omitting the
; ah=4ch assignment
; (int 20h requires that cs points to the PSP segment)
;

;
; we do not the address calculations to take the .EXE header into account
; so we must subtract its length (20h) by an "org -20h"
; but, since ip will be 100h, we must also issue an "org 100h"
; and, since 0x100-0x20=0xE0...

org 0xE0        ; 100h for ip value - 20h for header



section .text align=1
;
; the MZ .EXE header structure
; 28 bytes long
; 1 pararaph equals 16 bytes
; 1 page equals 512 bytes
; suggested reading: int 21h,ah=4bh procedure
;
host_exe_header:
.signature: dw 'MZ'     ; the 'MZ' characters
.last_page_size: dw 1   ; number of used bytes in the final file page, 0 for all
.page_count: dw 1       ; number of file pages including any last partial page
.reloc: dw 0            ; number of relocation entries after the header
.paragraphs: dw 2       ; size of header + relocation table, in paragraphs
.minalloc: dw 0         ; minimum required additional memory, in paragraphs
.maxalloc: dw 0xFFFF    ; maximum memory to be allocated, in paragraphs
.in_ss: dw 0            ; initial relative value of the stack segment
.in_sp: dw 0xF000       ; initial sp value
.checksum: dw 0         ; checksum: 1's complement of sum of all words
.in_ip: dw 100h         ; initial ip value
.in_cs: dw -10h         ; initial relative value of the text segment
.offset: dw 0           ; offset of the relocation table from start of header
.overlay: dw 0          ; overlay value (0h = main program)

; pad header (its size in bytes must be a multiple of 16)
times (32-$+$$) db 0

mov dx,message
mov ah,09h              ; write string ds:dx to stdout
int 21h
int 20h

section .data align=1
message: db 'Hello, World!$'

section .bss align=1

通过尝试不同的程序大小，我得出的结论是，Dos将每个页面的所有512字节加载到内存中。如果是这样，最后一页中的字节数的目的是什么？

它会干扰.bss，堆栈数据和/或动态内存分配吗？

最佳答案

总页数绝对不会被忽略，甚至不希望最初加载其所有文件的程序甚至使用它。他们将自己稍后阅读必要的片段。取决于操作系统的版本，bytes in the last page字段可能会或可能不会被忽略。也可以将其四舍五入为段落或磁盘扇区的边界。您不应该依赖特定的行为并正确地填写它。

您的测试代码有效，因为它很小，并且您的特定操作系统已选择将足够的代码加载到内存中。如果您使程序大于单个页面，但仍在1字段中指定page count，则可能您的代码将无法完全加载且无法正常工作。我试过了:

times (32-$+$$) db 0
times (512) nop
mov dx,message
mov ah,09h              ; write string ds:dx to stdout
int 21h
int 20h

如果page count为1，此操作将失败，但如果page count为2，则可以使用(用于测试的dosbox)。

关于assembly - MZ(DOS，16位).EXE header 中页数和最后一页大小的重要性，我们在Stack Overflow上找到一个类似的问题：https://stackoverflow.com/questions/14246493/