java - 如何在Xtend的“Activity 注释”中获得完整的返回类型转发？

我正在通过编写一个简单的“已记录”来尝试Xtend的 Activity 注释
注释，用于在调用方法时进行跟踪。基本上我想用Xtend编写:

@Logged
override onCreate()
{
   sampleFuncCall()
}

并在Java中获得如下内容:

@Override void onCreate()
{
   Log.d("TAG", "onCreate started");
   sampleFuncCall();
   Log.d("TAG", "onCreate ended");
}

这是我的第一次尝试:

@Active(LoggedAnnotationProcessor)
@Target(ElementType.METHOD)
annotation Logged {
}

class LoggedAnnotationProcessor extends AbstractMethodProcessor
{
    override doTransform(MutableMethodDeclaration method, extension TransformationContext context)
    {
        val prefix = "wrapped_"
        method.declaringType.addMethod(prefix + method.simpleName) [ m |
            m.static = method.static
            m.visibility = Visibility.PRIVATE
            m.docComment = method.docComment
            m.exceptions = method.exceptions
            method.parameters.forEach[ p | m.addParameter(p.simpleName, p.type) ]
            m.body = method.body
            m.primarySourceElement = method
            m.returnType = method.returnType
        ]
        val voidMethod = method.returnType === null || method.returnType.void
        method.body = [ '''
                try {
                    android.util.Log.d("TAG", "«method.simpleName» start");
                    «IF (!voidMethod) method.returnType» ret = «ENDIF»
                    «prefix + method.simpleName»(«method.parameters.map[simpleName].join(", ")»);
                    android.util.Log.d("TAG", "«method.simpleName» end");
                    «IF (!voidMethod)»return ret;«ENDIF»
                }
                catch(RuntimeException e) {
                    android.util.Log.d("TAG", "«method.simpleName» ended with exception "
                        + e.getClass().getSimpleName() + "\n" + e.getMessage());
                    throw e;
                }
            ''']
    }
}

(请注意，我找不到修改method.body的方法，而不得不创建带有“wrapped_”前缀的新私有方法。我想这对性能不利，因此，如果您知道如何直接修改方法的主体，请分享)。

在使用返回void的方法时，我遇到了问题。
如果未明确声明该方法的返回类型，则会出现以下错误:

无法在推断的类型引用上调用方法“isVoid”
编译阶段。在调用任何方法之前，请检查isInferred()。

好的，我可以添加对method.returnType.inferred的检查，但是该怎么做-似乎在这个阶段我们仍然不知道它是否将是空的，但是知道这对于转发方法的关键返回值。

请告诉我编写这种注释的正确方法是什么，谢谢!

最佳答案

也许您应该推迟计算。到关闭

method.body = [
    val voidMethod = method.returnType === null || method.returnType.void

         '''
            try {
                android.util.Log.d("TAG", "«method.simpleName» start");
                «IF (!voidMethod)»«method.returnType» ret = «ENDIF»
                «prefix + method.simpleName»(«method.parameters.map[simpleName].join(", ")»);
                android.util.Log.d("TAG", "«method.simpleName» end");
                «IF (!voidMethod)»return ret;«ENDIF»
            }
            catch(RuntimeException e) {
                android.util.Log.d("TAG", "«method.simpleName» ended with exception "
                    + e.getClass().getSimpleName() + "\n" + e.getMessage());
                throw e;
            }
        ''']