c++ - Cython中的C++ Struct继承

我用cython包装了一个C++库。在头文件中，有一些结构是从其他结构继承的，例如:

struct A {
    int a;
};
struct B : A {
    int b;
};

这应该在我的cdef extern...块中看起来如何？

最佳答案

Using C++ in Cython没有特别说明:

#file: pya.pyx
cdef extern from "a.h":
     cdef cppclass A:
        int a
     cdef cppclass B(A):
        int b

包装类:

#file: pya.pyx
cdef class PyB:
    cdef B* thisptr
    def __cinit__(self):
        self.thisptr = new B();
    def __dealloc__(self):
        del self.thisptr
    property a:
        def __get__(self): return self.thisptr.a
        def __set__(self, int a): self.thisptr.a = a
    property b:
        def __get__(self): return self.thisptr.b
        def __set__(self, int b): self.thisptr.b = b

例子:

import pyximport; pyximport.install(); # pip install cython

from pya import PyB

o = PyB()
assert o.a == 0 and o.b == 0
o.a = 1; o.b = 2
assert o.a == 1 and o.b == 2

要构建它，您需要指示pyximport使用c++:

#file: pya.pyxbld
import os
from distutils.extension import Extension

dirname = os.path.dirname(__file__)

def make_ext(modname, pyxfilename):
    return Extension(name=modname,
                     sources=[pyxfilename, "a.cpp"],
                     language="c++",
                     include_dirs=[dirname])

关于c++ - Cython中的C++ Struct继承，我们在Stack Overflow上找到一个类似的问题：https://stackoverflow.com/questions/9781572/