dependent-type - 如何定义精益中的相互归纳命题？

我尝试对归纳数据类型使用语法，但是它收到一条错误消息“相互归纳类型必须编译为具有依赖消除的基本归纳类型” 。

以下是我尝试在自然数上定义命题even和odd的示例

mutual inductive even, odd
with even: ℕ → Prop
| z: even 0
| n: ∀ n, odd n → even (n + 1)
with odd: ℕ → Prop
| z: odd 1
| n: ∀ n, even n → odd (n + 1)

还有一个相关的问题:定义相互递归函数的语法是什么？我似乎找不到任何地方的文档。

最佳答案

我认为Lean会自动尝试创建递归even.rec和odd.rec以使用Type而不是Prop。但这是行不通的，因为精益将逻辑世界(Prop)和计算世界(Type)分开了。换句话说，我们只能破坏一个逻辑项(证明)以产生一个逻辑项。请注意，如果您将even和odd设置为ℕ → Type类型，那么您的示例将起作用。

Coq证明助手是一个相关系统，它通过创建两个(相当弱和不切实际的)归纳原理来自动处理这种情况，但是，它当然不会生成一般的递归。

有一种解决方法，在此Lean wiki article中进行了描述。它涉及编写很多样板。让我举一个例子，说明在这种情况下该如何做。

首先，我们将互归类型编译为归纳族。我们添加一个表示均匀度的 bool 索引:

inductive even_odd: bool → ℕ → Prop
| ze: even_odd tt 0
| ne: ∀ n, even_odd ff n → even_odd tt (n + 1)
| zo: even_odd ff 1
| no: ∀ n, even_odd tt n → even_odd ff (n + 1)

接下来，我们定义一些缩写来模拟互归类型:

-- types
def even := even_odd tt
def odd := even_odd ff

-- constructors
def even.z : even 0 := even_odd.ze
def even.n (n : ℕ) (o : odd n): even (n + 1) := even_odd.ne n o
def odd.z : odd 1 := even_odd.zo
def odd.n (n : ℕ) (e : even n): odd (n + 1) := even_odd.no n e

现在，让我们推出我们自己的归纳原理:

-- induction principles
def even.induction_on {n : ℕ} (ev : even n) (Ce : ℕ → Prop) (Co : ℕ → Prop)
                      (ce0 : Ce 0) (stepe : ∀ n : ℕ, Co n → Ce (n + 1))
                      (co1 : Co 1) (stepo : ∀ n : ℕ, Ce n → Co (n + 1)) : Ce n :=
  @even_odd.rec (λ (switch : bool), bool.rec_on switch Co Ce)
                ce0 (λ n _ co, stepe n co)
                co1 (λ n _ ce, stepo n ce)
                tt n ev

def odd.induction_on {n : ℕ} (od : odd n) (Co : ℕ → Prop) (Ce : ℕ → Prop)
                     (ce0 : Ce 0) (stepe : ∀ n : ℕ, Co n → Ce (n + 1))
                     (co1 : Co 1) (stepo : ∀ n : ℕ, Ce n → Co (n + 1)) :=
  @even_odd.rec (λ (switch : bool), bool.rec_on switch Co Ce)
                ce0 (λ n _ co, stepe n co)
                co1 (λ n _ ce, stepo n ce)
                ff n od

最好隐含Ce : ℕ → Prop的even.induction_on参数，但是出于某种原因，精益不能推断它(请参阅最后的引理，我们必须显式传递Ce，否则精益推断与目标无关的Ce) 。这种情况与odd.induction_on是对称的。



如此lean-user thread中所述，对相互递归函数的支持非常受限制:



您可以在该线程中找到一个示例。但是，同样，我们可以使用相同的添加切换参数方法来模拟相互递归函数。让我们模拟相互递归的 bool 谓词evenb和oddb:

def even_oddb : bool → ℕ → bool
| tt 0       := tt
| tt (n + 1) := even_oddb ff n
| ff 0       := ff
| ff (n + 1) := even_oddb tt n

def evenb := even_oddb tt
def oddb  := even_oddb ff

这是一个如何使用以上所有示例的示例。让我们证明一个简单的引理:

lemma even_implies_evenb (n : ℕ) : even n -> evenb n = tt :=
  assume ev : even n,
  even.induction_on ev (λ n, evenb n = tt) (λ n, oddb n = tt)
    rfl
    (λ (n : ℕ) (IH : oddb n = tt), IH)
    rfl
    (λ (n : ℕ) (IH : evenb n = tt), IH)