我一直在尝试设计一个简单的OS，仅是引导扇区，以及带有中断的16位实模式。我终于能够制作出我在虚拟盒子中测试过的OS/bootloader，并且可以正常工作了。
然后，我将镜像刻录到CD，然后将其引导到带有Pentium 4，BIOS修订版A05和1GB RAM的旧台式机上，并且可以完美运行-一个简单的OS，在其顶部打印“标题”。屏幕，它所做的一切都允许您在屏幕上键入内容，并注册了一些用于浏览光标的键。
然后，我将光盘插入装有i5处理器，2.6 GB RAM和A05 BIOS Revision的1岁笔记本电脑中，光标似乎随机移动，高速打印随机字符，最后停在anscii字符上235(扩展字符表的一部分)，此时键盘可以正常工作，指定用于移动光标的键也可以正常工作，仅标题即可。这是我对其进行测试，对其进行编译，对其进行写入，并对其进行刻录的计算机。 (我使用了Linux Mint 12 OS)
我已经跳过了我认为需要做的所有“准备工作”:制作了一个遵循El Torito“无仿真”启动标准，启动签名，512字节并写入正确扇区的iso镜像。
我的代码有问题吗，我没有做任何事情，还是这很正常？
这是我的代码(NASM x86语法):
;**************************
; Note OS, Experimental OS
;**************************
[org 0x7C00]
[bits 16]
start:
jmp loader ;jump to the actual start of bootloader
times 8 - ($ - $$) db 0 ;pad eight bytes
;*********************
;El Torito Boot Info Table
;*********************
;in nasm, I couldn't figure out how to reserve bytes, in the middle of .text
;so I zeroed it out.
times 56 db 0
loader:
call cls ;clear the screen
mov si, head1 ;setup page headers
call printf
mov si, head2
call printf
jmp note ;start note program
cls:
mov ah, 0x0F ;get current video mode
mov al, 0x00 ;reset register
int 0x10 ;get video mode
mov ah, 0x00 ;set video mode
int 0x10 ;reset screen
mov ah, 0x02 ;set cursor pos
mov bh, 0x00 ;page 00
mov dh, 0x00 ;row 00
mov dl, 0x00 ;col. 00
int 0x10 ;set pos
ret
printf:
.loop ;our function that loops
mov al, [si] ;load byte
cmp al, 0 ;if null, end
je .end
mov ah, 0x0E ;function 0E
mov bh, 0x00 ;page 0x00
mov bl, 0x0F ;white text on black background
int 0x10 ;print
inc si ;increment source index
jmp .loop ;repeat
.end
ret ;return
;*******************
; Note 'Program'
;*******************
note:
mov ah, 0x00 ;function 00
int 0x16 ;get character
cmp al, '`' ;go up line?
je setcur
cmp al, 0x0D ;enter?
je setent
cmp al, '+' ;plus?
je setplu
cmp al, '-' ;minus?
je setminu
cmp al, '\' ;reset?
je loader
cmp al, 0x08 ;backspace?
je setback
mov ah, 0x0E ;function 0E
mov bh, 0x00 ;page 00
mov bl, 0x0F ;white on black
int 0x10 ;print
jmp note ;repeat
setcur:
mov ah, 0x03 ;get cur pos
mov bh, 0x00 ;page 00
int 0x10 ;get pos
cmp dh, 0x00 ;are we at top of page?
je .begin ;just reset cursor if so
sub dh, 0x01 ;go up one line
.begin
mov dl, 0x00 ;set to beginning of line
mov ah, 0x02 ;set cursor function
mov bh, 0x00 ;page 00
int 0x10 ;set position
jmp note ;read next character
setent:
mov ah, 0x0E ;write character
mov al, 0x0A ;begin line
mov bh, 0x00 ;page 00
mov bl, 0x0F ;white on black
int 0x10 ;print
setplu:
mov ah, 0x03 ;get cursor pos
mov bh, 0x00 ;page 0x00
int 0x10 ;get pos
mov ah, 0x02 ;set cursor pos
add dl, 0x01 ;add one to column
int 0x10 ;set new pos
jmp note ;get next char
setminu:
mov ah, 0x03 ;get cursor pos
mov bh, 0x00 ;page 00
int 0x10 ;get pos
mov ah, 0x02 ;set cursor pos
sub dl, 0x01 ;sub one to column
int 0x10 ;set new pos
jmp note ;get next char
setback:
mov ah, 0x03 ;get cursor pos
mov bh, 0x00 ;page 00
int 0x10 ;get pos
mov ah, 0x02 ;set cursor pos
sub dl, 0x01 ;sub one column
int 0x10 ;set pos
mov ah, 0x0E ;write char
mov al, ' ' ;write space
mov bh, 0x00 ;page 00
mov bl, 0x0F ;white on black
int 0x10
mov ah, 0x02 ;reset cur pos
int 0x10 ;reset
jmp note
;******************
; Our Page Headers
;******************
head1: db '- Note OS Version 1.2-', 0x0A, 0x0D, 0
head2: db '=======================', 0x0A, 0x0D, 0x0A, 0x0D, 0
times 510 - ($ - $$) db 0
dw 0xAA55
供引用(我引用的东西):
Anscii表:http://www.asciitable.com/
El-Torito信息:http://wiki.osdev.org/El-Torito
编辑:
这是我编写的键及其作用:
输入-现在可以正常使用
退格键-现在可以正常使用
加号-向右移动光标
减号-向左移动光标
`-将光标移动到上一行的开头
\-“软重启”几乎跳到加载程序的开头
最佳答案
问题在这里:
[org 0x7C00]
...
start:
jmp loader ;jump to the actual start of bootloader
...
loader:
call cls ;clear the screen
mov si, head1 ;setup page headers
call printf
...
printf:
.loop ;our function that loops
mov al, [si] ;load byte
您希望在代码启动时输入
CS=DS=0。 DS不能保证为0。因此，当DS非零时，mov al, [si]从段0以外的某个段读取字节，并且可能会有一些垃圾，而不是您的问候消息的副本。另外，有些BIOS使用
0:0x7C00的地址跳转到您的代码，而另一些BIOS使用0x7C0:0的地址，这意味着即使CS也不能保证具有固定值。我要做的是:
[org 0x7C00]
[bits 16]
start:
jmp loader ;jump to the actual start of bootloader
...
loader:
jmp 0:loader2 ; this far jump guarantees CS=0
loader2:
push cs
pop ds ; this guarantees DS=0
; the rest of the code goes here
关于assembly - 引导加载程序奇怪的行为，我们在Stack Overflow上找到一个类似的问题：https://stackoverflow.com/questions/9660315/