xml - 如何使XSL在多列中显示结果？

我正在创建一个创建XML的应用程序，如下所示：

<?xml version="1.0" encoding="ISO-8859-1"?>
<?xml-stylesheet type="text/xsl" href="MyCDCatalog.xsl"?>
<catalog>
    <cd>
        <title>Empire Burlesque</title>
        <artist>Bob Dylan</artist>
        <price>10.90</price>
        <year>1985</year>
    </cd>
    <cd>
        <title>Hide your heart</title>
        <artist>Bonnie Tyler</artist>
        <price>9.90</price>
        <year>1988</year>
    </cd>
    <cd>
        <title>Greatest Hits</title>
        <artist>Dolly Parton</artist>
        <price>9.90</price>
        <year>1982</year>
    </cd>
    <cd>
        <title>One night only</title>
        <artist>Bee Gees</artist>
        <price>10.90</price>
        <year>1998</year>
    </cd>
    <cd>
        <title>Sylvias Mother</title>
        <artist>Dr.Hook</artist>
        <price>8.10</price>
        <year>1973</year>
    </cd>
    <cd>
        <title>Maggie May</title>
        <artist>Rod Stewart</artist>
        <price>8.50</price>
        <year>1990</year>
    </cd>
</catalog>

我还使用了一个名为mycdcatalog.xsl的xsl文件（下面）来转换上面的xml文件。

<?xml version="1.0" encoding="ISO-8859-1"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:template match="/">
  <html>
  <body>
    <h2>My CD Collection</h2>
    <table border="1">
      <xsl:for-each select="catalog/cd">
      <tr>
        <td><xsl:value-of select="artist" />'s <xsl:value-of select="title" /> (<xsl:value-of select="year" />):   $<xsl:value-of select="price" /></td>
      </tr>
      </xsl:for-each>
    </table>
  </body>
  </html>
</xsl:template>
</xsl:stylesheet>

目前，xsl文件返回一列中的所有条目。如何在3列或更多列中获取输出？
我希望输出如下：

[cd1] [cd2] [cd3]
[cd4] [cd5] [cd6]....

在哪里？

cd1 = Bob Dylan's Empire Burlesque (1985): $10.90
cd2 = Bonnie Tyler's Hide your heart (1988): $9.90
etc.

谢谢你的帮助。

最佳答案

另一种方法是在第一、第四、第七（etc）位置匹配cd。

<xsl:apply-templates select="cd[(position() - 1) mod $columns = 0]" mode="first"/>

其中$columns是包含列数的参数
然后，您可以通过查看以下同级的相关数目来匹配行中的cd元素：

<xsl:apply-templates select=".|following-sibling::cd[position() &lt; $columns]"/>

这是完整的xslt

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
   <xsl:output method="html" indent="yes" omit-xml-declaration="yes" />
   <xsl:param name="columns" select="3"/>

   <xsl:template match="/catalog">
      <html>
         <body>
            <h2>My CD Collection</h2>
            <table>
               <xsl:apply-templates select="cd[(position() - 1) mod $columns = 0]" mode="first"/>
            </table>
         </body>
      </html>
   </xsl:template>

   <xsl:template match="cd" mode="first">
      <tr>
         <xsl:apply-templates select=".|following-sibling::cd[position() &lt; $columns]"/>
         <xsl:if test="count(following-sibling::cd) &lt; ($columns - 1)">
            <xsl:call-template name="emptycell">
               <xsl:with-param name="cells" select="$columns - 1 - count(following-sibling::cd)"/>
            </xsl:call-template>
         </xsl:if>
      </tr>
   </xsl:template>

   <xsl:template match="cd">
      <td>
         <xsl:value-of select="concat(title, &apos; &apos;, artist)"/>
      </td>
   </xsl:template>

   <xsl:template name="emptycell">
      <xsl:param name="cells"/>
      <td/>
      <xsl:if test="$cells &gt; 1">
         <xsl:call-template name="emptycell">
            <xsl:with-param name="cells" select="$cells - 1"/>
         </xsl:call-template>
      </xsl:if>
   </xsl:template>
</xsl:stylesheet>

当应用于示例XML时，将输出以下内容：

<html>
   <body>
      <h2>My CD Collection</h2>
      <table>
         <tr>
            <td>Empire Burlesque Bob Dylan</td>
            <td>Hide your heart Bonnie Tyler</td>
            <td>Greatest Hits Dolly Parton</td>
         </tr>
         <tr>
            <td>One night only Bee Gees</td>
            <td>Sylvias Mother Dr.Hook</td>
            <td>Maggie May Rod Stewart</td>
         </tr>
      </table>
   </body>
</html>

（我只在这里输出姓名和艺术家，但我相信您可以看到如何更改它以显示更多信息）
注意，如果剩余的cd元素数小于行中的列数，则有一点讨厌的递归模板可以输出空单元格。
例如，将参数更改为4，则输出以下内容：

<table>
  <tr>
    <td>Empire Burlesque Bob Dylan</td>
    <td>Hide your heart Bonnie Tyler</td>
    <td>Greatest Hits Dolly Parton</td>
    <td>One night only Bee Gees</td>
  </tr>
  <tr>
    <td>Sylvias Mother Dr.Hook</td>
    <td>Maggie May Rod Stewart</td>
    <td />
    <td />
  </tr>
</table>

关于xml - 如何使XSL在多列中显示结果？，我们在Stack Overflow上找到一个类似的问题：https://stackoverflow.com/questions/9407507/

Xsl

xml - 如何使XSL在多列中显示结果？