perl - 给定Perl中的包名称，如何从包中调用子例程？

给定一个包含代表程序包名称的字符串的变量，如何调用程序包的特定子例程？

这是我发现的最接近的东西:

package MyPackage;

sub echo {
    print shift;
}

my $package_name = 'MyPackage';
$package_name->echo('Hello World');

1;

这段代码的问题在于子例程被称为类方法；该子例程被称为类方法。程序包名称作为第一个参数传入。我想从包名称中调用子例程，而无需隐式传递特殊的第一个参数。

最佳答案

Perl方法调用只是常规子例程，这些子例程将invocant作为第一个值。

use strict;
use warnings;
use 5.10.1;

{
  package MyPackage;
  sub new{ bless {}, shift } # overly simplistic constructor (DO NOT REUSE)
  sub echo{ say @_ }
}

my $package_name = 'MyPackage';
$package_name->echo;

my $object = $package_name->new();
$object->echo; # effectively the same as MyPackage::echo($object)

MyPackage
MyPackage=HASH(0x1e2a070)

如果要在没有参与者的情况下调用子例程，则需要以不同的方式调用它。

{
  no strict 'refs';
  ${$package_name.'::'}{echo}->('Hello World');
  &{$package_name.'::echo'}('Hello World');
}

# only works for packages without :: in the name
$::{$package_name.'::'}{echo}->('Hello World');

$package_name->can('echo')->('Hello World');

can 方法返回对子例程的引用，如果已在调用方上调用了该子例程，则该子例程将被调用。然后可以单独使用coderef。

my $code_ref = $package_name->can('echo');
$code_ref->('Hello World');

使用 can 有一些注意事项:

can可能会被包或其继承的任何类覆盖。

定义方法的包可能不同于发起者。

这实际上可能是您正在寻找的行为。

另一种方法是使用称为symbolic reference的东西。

{
  no strict 'refs';
  &{ $package_name.'::echo' }('Hello World');
}

通常不建议使用符号引用。问题的一部分是，在您不打算使用符号引用的情况下，可能会意外地使用它。这就是为什么您不能有效使用use strict 'refs';的原因。

这可能是您要做的最简单的方法。

如果您不想使用符号引用，则可以使用Stash。

$MyPackage::{echo}->('Hello World');
$::{'MyPackage::'}{echo}->('Hello World');

$main::{'MyPackage::'}{echo}->('Hello World');
$main::{'main::'}{'MyPackage::'}{echo}->('Hello World');
$main::{'main::'}{'main::'}{'main::'}{'MyPackage::'}{echo}->('Hello World');

唯一的问题是您必须在$package_name上分割::

*Some::Long::Package::Name::echo = \&MyPackage::echo;

$::{'Some::'}{'Long::'}{'Package::'}{'Name::'}{echo}('Hello World');

sub get_package_stash{
  my $package = shift.'::';
  my @package = split /(?<=::)/, $package;
  my $stash = \%:: ;
  $stash = $stash->{$_} for @package;
  return $stash;
}
get_package_stash('Some::Long::Package::Name')->{echo}('Hello World');

不过，这并不是什么大问题。快速浏览CPAN后，您会发现Package::Stash。

use Package::Stash;
my $stash = Package::Stash->new($package_name);
my $coderef = $stash->get_symbol('&echo');
$coderef->('Hello World');

(Pure Perl的Package::Stash版本使用符号引用，而不是Stash)

甚至可以为子例程/方法创建别名，就好像是从使用Exporter的模块中导入的一样:

*echo = \&{$package_name.'::echo'};
echo('Hello World');

我建议尽管限制别名的范围:

{
  local *echo = \&{$package_name.'::echo'};
  echo('Hello World');
}

这是一个异常(exception)，您可以在启用了strict 'refs'的情况下使用符号引用。

关于perl - 给定Perl中的包名称，如何从包中调用子例程？，我们在Stack Overflow上找到一个类似的问题：https://stackoverflow.com/questions/10890558/