json - 当 toString() 时 Groovy JsonBuilder 的奇怪行为

我需要创建一个 json 以用作 http.request 中的正文。我能够动态构建 json，但是在两次调用 builder.toString() 时我注意到了一个奇怪的行为。生成的 json 完全不同。我可能认为这与某种缓冲区有关。我一直在阅读文档，但找不到好的答案。这是要测试的代码。

import groovy.json.JsonBuilder

def builder = new JsonBuilder()

def map = [
    catA: ["catA-element1", "catA-element2"],
    catB:[],
    catC:["catC-element1"]
]

def a = map.inject([:]) { res, k, v ->
    def b = v.inject([:]) {resp, i ->
        resp[i] = k
        resp
    }
    res += b
}
println a

def root = builder.query {
    bool {
        must a.collect{ k, v ->
            builder.match {
                "$v" k
            }
        }
    }
    should([
        builder.simple_query_string {
            query "text"
        }
    ])
}
println builder.toString()
println builder.toString()

这将打印以下行。注意最后两行

[catA-element1:catA, catA-element2:catA, catC-element1:catC]
{"query":{"bool":{"must":[{"match":{"catA":"catA-element1"}},{"match":{"catA":"catA-element2"}},{"match":{"catC":"catC-element1"}}]},"should":[{"simple_query_string":{"query":"text"}}]}}
{"match":{"catC":"catC-element1"}}

在我的代码中，我可以轻松地将第一个 toString() 结果发送到一个变量并在需要时使用它。但是，为什么在多次调用时它会发生变化？

最佳答案

我认为这是因为您在闭包 builder 中使用了 bool 。如果我们在打印结果之前制作 print builder.content ( buider.toString() 正在调用 JsonOutput.toJson(builder.content) )，我们得到:

[query:[bool:ConsoleScript54$_run_closure3$_closure6@294b5a70, should:[[simple_query_string:[query:text]]]]]

将 println builder.content 添加到 bool 闭包中，我们可以看到在评估闭包时修改了 builder.content:

def root = builder.query {
    bool {
        must a.collect{ k, v ->
            builder.match {
                "$v" k
                println builder.content
            }
        }
    }
    should([
        builder.simple_query_string {
            query "text"
        }
    ])
}

println JsonOutput.toJson(builder.content)
println builder.content

以上产生:

[query:[bool:ConsoleScript55$_run_closure3$_closure6@39b6156d, should:[[simple_query_string:[query:text]]]]]
[match:[catA:catA-element1]]
[match:[catA:catA-element2]]
{"query":{"bool":{"must":[{"match":{"catA":"catA-element1"}},{"match":{"catA":"catA-element2"}},{"match":{"catC":"catC-element1"}}]},"should":[{"simple_query_string":{"query":"text"}}]}}
[match:[catC:catC-element1]]

您可以使用不同的构建器轻松避免这种情况:

def builder2 = new JsonBuilder()

def root = builder.query {
    bool {
        must a.collect{ k, v ->
            builder2.match {
                "$v" k
            }
        }
    }
    should([
        builder.simple_query_string {
            query "text"
        }
    ])
}

或者甚至更好:

def root = builder.query {
    bool {
        must a.collect({ k, v -> ["$v": k] }).collect({[match: it]})
    }
    should([
        simple_query_string {
            query "text"
        }
    ])
}

关于json - 当 toString() 时 Groovy JsonBuilder 的奇怪行为，我们在Stack Overflow上找到一个类似的问题：https://stackoverflow.com/questions/31396436/