delphi - 如何使用尚未初始化的变量

我正在尝试创建一个具有字符串和节点数组的节点，但是尚未创建那些其他节点，那么如何使用它们？稍后，我将需要在“针对节点中的所有边缘”循环中访问特定节点的边缘。这是一个图形数据结构。该图是有向的，表示节点A可以与B连接，而B不与A连接。

type
  TNode = record
    name: String;
    edges: TNodeArray;
    procedure Init(const aName: String; const aEdges: TNodeArray);
  end;
  TNodeArray = array of TNode;

procedure  TNode.Init(const aName: String; const aEdges: TNodeArray);
begin
  name := aName;  edges := aEdges;
end;

function NewNode(const aName: String; const aEdges: TNodeArray): TNode;
begin
  Result.Init(aName, aEdges);
end;

procedure Main;
var
  n0, n1, n2, n3: TNode;
begin
  n0 := NewNode('new york', TNodeArray.Create(n1, n2));
  n1 := NewNode('london', TNodeArray.Create(n2));
  n2 := NewNode('moscu', TNodeArray.Create(n1, n3));
  n3 := NewNode('other city', nil);  // 'other city' has no connections
end;

最佳答案

在评论中，事实证明这是有向图。如果是这样，您可以使用以下方法：

type
  TNode = class
  strict private
    FName: string;
    FOutgoingArcs: TList<TNode>;
    function GetOutgoingArc(Index: Integer): TNode;
    function GetOutgoingArcCount: Integer;
  public
    constructor Create(const AName: string);
    procedure AddOutgoingArc(ANode: TNode);
    procedure AddOutgoingArcs(const ANodes: array of TNode);
    property OutgoingArcs[Index: Integer]: TNode read GetOutgoingArc;
    property OutgoingArcCount: Integer read GetOutgoingArcCount;
    property Name: string read FName write FName;
    destructor Destroy; override;
  end;

implementation

{ TNode }

procedure TNode.AddOutgoingArc(ANode: TNode);
begin
  FOutgoingArcs.Add(ANode)
end;

procedure TNode.AddOutgoingArcs(const ANodes: array of TNode);
var
  Node: TNode;
begin
  for Node in ANodes do
    AddOutgoingArc(Node);
end;

constructor TNode.Create(const AName: string);
begin
  FName := AName;
  FOutgoingArcs := TList<TNode>.Create;
end;

destructor TNode.Destroy;
begin
  FOutgoingArcs.Free;
  inherited;
end;

function TNode.GetOutgoingArcCount: Integer;
begin
  Result := FOutgoingArcs.Count;
end;

function TNode.GetOutgoingArc(Index: Integer): TNode;
begin
  Result := FOutgoingArcs[Index];
end;

我还认为最好在一个列表中跟踪所有节点，所以我愿意

var
  Nodes: TObjectList<TNode>;

function CreateNode(const AName: string): TNode;
begin
  Result := TNode.Create(AName);
  Nodes.Add(Result);
end;

现在我们可以播放（确保首先创建Nodes：Nodes := TObjectList<TNode>.Create(True{say})）：

var
  NewYork,
  London,
  Paris,
  Moscow: TNode;
begin

  NewYork := CreateNode('New York');
  London := CreateNode('London');
  Paris := CreateNode('Paris');
  Moscow := CreateNode('Moscow');

  NewYork.AddOutgoingArc(London);
  London.AddOutgoingArcs([NewYork, Paris, Moscow]);
  Paris.AddOutgoingArcs([London, Moscow]);
  Moscow.AddOutgoingArc(NewYork);

但是，当然有一千种设计方法。这只是一种可能的解决方案。

更新：

请注意，只有一个名为“伦敦”的对象，因此，如果您通过“通过巴黎”更改此对象，则会看到“通过纽约”：

Paris.OutgoingArcs[0].Name := 'The Capital of the United Kingdom';

现在

NewYork.OutgoingArcs[0].Name

也是'The Capital of the United Kingdom'。

另请注意，

Nodes := TObjectList<TNode>.Create(True)

节点将归Nodes对象列表所有（这是True的意思），因此，当释放Nodes时将释放它们。因此，例如，如果您在自己的类TTravelPlanner中使用这些节点，则可能要在Nodes中创建TTravelPlanner.Create并在Nodes.Free中执行TTravelPlanner.Destroy。

关于delphi - 如何使用尚未初始化的变量，我们在Stack Overflow上找到一个类似的问题：https://stackoverflow.com/questions/61385863/

nodes

delphi - 如何使用尚未初始化的变量