英特尔和AMD文档说,对于64位模式,实际上只有48位可用于虚拟地址,并且从48到63的位必须复制第47位(符号扩展)。据我所知,目前所有的CPU都是以这种方式实现的,但从理论上讲,没有任何事情可以扩展以后的实现中的可用空间(这不会破坏二进制兼容性)。

是否有一种标准方法以编程方式确定有意义的位数? (即某些特定的CPUID,就像物理地址一样)。

我知道实际上48位对于任何合理的应用程序和OS来说已经足够了。我的问题是理论上的。

最佳答案

是的,如果支持,您可以使用CPUID.80000008H:EAX[7:0]

算法如下:


cpuid检查CPUID.80000000h.EAX的最大扩展E值。
如果E> = 80000008h,请使用
CPUID.80000008H:EAX[7:0]表示物理地址位数。
CPUID.80000008H:EAX[15:8]表示线性地址位数。
否则,如果CPUID.1:EDX.PAE(位6),则CPU具有36个物理地址位和32个线性地址位。
否则,CPU具有32个物理和逻辑地址位。




英特尔的CPUID.X:R B表示


X在eax之前放入cpuid的值。
R感兴趣的输出寄存器。
B格式为[upper:lower]的位域,或格式为.bitname的命名位。




AMD将虚拟:物理地址的最大限制设置为63:52。
尽管物理地址空间的大小可以不同,但​​是当前的实现通常是48:40。



可以使用NASM编译的示例代码

BITS 64

GLOBAL max_phy_addr
GLOBAL max_lin_addr


SECTION .text


max_phy_addr:
 push rbx


 mov eax, 80000000h
 cpuid

 cmp eax, 80000008h
 jae .fromCpuid

 mov eax, 1
 cpuid

 mov eax, 32
 shr edx, 4
 and edx, 4

 add eax, edx

 pop rbx
 ret

.fromCpuid:

 mov eax, 80000008h
 cpuid

 movzx eax, al

 pop rbx
 ret


max_lin_addr:
 push rbx

 mov eax, 80000000h
 cpuid

 cmp eax, 80000008h
 jae .fromCpuid

 mov eax, 1
 cpuid

 mov eax, 32

 pop rbx
 ret

.fromCpuid:

 mov eax, 80000008h
 cpuid

 movzx eax, ah

 pop rbx
 ret


并与C程序(例如

#include <stdio.h>

long max_phy_addr();
long max_lin_addr();

int main()
{
   printf("Phy: %llu\nLin: %llu\n", max_phy_addr(), max_lin_addr());
   return 0;
}




我刚刚发现我的Haswell是48:39!

07-24 09:45
查看更多