xslt - 在 XSLT 中循环 - <xsl :for-each

我需要在 XSLT 中呈现以下格式。我有一个包含 5 个元素(Text1、Text2...Text5)的 <xsl:for-each 循环，并且需要在每三个元素之后包装一个 ul 标签。请问有什么建议吗？

<ul>
    <li>Text1</li>
    <li>Text2</li>
    <li>Text3</li>
</uL>
<ul>
    <li>Text4</li>
    <li>Text5</li>
</uL>

最佳答案

好问题，+1。

这种转换 :

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="thing[position() mod 3 = 1]">
  <ul>
   <xsl:apply-templates mode="inGrpoup" select=
    ".|following-sibling::*[not(position() > 2)]"/>
  </ul>
 </xsl:template>

 <xsl:template match="thing" mode="inGrpoup">
  <li><xsl:value-of select="."/></li>
 </xsl:template>
 <xsl:template match="text()"/>
</xsl:stylesheet>

应用于以下 XML 文档 :

<things>
    <thing>1</thing>
    <thing>2</thing>
    <thing>3</thing>
    <thing>4</thing>
    <thing>5</thing>
    <thing>6</thing>
    <thing>7</thing>
    <thing>8</thing>
</things>

产生想要的、正确的结果 (连续三组的事物):

<ul>
   <li>1</li>
   <li>2</li>
   <li>3</li>
</ul>
<ul>
   <li>4</li>
   <li>5</li>
   <li>6</li>
</ul>
<ul>
   <li>7</li>
   <li>8</li>
</ul>

说明 :

模板模式匹配 一组三个 thing 元素的第一个 thing。

一旦确定，使用模式 处理一组 thing 元素(以不同于处理初始起始 thing 的方式)。

关于xslt - 在 XSLT 中循环 - <xsl :for-each，我们在Stack Overflow上找到一个类似的问题：https://stackoverflow.com/questions/8542979/