为什么Monoid实例不需要(Ord a,Ord b)约束,而Semigroup实例却不需要?

这是否取决于Category.Constrained类或使用GADT定义数据类型?

{-# LANGUAGE GADTs, TypeFamilies, ConstraintKinds, StandaloneDeriving #-}

module Question3 where

import Control.Category.Constrained as CC
import Data.Set as S
import Data.Map as M

data RelationMS a b where
  IdRMS :: RelationMS a a
  RMS :: (Ord a, Ord b) => Map a (Set b) -> RelationMS a b
deriving instance (Show a, Show b) => Show (RelationMS a b)

RMS mp2 `compRMS` RMS mp1
  | M.null mp2 || M.null mp1 = RMS M.empty
  | otherwise = RMS $ M.foldrWithKey
        (\k s acc -> M.insert k (S.foldr (\x acc2 -> case M.lookup x mp2 of
                                                    Nothing -> acc2
                                                    Just s2 -> S.union s2 acc2
                                         ) S.empty s
                                ) acc
        ) M.empty mp1

instance Category RelationMS where
    type Object RelationMS o = Ord o
    id = IdRMS
    (.) = compRMS

instance Semigroup (RelationMS a b) where
    RMS r1 <> RMS r2 = RMS $ M.foldrWithKey (\k s acc -> M.insertWith S.union k s acc) r1  r2

instance (Ord a, Ord b) => Monoid (RelationMS a b) where
    mempty = RMS $ M.empty
    mappend = (<>)

最佳答案

这当然与类别实例无关。

至少从概念上讲,Semigroup实例确实也需要Ord,但是您已经将其打包在GADT中(除了Id情况,因为它很琐碎,因此不需要),因此无需在实例中提及约束头。

但是,对于mempty,您手边没有RelationMS值,可以从中读出(Ord a, Ord b)约束。恰恰相反:您需要提供这些约束,因为您现在正在尝试包装此类GADT!这就是Monoid实例在其头部需要约束的原因,而Semigroup实例则不需要。

10-05 20:55
查看更多