logging - 控制台上未显示 Clojure Web 服务中的基本日志记录

我正在关注 this tutorial 在我的 Clojure Web 应用程序中设置应用程序日志记录，我将使用它进行一些 Datomic 实验。该教程建议我所要做的就是将 Clojure 的 clojure.tools.logging 库添加到我在 Leiningen 中的项目依赖项中，并且输出应该只显示在我的控制台上。但是，在启动应用程序时，我没有在控制台或其他地方看到任何日志输出。我究竟做错了什么？

这是我的设置方式。我的网络堆栈是 Ring/Compojure，作为嵌入式 Jetty 独立 JAR 运行(使用 ring.adapter.jetty )，具有尚未使用数据库的虚拟 API 路由。

我的 project.clj(注意:我正在评估 Datomic 的专业版，所以我在项目之外完成了 GPG 设置，以便正确下载这个 protected JAR):

(defproject helloworld "0.1.0-SNAPSHOT"
  :description "FIXME: write description"
  :url "http://example.com/FIXME"
  :min-lein-version "2.0.0"
  :repositories {
    "my.datomic.com" {:url "https://my.datomic.com/repo" :creds :gpg}}
  :dependencies [[org.clojure/clojure "1.6.0"]
                 [compojure "1.3.1"]
                 [ring/ring-defaults "0.1.2"]
                 [ring/ring-json "0.3.1"]
                 [ring/ring-defaults "0.1.2"]
                 [ring/ring-jetty-adapter "1.4.0"]
                 [org.clojure/tools.logging "0.3.1"]
                 [com.datomic/datomic-pro "0.9.5198" :exclusions [joda-time]]
                 [joda-time "2.8.1"]]
  :plugins [[lein-ring "0.8.13"]]
  :ring {:handler helloworld.handler/app}
  :main helloworld.core
  :aot [helloworld.core]
  :profiles
  {:dev {:dependencies [[javax.servlet/servlet-api "2.5"]
                        [ring-mock "0.1.5"]]}})

文件 src/helloworld/core.clj :

(ns helloworld.core
  (:require [clojure.tools.logging :as log]
            [ring.adapter.jetty :as jetty]
            [helloworld.handler :refer [app]])
  (:gen-class))

(defn -main [& args]
  (println "Hello, world!")
  (log/info "Service is running!")
  (jetty/run-jetty app {:port 8080}))

Compojure 应用程序和 API 处理程序 src/helloworld/handler.clj :

(ns helloworld.handler
  (:require [clojure.tools.logging :as log]
            [compojure.core :refer :all]
            [compojure.route :as route]
            [ring.middleware.defaults :refer [wrap-defaults api-defaults]]
            [ring.middleware.json :as json-middleware]
            [ring.util.response :refer [response]]))

(def dummy-entity {:id 1 :name "Hello, world!"})

(defroutes app-routes
  (GET "/" []
    (log/info "Getting all the things!")
    (response [dummy-entity]))
  (route/not-found "Not Found"))

(def app
  (->
    (wrap-defaults app-routes api-defaults)
    (json-middleware/wrap-json-body)
    (json-middleware/wrap-json-response)))

这是我尝试运行它时看到的(这也是在几次点击默认端点之后):

$ lein run
Hello, world!

所以 println 肯定是有效的，但日志记录似乎不是。

最佳答案

事实证明，这里的问题是包含 Datomic 库，即使我没有使用它!如果我删除 datomic-pro 和 joda-time 依赖项并重新运行，会发生以下情况:

$ lein run
2015-07-12 12:50:36.305:INFO::main: Logging initialized @1599ms
Hello, world!
Jul 12, 2015 12:50:38 PM clojure.tools.logging$eval18$fn__22 invoke
INFO: Service is running!
2015-07-12 12:50:38.167:INFO:oejs.Server:main: jetty-9.2.10.v20150310
2015-07-12 12:50:38.225:INFO:oejs.ServerConnector:main: Started ServerConnector@510a6f62{HTTP/1.1}{0.0.0.0:8080}
2015-07-12 12:50:38.226:INFO:oejs.Server:main: Started @3520ms
Jul 12, 2015 12:50:42 PM clojure.tools.logging$eval18$fn__22 invoke
INFO: Getting all the things!

所以现在我也收到了一堆 Jetty 日志，以及我的应用程序日志。

我认为问题是这样的:

Clojure 的日志库从可用的日志后端中选择它最喜欢的日志后端。

我正在看的教程假设您的项目的依赖项(或它们的任何传递依赖项!)中不包含日志库，因此将选择最后一个默认值 (java.util.logging)。默认情况下，这将登录到控制台。

然而，Datomic 引入了 SLF4J，Clojure 日志库很喜欢它。

反过来，

SLF4J 没有任何日志适配器可供使用，因为我没有在我的项目依赖项中指定任何日志适配器。所以它选择了一个无操作记录器。 (谢谢，SLF4J。)

我通过对实际使用的记录器进行一些调试来验证这一点。我将此添加到 -main :

(ns ...
  (require ...
           [clojure.tools.logging.impl :as log-impl]
           ...))
...
(let [logger (log-impl/get-logger log/*logger-factory* *ns*)]
    (println logger))

这向我展示了一些属于 SLF4J 的 NOOP 记录器类的对象。

我通过向我的项目依赖项添加适当的 SLF4J 适配器来修复。我选择使用 Logback:

[com.datomic/datomic-pro "0.9.5198"
 :exclusions [joda-time org.slf4j/slf4j-nop org.slf4j/slf4j-log4j12]]
[ch.qos.logback/logback-classic "1.1.3"]

为了配置，我在 resources/logback.xml 中添加了以下内容:

<?xml version="1.0" encoding="UTF-8"?>
<configuration>
  <appender name="CONSOLE" class="ch.qos.logback.core.ConsoleAppender">
    <encoder>
      <pattern>%d{HH:mm:ss.SSS} [%thread] %-5level %logger{36} - %msg%n</pattern>
    </encoder>
  </appender>

  <root level="debug">
    <appender-ref ref="CONSOLE" />
  </root>
</configuration>

这解决了它!

关于logging - 控制台上未显示 Clojure Web 服务中的基本日志记录，我们在Stack Overflow上找到一个类似的问题：https://stackoverflow.com/questions/31371993/